Scilabでガウス型波束の散乱

Scilabを用いて初期波動関数がガウス型をしている波束が、ポテンシャルの谷によって散乱される様子をシミュレーションしました。

001.gif

Fig.1: ガウス型波束がポテンシャルの谷間によって散乱される様子を表したアニメーション。赤が波動関数の絶対値、緑が波動関数の実部を表す。青はポテンシャルの形状。



偏微分方程式


ねがてぃぶろぐでは微分方程式による物理現象のモデル化(PDF)で紹介されている常微分方程式をScilabで計算してきました。
次のテーマである波束の運動の問題は、時間微分だけの常微分方程式ではなく、時間と空間の両方の微分を含む偏微分方程式です。

ScilabやOctaveには偏微分方程式を解くための特別な関数は用意されていません。そこで、偏微分方程式を解くためには微分を差分に置き換えた計算が必要になります。Scilabで一次元井戸型ポテンシャルScilabで規則ポテンシャルと縮退では位置の微分であるエネルギー演算子を含むハミルトニアンを行列で表すことによって、固有値問題を解くための命令であるspecを利用することにより計算しました。

今回はScilabで一次元井戸型ポテンシャルと同様にハミルトニアンを行列であらわし、常微分方程式ソルバodeと組み合わせることにより、時間に依存するシュレディンガー方程式を解いてガウス型波束が散乱される様子をシミュレーションします。


ガウス型波束の運動


シッフの量子力学の本(上巻 下巻)によるとx軸の正の方向に運動量を持つ波束の波動関数は以下のように表されます。

\psi(x) = \frac{1}{\sqrt[4]{2 \pi (\Delta x)^2}} \exp\left(- \frac{(x-\langle x \rangle)^2}{4(\Delta x)^2}+\frac{i\langle p \rangle}{\hbar}x \right)

今回は、このガウス型波束を初期値に持つ波動関数がポテンシャルの谷に散乱される様子をScilabを用いてシミュレーションします。


時間に依存するシュレディンガー方程式


時間に依存するシュレディンガー方程式は、以下の様に表されます。

i \hbar \frac{\partial \psi (x,t)}{\partial t} = \left(- \frac{\hbar}{2m}\frac{\partial^2}{\partial x^2} + V(x) \right)\psi(x,t)

時間に依存しないシュレディンガー方程式の場合と同様に

\hbar = 1, m = \frac{1}{2}

とおくと、ハミルトニアンHは以下のようにかけます。

H = - \frac{\partial^2}{\partial x^2} + V(x)

この段階で時間に依存するシュレディンガー方程式は以下のように書くことが出来ます。

i\frac{\partial \psi}{\partial t} = H \psi

ここまでくればScilabの常微分方程式ソルバodeで解けることが分かります。
dψ/dt = ...の形にすると

\frac{\partial \psi}{\partial t} = -i H \psi

となり、これが今回の解くべき方程式となります。

微分方程式による物理現象のモデル化(PDF)によるとOctaveの常微分方程式ソルバであるlsodeは複素数に対応していないとのことですが、Scilabのodeは複素数に対応しているので、今回はodeを利用してシュレディンガー方程式を解きます。


疎行列


Scilabで一次元井戸型ポテンシャルで書いたとおり、ハミルトニアンを行列として書き下すと、以下のようにほとんどの成分がゼロとなります。

\begin{eqnarray*} H &=& - \frac{\mathrm{d}^2}{\mathrm{d}x^2} + V \\ &=& \left( \begin{array}{ccccccc} \frac{2}{h^2} + v_1 & -\frac{1}{h^2} & 0 & \hdots & & \hdots & 0 \\ -\frac{1}{h^2} & \frac{2}{h^2} + v_2 & -\frac{1}{h^2} & 0 & \hdots & & \vdots \\ 0 & -\frac{1}{h^2} & \frac{2}{h^2} + v_3 & -\frac{1}{h^2} & 0 & \hdots & \\ \vdots & \ddots & \ddots & \ddots & \ddots & \ddots & \vdots \\ & \hdots & 0 & -\frac{1}{h^2} & \frac{2}{h^2} + v_{n-2} & -\frac{1}{h^2} & 0 \\ \vdots &  & \hdots & 0 & -\frac{1}{h^2} & \frac{2}{h^2} + v_{n-1} & -\frac{1}{h^2} \\ 0 & \hdots &  & \hdots & 0 & -\frac{1}{h^2} & \frac{2}{h^2} + v_n \end{array} \right) \end{eqnarray*}

このようにゼロでない要素が全体の中でごくわずかしかない行列を疎行列と呼びます。Scilabでは疎行列を扱う特別なデータ型があり、普通に定義した行列に対して

sp = sparse(X);


とすることによって疎行列へ変換することが出来ます。(参考:sparse)

今回の計算のハミルトニアンのようにゼロとなる要素が多い場合は、疎行列型へ変換することにより計算速度が劇的に速くなります。


数値計算


微分方程式による物理現象のモデル化(PDF)のように100stepごとに700ステップまで表示するScilabのプログラムがschiff-gv_sce.txtです。

clear;

vw = 0.064; // ポテンシャルの幅
vh = - (70.7 * %pi) ^ 2; // ポテンシャルの深さ
dim = 500; // 空間の分割数
h = 2.0 / dim; // 空間の刻み幅

// *** 位置ベクトル ***
X = linspace(-1,1,dim + 1);

// *** ハミルトニアンの定義 ***
// エネルギー演算子
vd = 2 / h ^ 2;
vdt = - 1 / h ^ 2;
SD = diag(vdt * ones(1,dim),1);
D = diag(vd * ones(1,dim + 1));
H = SD + D + SD.';
// ポテンシャル
V = zeros(H);
for i = 1:dim + 1 do
if abs(X(i)) < vw / 2 then
V(i,i) = vh;
end
end
// 全ハミルトニアン
H = sparse(H + V); // 疎行列へ変換するほうが実行速度が速い

// *** 常微分方程式の定義 ***
function dphi = schiff(t,phi)
dphi = - %i * H * phi;
endfunction

// *** 波束の初期設定 ***
xe = - 0.3; // 初期波束の位置の期待値(波束の中心位置)
dx = 0.035; // 初期波束の空間的広がり
pe = 50 * %pi; // 初期波束の運動量の期待値
phi0 = zeros(dim + 1,1);
for k = 1:dim + 1 do
// 初期波束
phi0(k) = exp(-(X(k) - xe) ^ 2 / (4 * dx ^ 2) + %i * pe * X(k)) ..
/ (2 * %pi * (dx) ^ 2) ^ 0.25;
end

// *** 時間刻みの設定 ***
dt = h ^ 2 / 4;
nstep = 700;
itvl = 100;
tf = dt * itvl;
T = [0:dt:tf];

// *** プロット ***
// ポテンシャルのプロット
subplot(3,3,1);
plot(X,diag(V));
// 目盛りを非表示にする
g = gca();
g.axes_visible = 'off';
zoom_rect([-0.5,-5,0.5,5]);
// 初期値のプロット
subplot(3,3,2);
plot(X,diag(V)); // ポテンシャルのプロット
plot(X,real(phi0),'-g'); // 波動関数の実部のプロット
plot(X,abs(phi0),'-r'); // 波動関数の絶対値のプロット
// ステップ数を表示
xstring(0.1,3,"step = 0");
// 目盛りを非表示にする
g = gca();
g.axes_visible = 'off';
zoom_rect([-0.5,-5,0.5,5]);

for k = 1:nstep/itvl do
// 微分方程式の数値解
phi = ode(phi0,0,T,schiff);
// ポテンシャルと波動関数のプロット
subplot(3,3,k + 2);
plot(X,diag(V)); // ポテンシャルのプロット
plot(X,real(phi(:,itvl)),'-g'); // 波動関数の実部のプロット
plot(X,abs(phi(:,itvl)),'-r'); // 波動関数の絶対値のプロット
// ステップ数を表示
stepnum = string(k * itvl);
xstring(0.1,3,strcat(["step = ",stepnum]));
// 目盛りを非表示にする
g = gca();
g.axes_visible = 'off';
zoom_rect([-0.5,-5,0.5,5]);
// 最後の波動関数を次の初期値に設定
phi0 = phi(:,itvl);
end


Fig.1のGIFアニメーションはschiff-gv-gif_sce.txtで作成したGIF画像をGimpやImagemagickで結合したものです。
Scilabの計算結果をGIFアニメーションにする方法はのちのち別のエントリにまとめようと思っています。

GIF動画に関連する情報は以下のリストにあります。


関連エントリ




参考URL




付録


このエントリで使用したScilabのシミュレーション用ファイルを添付します。ファイル名末尾の".txt"を削除して、"_"を"."に変更すれば使えるはずです。(参考:ねがてぃぶろぐの付録)


参考文献/使用機器




フィードバック



にほんブログ村 その他趣味ブログ 電子工作へ

 ↑ 電子工作ブログランキング参加中です。1クリックお願いします。


コメント・トラックバックも歓迎です。 ↓      


 ↓ この記事が面白かった方は「拍手」をお願いします。


tag: Scilab ode 常微分方程式 偏微分方程式 疎行列 量子力学 

comment

Secret

No title

はじめまして。scilabを勉強中で、こちらのブログを大変参考にさせて頂いてます。
現在この記事のプログラムのように、複素数を含む微分方程式を解こうとしています。
そこでschiff-gv.sceを試しに動かしてみたのですが、
ode: external must be real
のエラーが出てしまいます。何か対処法がありましたらご教示頂けると幸いです。

Re: No title

通りすがりさん、こんにちは。

Scilab 5.5.1ではエラーが出るようになってしまいました。
エントリのコードはWindows版のScilab 5.4.1ではとりあえず動いてはいるので、対処療法的にはScilabをダウングレードするのが一番手っ取り早いです。

Scilabはバージョンごとに別ディレクトリにインストールされるので、共存は比較的簡単です。
http://www.scilab.org/download/5.4.1

取り急ぎ。

ご返答ありがとうございます

おかげさまで無事解決しました。
ありがとうございました。
FC2カウンター
カテゴリ
ユーザータグ

LTspiceAkaiKKRmachikaneyamaScilabKKRPSoC強磁性CPAPICOPアンプecalj常微分方程式モンテカルロ解析状態密度トランジスタodeDOSインターフェース定電流スイッチング回路PDS5022半導体シェルスクリプト分散関係レベルシフト乱数HP6632AR6452A可変抵抗トランジスタ技術温度解析ブレッドボードI2C反強磁性確率論数値積分セミナーバンドギャップバンド構造偏微分方程式非線形方程式ソルバ熱設計絶縁ISO-I2Cカオス三端子レギュレータLM358GW近似マフィンティン半径A/DコンバータフォトカプラシュミットトリガLEDPC817C発振回路数値微分直流動作点解析サーボカレントミラーTL431アナログスイッチUSB74HC4053bzqltyVESTA補間電子負荷アセンブライジング模型BSch量子力学単振り子2ちゃんねるチョッパアンプLDA開発環境基本並進ベクトルFFT標準ロジックブラべ格子パラメトリック解析抵抗SMPMaxima失敗談ラプラス方程式繰り返し位相図スイッチト・キャパシタ熱伝導状態方程式キュリー温度gfortranコバルトTLP621不規則合金Quantum_ESPRESSO六方最密充填構造ランダムウォーク相対論ewidthスピン軌道相互作用FETQSGWVCAcygwinスレーターポーリング曲線GGA仮想結晶近似PWscfシュレディンガー方程式LM555ハーフメタル固有値問題NE555最小値ガイガー管QNAPUPS自動計測ダイヤモンドマントルTLP552格子比熱最適化MCU井戸型ポテンシャル最大値xcrysdenCIF条件分岐詰め回路フェルミ面差し込みグラフスーパーセルfsolveブラウン運動awk過渡解析起電力三角波第一原理計算FXA-7020ZRWriter509Ubuntuテスタ熱力学データロガーTLP521OpenMPubuntu平均場近似MAS830LトランスCK1026PIC16F785PGA2SC1815EAGLEノコギリ波負帰還安定性ナイキスト線図MBEOPA2277P-10フィルタCapSenseAACircuitLMC662文字列固定スピンモーメントFSMTeX結晶磁気異方性全エネルギーc/a合金multiplotgnuplot非線型方程式ソルバL10構造正規分布等高線ジバニャン方程式初期値interp1fcc面心立方構造ウィグナーザイツ胞半金属デバイ模型電荷密度重積分SIC二相共存磁気モーメント不純物問題PWgui擬ポテンシャルゼーベック係数ZnOウルツ鉱構造edeltquantumESPRESSOフォノンリジッドバンド模型スワップ領域BaO岩塩構造ルチル構造ヒストグラム確率論マテリアルデザインフラクタルマンデルブロ集合キーボードRealforceクーロン散乱三次元疎行列縮退化学反応関数フィッティング最小二乗法Excel直流解析PCTS-110TS-112日本語パラメータ・モデル等価回路モデルcif2cell入出力陰解法熱拡散方程式HiLAPW両対数グラフCrank-Nicolson法連立一次方程式specx.fifort境界条件片対数グラフグラフの分割円周率ヒストグラム不規則局所モーメントGimpシンボル軸ラベル凡例線種トラックボール

最新コメント
リンク

にほんブログ村 その他趣味ブログ 電子工作へ