gnuplotのmultiplotのメモ

Windows版のgnuplot(wgnuplot)を使って、一つの図の中に複数のグラフを描画する際のmultiplotを利用するためのTIPについて書きます。
  • multiplotの中でterminalの変更はできない
  • replotは使えないのでplotですべてプロット。改行は,\
  • 横軸が共通のときはmarginで合わせる
  • xrangeをデフォルトへ戻すのはset xrange [*:*]
  • wgnuplot.exeのプロセスが残ってしまうなら unset multiplot の後に何でもいいからplot

001_2015101506141594f.png

Fig.1: AkaiKKRでγ-Mnの反強磁性の結果をmultiplotで一つのグラフにまとめたもの



gnuplotのmultiplot


gnuplotではmultiplotを利用して一枚の図の中に複数のグラフを描くことが可能です。この際にいくつか注意しなければならない点があります。今回は、それらのポイントを(最小限のものだけ)まとめました。multiplotの詳しい使い方は、米澤 進吾さんのホームページなどを参照されるのが良いと思います。

set terminal pngcairo enhanced color size 520,600
set output "fccMn.png"

## *** マルチプロットの開始 ***
set multiplot layout 2,1
set lmargin 8 # 左マージン
set rmargin 2 # 右マージン

## *** 磁気モーメントのプロット ***
set key left top # 凡例の位置
set yrange [0:4]
set xlabel "Lattice constant a (Bohr)"
set ylabel "Local spin moment ({/Symbol m}_B)"
plot 'fccMn-Moment.txt' u 1:4 w lp title "Non-mag",\
'fccMn-Moment.txt' u 1:3 w lp title "Ferro",\
'fccMn-Moment.txt' u 1:2 w lp title "Antiferro"

## *** 全エネルギーのプロット ***
set key right top
unset ytics
set yrange [*:*] # yの範囲をデフォルトに戻す
set xlabel "Lattice constant a (Bohr)"
set ylabel "Total Energy (arb. unit)"
plot 'fccMn-NMG.txt' u 1:2 w lp title "Non-mag",\
'fccMn-FMG.txt' u 1:2 w lp title "Ferro",\
'fccMn-AFM.txt' u 1:($2/2.0) w lp title "Antiferro"

## *** マルチプロットの終了 ***
unset multiplot

## *** 後処理 ***
# 何かプロットしておくとwgnuplot.exeのプロセスが残らない
set terminal windows
plot sin(x)


terminalの切り替え不可


multiplot環境下ではterminalの切り替えができません。
私はこれまでmultiplotを使わない状況では、windowsのterminalで画面上で描画を確認した後、terminalをpngcairo等に変更して画像出力をしていましたがmultiplotを使う場合は、最初からpngcairoやpostscriptなど画像出力用のterminalを指定して一発勝負にします。

一つのグラフにつき一回のplot


multiplot環境の中では、一回のplotに付きひとつのパネルが作成されます。
一つのパネルの中に複数の線を描きたい場合、一回のplotで行う必要があります。
plot 'fccMn-NMG.txt' u 1:2 w lp title "Non-mag",\
'fccMn-FMG.txt' u 1:2 w lp title "Ferro",\
'fccMn-AFM.txt' u 1:($2/2.0) w lp title "Antiferro"

この際に、改行を表す ,\ を利用します。

グラフの横位置を合わせる


複数のパネルが共通のx軸を持っている場合、位置がずれて見栄えが悪くなることがあります。
そういう場合は lmarginrmargin でマージンを設定します。
set lmargin 8
set rmargin 2


描画範囲のリセット


描画範囲を設定するときには set yrange [0:4] のように指定します。
これをデフォルトの設定に戻すには set yrange [*:*]のように指定します。
set xrange [*:*]
set yrange [*:*]

なんとなく unset を使いたくなりますが、こちらは間違いです。

wgnuplot.exeのプロセスが残ってしまう場合


私の環境(のうちのひとつ)では wgnuplot.exe のプロセスが残ってしまうことがあるようです。
multiplot環境を抜けた後、terminalをwindowsに切り替えて、何でも良いのでプロットするとプロセスが残りません。
set terminal windows
plot sin(x)

プロセスが残らないなら必要ないと思います。

関連エントリ




参考URL




付録


このエントリで使用したファイルを添付します。ファイル名末尾の".txt"を削除して、"_"を"."に変更すれば使えるはずです。(参考:ねがてぃぶろぐの付録)


フィードバック



にほんブログ村 その他趣味ブログ 電子工作へ

 ↑ 電子工作ブログランキング参加中です。1クリックお願いします。


コメント・トラックバックも歓迎です。 ↓      


 ↓ この記事が面白かった方は「拍手」をお願いします。


tag: gnuplot multiplot AkaiKKR machikaneyama 

comment

Secret

FC2カウンター
カテゴリ
ユーザータグ

LTspiceAkaiKKRmachikaneyamaScilabKKRPSoCOPアンプCPA強磁性PICモンテカルロ解析常微分方程式odeトランジスタecalj状態密度DOSインターフェース定電流スイッチング回路PDS5022半導体シェルスクリプト乱数レベルシフトHP6632A温度解析分散関係I2Cトランジスタ技術R6452A可変抵抗ブレッドボードセミナーバンドギャップ数値積分確率論反強磁性偏微分方程式バンド構造絶縁熱設計非線形方程式ソルバフォトカプラシュミットトリガLEDLM358カオスISO-I2C三端子レギュレータGW近似A/Dコンバータカレントミラーアナログスイッチ数値微分マフィンティン半径TL431発振回路サーボPC817CUSB直流動作点解析74HC4053補間FFTBSch開発環境パラメトリック解析2ちゃんねるチョッパアンプ量子力学bzqlty電子負荷イジング模型LDA標準ロジックアセンブラ基本並進ベクトルブラべ格子単振り子熱伝導位相図TLP621キュリー温度繰り返し状態方程式MaximaVESTAスイッチト・キャパシタ相対論FETランダムウォークスピン軌道相互作用SMP六方最密充填構造抵抗不規則合金ewidthスレーターポーリング曲線GGAラプラス方程式cygwingfortranQSGW失敗談コバルト条件分岐TLP521テスタLM555Writer509TLP552格子比熱マントルデータロガー自動計測詰め回路ガイガー管ダイヤモンドQNAPMCUFXA-7020ZR過渡解析三角波UPSNE555固有値問題熱力学ブラウン運動フェルミ面awk起電力第一原理計算OpenMPfsolveubuntu最大値xcrysden最小値最適化仮想結晶近似VCA差し込みグラフスーパーセル井戸型ポテンシャル平均場近似シュレディンガー方程式FSMフラクタルOPA2277固定スピンモーメント2SC1815全エネルギー合金multiplotgnuplotc/aTeX結晶磁気異方性interp1ウィグナーザイツ胞初期値マンデルブロ集合疎行列面心立方構造fcc不純物問題非線型方程式ソルバフィルタL10構造PGA半金属二相共存SICZnOウルツ鉱構造BaO重積分クーロン散乱磁気モーメント電荷密度三次元CIF岩塩構造CapSenseノコギリ波デバイ模型ハーフメタル正規分布フォノンquantumESPRESSOルチル構造スワップ領域リジッドバンド模型edelt縮退キーボード軸ラベルグラフの分割凡例トラックボールPC不規則局所モーメント片対数グラフトランス両対数グラフCK1026MAS830L直流解析Excel円周率パラメータ・モデルヒストグラム日本語最小二乗法等価回路モデルGimp線種シンボルTS-110TS-112PIC16F785LMC662化学反応文字列specx.f入出力ifortマテリアルデザインヒストグラム確率論Realforce等高線ジバニャン方程式P-10Ubuntuナイキスト線図Crank-Nicolson法陰解法熱拡散方程式HiLAPWAACircuit連立一次方程式負帰還安定性境界条件EAGLEMBE関数フィッティング

最新コメント
リンク

にほんブログ村 その他趣味ブログ 電子工作へ