LTspiceで74HC4053 その５

前回ついに以下の回路図までこぎつけました。

今回はその２やその３で行ったのと逆の作業、すなわち回路図からサブサーキットファイルへの変換を行います。

.include hc_tnomi.cir

.SUBCKT 74HC4053 INH SEL CH0 CH1 COM VDD VSS VEE
XINP0 SEL0 SEL1 VDD0 VSS0 INP2N
XINP1 INH0 INH1 VDD0 VSS0 INP2N
XINV SEL1 SEL2 VDD0 VSS0 INVN
XNAND0 INH1 SEL2 CH00 VDD0 VSS0 NANDN
XNAND1 INH1 SEL1 CH10 VDD0 VSS0 NANDN
XLC0 CH00 CH01 VEE0 VDD0 VSS0 LLCN
XLC1 CH10 CH11 VEE0 VDD0 VSS0 LLCN
XAS0 CH01 CH0 COM VEE0 VDD0 SWITCH1N
XAS1 CH11 CH1 COM VEE0 VDD0 SWITCH1N
L1 VDD VDD0 6.08NH
L2 VEE VEE0 6.08NH
L3 VSS VSS0 6.08NH
L4 SEL SEL0 4.28NH
L5 INH INH0 4.28NH
C1 VDD VDD0 1.5P
C2 VEE VEE0 1.5P
C3 VSS VSS0 1.5P
C4 SEL0 VSS 1.5P
C5 INH0 VSS 1.5P
C6 CH0 VSS 1.5P
C7 CH1 VSS 1.5P
C8 COM VSS 1.5P
.ENDS

以上のようになりました。この引用部分を"74hc4053.sub"という名前のファイルとして"C:\Program Files\LTC\SwCADIII\lib\sub"へ保存します。LTspiceをインストールしたディレクトリが異なる場合は適宜読み替えてください。

ではサブサーキットファイルの中身を順番に見ていきます。
1行目の".include hc_tnomi.cir"の"hc_tomi.cir"はNXP Semiconductorsからダウンロードした"hc.zip"を解凍した中身のファイルのひとつです。

"74hc4053.sub"は"hc_tomi.cir"で定義されるサブサーキットを呼び出しています。そのため、あらかじめ".include"命令でファイルの結合を行う必要があります。

次に".SUBCKT"行があります。サブサーキット名は"74HC4053"としました。
この後に続くノード名がサブサーキット"74HC4053"の外部へ出力する端子となります。また、ここに書かれた順番が外部から呼び出されるときの"Netlist Order"となります。

これ以降はその２で書いたとおりの書式なので特に問題は無いでしょう。

tag: LTspice 74HC4053 アナログスイッチ

Pagetop

LTspiceで74HC4053 その４

LTspiceで74HC4053 その１その２その３の続編です。

前回までにNXP Semiconductorsに配布されている状態の74HC4053に相当するサブサーキットであるSWI1がどういう構造になっているかを確認しました。

SWI1はロジック部分が省略されているモデルなので、74HC4053を含む回路図の該当部分に直接利用することが出来ません。
今回は、SWI1にロジック部分を補ったサブサーキットを作成することを目的にします。

東芝セミコンダクタの74HC4053のページから74HC4053のデータシートをダウンロードしてください。和文データシートの4ページ目にシステム図という項目があります。74HC4053は一番下になります。

東芝セミコンダクタ74HC4053データシートより引用

このシステム図では2chアナログマルチプレクサが3回路入っていますが、LTspice用のサブサーキット化する際には1回路分だけを使うことにします。
1回路分だけを取り出したものが以下になります。

サブサーキット用のテキストファイルに変換しやすいようにあらかじめすべてのノードに名前をつけておきます。
1枚目のシステム図と比べてXINVの挿入位置が逆であるように見えますが、スイッチの切り替えロジックの都合です。気にしないでください。

tag: LTspice 74HC4053 アナログスイッチ

Pagetop

まずは、前回までのおさらいです。
2chアナログスイッチ74HC4053の機能のうち、アナログ信号を切り替えるスイッチの部分のみがモデル化されています。
したがって、74HC4053へのデジタル信号入力に対してどのスイッチをON/OFFするかのロジック部分は自分で作らなければいけません。
また、このロジック部分を除いたサブサーキットはSWI1という名前で用意されており、これはロジック部分の入力端子のリードインダクタンスや寄生容量までモデル化されています。

このうちその１では、どのようなロジック部分を作ればよいのかを考えました。
またその２では、74HC04を例にリードインダクタンスや寄生容量を考慮したサブサーキットが.subcktによってどのように記述されるかを見ました。

今回はロジック部分を含まないSWI1を回路図に直すことにします。

以下の引用部分はhc_tmomi.cirのなかのSWI1の部分です。

.SUBCKT SWI1  2  3  4  70  80  90
* INP = 2  Y = 3  Z = 4  VEE = 70  VCC = 80  GND = 90
XINP 20  25  50  60      INP2N
XLC  25  30  40  50  60  LLCN
XAS  30   3   4  40  50  SWITCH1N
L1  80  50   6.08NH
L2  70  40   6.08NH
L3  60  90   6.08NH
L4   2  20   4.28NH
C1  50  90   1.5P
C2  40  90   1.5P
C3  60  90   1.5P
C4  20  90   1.5P
C5  3   90   1.5P
C6  4   90   1.5P
.ENDS

大雑把な構成は、「入力バッファ」「レベルシフタ」「アナログスイッチ」および「各入出力端子のリードインダクタンスと寄生容量」です。

このサブサーキットを回路図に描き直しました。

レベルシフタとしてNon-Inv Bufferの記号をつかっていますが、出力の論理やアナログスイッチの入力論理がどうなっているかは確認していません。それぞれの記号がLLCNとSWITCH1Nのサブサーキットを表していると解釈してください。

tag: LTspice 74HC4053 アナログスイッチ

Pagetop

LTspiceで74HC4053 その２

タイトル通りLTspiceで74HC4053 その１の続きです。
前回のおさらいをすると、ベルが鳴る様の標準 CMOS ロジックのトランジスターモデルを参考にNXP Semiconductorsからダウンロードした74HCシリーズのSPICEモデル、特に74HC4053をLTspiceで使うというものです。

NXP SemiconductorsからダウンロードできるSPICEモデルのうち74HC04等の一部の基本的な機能を持つものは、特に追加の回路を記述しなくても端子のリードインダクタンスや寄生容量までモデル化されています。

次の目標は74HC4053の端子のリードインダクタンスや寄生容量を考慮したモデルを作ることにします。
今回は、その前段階として74HC04のモデルについて見てみます。

74HC04に相当するサブサーキットは74hct.cirからINV1と分かります。上図はINV1を回路図に描き直したものです。
各ノードにラベルで数字を割り振ってあります。

.SUBCKT INV1 2 3 80 90
*IN=2, OUT=3, VCC=80, GND=90
XINP 20 25 50 60 INP1N
XINV 25 35 50 60 INVN
XOUTP 35 40 50 60 OUTPN
L1 80 50 6.87NH
L2 60 90 6.87NH
L3 2 20 5.97NH
L4 40 3 5.97NH
C1 50 90 1.5P
C2 60 90 1.5P
C3 20 90 1.5P
C4 3 90 1.5P
.ENDS

上の引用部がhc_tmomi.cirのなかのINV1の.SUBCKT部分です。
spice3f5マニュアルの日本語訳をAyumi's Lab.さまが公開しています。PDF版もあるのでぜひダウンロードしましょう。
.SUBCKTの解説部分は2.4 サブ回路にあります。

.SUBCKTから.ENDSの間には12行ありますが、これらは4種類の要素に分けられます。
「コメント」「外部サブサーキットの呼び出し」「インダクタ」「コンデンサ」です。

*で始まる行はコメントです。この行はSPICEに評価されません。
しかし、人間からみると重要な情報です。.SUBCKT行のサブ回路名の後に続く「2」「3」「80」「90」はINV1と外部を接続するノード番号ですが、これらがそれぞれ何をさすかが書いてあります。私のかいた回路図でも「IN=2」の様に役割とノード番号を対応させて書いておきました。
ここで注意しておかなければならないのはGNDと名付けられているノードであるノード90番は、グローバルノード0番ではなく、単純にGND端子をあらわすノードであることです。このことにより、INV1サブ回路を呼び出す回路でGND端子を回路のGND
以外に接続することが出来るようになります。

XINPの様にXから始まる行は、サブサーキットの呼び出しです。呼び出されるサブサーキットの名前は行の最後に書いてあります。
XINPの場合は、INP1Nを呼び出していることになります。これはhc_tmomi.cirの内部で.SUBCKTとして定義されていますが、現時点ではさしあたってベルが鳴るさまのサイトにある説明にあるとおり「入力保護回路+インバータ」であるという程度の理解にとどめておきます。
同様にINVNは「インバータ」、OUTPNは「出力インバーティングバッファ」です。いずれも回路図中ではNOTのMIL記号で表しました。

ここまでくれば後は想像通りLではじまるものがインダクタで、Cではじまるものがコンデンサです。
それぞれ、接続するノード番号と値が記されています。

同じノード番号同士を接続すると最初にあげた回路図のようになります。

関連

LTspiceで74HC4053 その１

tag: LTspice 74HC4053 アナログスイッチ

Pagetop

LTspiceで74HC4053　その１

アナログスイッチとして74HC4053のシミュレーションをすることを目的にします。
楽勝かと思ったら、ぜんぜんそんなことありませんでした。
その１となってますが、その２以降は書けないかもしれません。

教科書とするものは、ベルが鳴るさんの標準 CMOS ロジックのトランジスターモデルです。

まずはNXP SemiconductorsのページがからHC(T)をクリックしてhc.zipをダウンロードし解凍します。すると5つのファイルが出てきます。

それらの内訳は、readme.txtと1つのテスト用回路例(hct.cir)と3つのモデルライブラリ(hc_tslow.cir,hc_tnomi.cir,hc_tfast.cir)です。3つのモデルライブラリはすべて同一のIC郡をモデル化したものですが、私には何が違うのかよく分かりません。さしあたってnormalと書いてあるhc_tnomi.cirのみを使います。

hc_tnomi.cir内部の構造はベルが鳴るさんの解説のとおり3段階の構造を持っています。下部構造から順に以下のようになります。
(1) FET等の回路素子
(2) (1)を用いて作った論理ゲートやアナログスイッチ
(3) (2)にさらにパッケージのリードインダクタンスや寄生容量を加味したもの

74HC4053に対応するsubcktは、hct.cirに書いてあるとおりSWI1です。しかし、ちょっと待ってください。実を言うと74HC4051と74HC4012もおなじSWI1が対応しているとなっています。
もちろん、2chアナログマルチプレクサと4chアナログマルチプレクサ、8chアナログマルチプレクサが同じものであるはずがありません。

Hct.cir の注釈にある通り、内部機能 (論理演算や FF 機能) はモデル化されていませんし、

というのはつまるところそういうことです。NXP Semiconductorsからダウンロードできるモデルは、アナログマルチプレクサの内部のアナログスイッチの部分や、内部の論理回路部分を構成するゲートだけです。
したがって、2chアナログマルチプレクサである74HC4053のシミュレーションをするためにはhc_tnomi.cirの(2)や(3)の要素を組み合わせて4段階目のサブサーキットを自分で作らなくてはいけません。

74HC4053の内部の論理回路は東芝セミコンダクタの74HC4053のページからデータシートをダウンロードして確認すればわかります。
74HC4053のなかに3組あるアナログマルチプレクサのうち1組だけ取り出したものがこの回路になります。