スポンサーサイト

上記の広告は1ヶ月以上更新のないブログに表示されています。
新しい記事を書く事で広告が消せます。

Scilabで非線形方程式ソルバ その3

Scilabで非線形方程式ソルバ その1その2では関数の解を非線形方程式ソルバで計算しました。
今回は、離散データに対しても似たような解を求めるために、関数の補完と組み合わせるという事を行いました。

001_201502150526487fb.png
Fig.1: 離散データに対する補完と非線形方程式ソルバ



離散データのfsolve


Scilabで非線形方程式ソルバ その1その2では関数 f(x) がゼロとなる x を探す方法を書きました。今回は f(x) が具体的な関数の形ではなく、離散データとして与えられている場合について書きます。

と言ってもやっていることは簡単で、離散データを内挿(補間)してから解を求めるだけです。

今回はScilabで非線形方程式ソルバ その1との比較のために対数関数を例にしますが、実際の離散データは実験データであったり、複雑な数値計算(例えば第一原理計算や回路シミュレーション)の結果得られる数値列を想定します。

離散データの補完にはScilabでデータの補間で紹介したinterp1を利用します。
interp1の補間方法のデフォルトは線形補完(linear)のようです。今回のエントリでは最近接(nearest)は使えません。

スクリプト


スクリプトはlogsolve2_sce.txtとなりました。

今回は、離散データ自体もスクリプト内部で用意しましたが、実験データや、ほかの数値データを読み込む場合にはExcelデータを Scilabで読みこむScilabで大容量のCSV(テキスト)ファイルを読み込む,Scilabで大容量のCSV(テキスト)ファイルを読み込む2などを参照してください。

clear;

// *** データの作成 ***
X = linspace(0.1,10,15);
Y = log(X);

// *** 解くべき関数の定義 ***
function y = func(x)
// y = log(x) - yp;
// y = interp1(X, Y, x, "spline") - yp; // スプライン補完
y = interp1(X, Y, x, "linear") - yp; // 線形補完
endfunction

// *** 非線形方程式ソルバ ***
yp = 1; // yp = f(x)
x0 = 1; // ソルバ―の初期値
// 非線形方程式を解く
xp = fsolve(x0, func)
// 誤差
err = abs(xp - exp(yp))

// *** グラフのプロット ***
plot(X, Y, '.-b');
plot(X, yp * ones(Y), '--k');
plot(xp, yp, 'or');


結果


所詮、離散的な数値データから間の値を予測するだけなので、Scilabで非線形方程式ソルバ その1と比較すると結果に誤差が出ます。

線形補完を行った時の近似解と、真の値からの誤差は以下のようになりました。
 xp  =    2.737908
err = 0.0196261


スプライン補完を行った場合は、以下の通りです。
 xp  =    2.7130249
err = 0.0052569


今回の例ではスプライン補完の方が良い結果が得られているようです。

関連エントリ




参考URL




付録


このエントリで使用したScilabのシミュレーション用ファイルを添付します。ファイル名末尾の".txt"を削除して、"_"を"."に変更すれば使えるはずです。(参考:ねがてぃぶろぐの付録)


参考文献/使用機器




フィードバック



にほんブログ村 その他趣味ブログ 電子工作へ

 ↑ 電子工作ブログランキング参加中です。1クリックお願いします。


コメント・トラックバックも歓迎です。 ↓      


 ↓ この記事が面白かった方は「拍手」をお願いします。
スポンサーサイト

tag: Scilab 非線形方程式ソルバ 補間 fsolve interp1 

Scilabで非線形方程式ソルバ その2

Scilabで非線形方程式ソルバ その1では、(解析的に解を得ることも可能な)非常に簡単な関数についてソルバ―を用いて解を求めました。

しかし前回の関数は、得られる解が一つだけでした。
では、解が二つ以上得られる場合、例えば二次関数の解を求める場合はどうなるのでしょうか?

002_20150212083236a8a.png

Fig.1: y = x2 と y = 1 の交点のx座標を計算した結果(上)。非線形方程式ソルバに与えた初期値x0とその結果として得られる解の関係(下)。


結論から言うと、非線形方程式ソルバでは解が一つしか得られず、その値はパラメータとして与える初期値に依存します。得られる解は、与えた初期値に近い値となりますが、必ずしも最も近い値になるというわけではないようなので、初期値の選び方は慎重に行う必要があります。


初期値の重要性


Scilabで非線形方程式ソルバ その1では、単純な対数関数の解を非線形方程式ソルバ―を用いて計算し、解析解と一致することを確認しました。

今回は x2 - 1 = 0 の解が、初期値 x0 の値によってどのように変化するかを確認します。

今回の記事で着目する二次関数と対数関数の違いは、得られる解が一つであるか二つであるかという事です。
Scilabの非線形方程式ソルバーは、数値的に解の近似値を計算するため、実際には複数の解が存在する場合であっても解が一つしか出てきません。
多くの場合、物理的に意味のある解は一つだけだったりするのですが、上手く重要な解を得るためには、初期値をどのように設定するかが重要になります。

x2 - 1 = 0 の解は当然ながら x=1 と x=-1 の二つなのですが、ソルバ―に与える初期値に応じてどちらの解が得られるかを確認するのが今回のエントリの趣旨です。

なお、多項式のすべての解をすべて一気に計算するための命令もScilabには用意されています。(参考: roots)

スクリプト


今回計算するSciabスクリプトはparabolicsolve_sce.txtです。

clear;

// *** データの作成 ***
X = linspace(-2,2);
Y = X .^ 2;

// *** 解くべき関数の定義 ***
function y = func(x)
y = x .^ 2 - yp;
endfunction

// *** 非線形方程式ソルバ ***
yp = 1; // yp = f(x)
x0 = 2; // ソルバ―の初期値
// 非線形方程式を解く
xp = fsolve(x0, func)

// *** 非線形方程式の初期値依存性 ***
X0 = X;
XP = fsolve(X0, func);

// *** グラフのプロット ***
subplot(2,1,1);
plot(X, Y, '-b');
plot(X, yp * ones(Y), '--k');
plot(xp, yp, 'or');
xlabel("x")
ylabel("y")

subplot(2,1,2);
plot(X0, XP, '-or')
xlabel("x0")
ylabel("xp")


結果


結果は、冒頭に紹介したFig.1です。
注目すべきは下のパネルの x0 = 0 近傍の挙動です。
必ずしも最も近い解が得られるわけではなく、初期値の微妙な変化で得られる解が振動していることがわかります。

なお、とにかくたくさん解がありそうな場合は、グラフを描いてみるのが良いです。Scilabでジバニャン方程式は f(x,y) = 0 となる x と y の組み合わせをすべてプロットしたものです。

関連エントリ




参考URL




付録


このエントリで使用したScilabのシミュレーション用ファイルを添付します。ファイル名末尾の".txt"を削除して、"_"を"."に変更すれば使えるはずです。(参考:ねがてぃぶろぐの付録)


参考文献/使用機器




フィードバック



にほんブログ村 その他趣味ブログ 電子工作へ

 ↑ 電子工作ブログランキング参加中です。1クリックお願いします。


コメント・トラックバックも歓迎です。 ↓      


 ↓ この記事が面白かった方は「拍手」をお願いします。

tag: Scilab 非線形方程式ソルバ fsolve 初期値 

Scilabで非線形方程式ソルバ その1

Scilabの非線形方程式ソルバfsolveは任意の関数 f(x) に対して f(x) = 0 となるxを探すことができます。

これまで比較的複雑なプログラムでfsolveを使っていたので、簡単な例について書いておきます。

001_20150205220744dcb.png

Fig.1: y = ln(x) と y = 1 の交点のx座標を計算した結果



簡単な例題


これまで既に非線形方程式ソルバを利用してきました。
しかしこれらは、比較的複雑な使用例だったので、今回は簡単な例について説明します。

非線形方程式ソルバ―fsolveを用いれば y=f(x) の形で表されている関数を解くことができます。
方程式を解くとは y=0 となるxを探すという事です。fsolveはyがベクトルであっても y がゼロベクトルとなるxの組を計算してくれます(例: Scilabでおもりの吊り下げ)。しかし、今回は簡単な例ということでx, yはスカラーとします。
なお任意の定数 y = yp となるときの x = xp を探すには 0 = f(xp) - yp を解けばよいことになります。

今回は具体的な関数の形として f(x) = ln(x) を考え、yp=1 となる x = xp を求めることから始めます。
もちろんこれは、数値計算を行うまでもなく高校数学の知識を用いれば xp = exp(1) = 2.71828... という解がすでに分かっているわけですが、同じ方法を用いればもっと複雑で、簡単には解がわからない関数も数値的に解を得ることができます。

プログラミング


このScilabスクリプトはlogsolve_sce.txtのようになりました。

clear;

// *** データの作成 ***
X = linspace(0.1,10);
Y = log(X);

// *** 解くべき関数の定義 ***
function y = func(x)
y = log(x) - yp;
endfunction

// *** 非線形方程式ソルバ ***
yp = 1; // yp = f(x)
x0 = 1; // ソルバ―の初期値
// 非線形方程式を解く
xp = fsolve(x0, func)
// 誤差
err = abs(xp - exp(yp))

// *** グラフのプロット ***
plot(X, Y, '-b');
plot(X, yp * ones(Y), '--k');
plot(xp, yp, 'or');



関連エントリ




付録


このエントリで使用したScilabのシミュレーション用ファイルを添付します。ファイル名末尾の".txt"を削除して、"_"を"."に変更すれば使えるはずです。(参考:ねがてぃぶろぐの付録)


参考文献/使用機器




フィードバック



にほんブログ村 その他趣味ブログ 電子工作へ

 ↑ 電子工作ブログランキング参加中です。1クリックお願いします。


コメント・トラックバックも歓迎です。 ↓      


 ↓ この記事が面白かった方は「拍手」をお願いします。

tag: Scilab 非線形方程式ソルバ 

Scilabで床で跳ねるボール

matlab 衝突のシミュレーションで質問された床ではねるボールのシミュレーションをScilabで行いました。

001_2015012510244301d.png
Fig.1: 跳ねるボールのシミュレーション


この問題は、常微分方程式ソルバodeと非線形方程式ソルバfsolveの二つを組み合わせることによってシミュレーションすることができます。


問題設定


高さx0から初速度v0でボールを投げる。ボールは重力加速度gで下方へ引かれ、床に落下する。落下したボールは、反発係数kで上方へ跳ねるとする。

この問題はmatlab 衝突のシミュレーション跳ねるボールのシミュレーションです。今回のエントリでは、この問題をScilabでシミュレーションします。

常微分方程式ソルバ


まず前半部分の放物運動は、常微分方程式ソルバodeを用いて簡単に計算できます。(参考: 常微分方程式タグ)

解くべき連立常微分方程式は以下のようになります。

\frac{\mathrm{d}x}{\mathrm{d}t} = v
\frac{\mathrm{d}v}{\mathrm{d}t} = -g

非線形方程式ソルバ


次に床で跳ねる計算を行います。
床ではねる直前の速度をv-,直後の速度をv+とすると反発係数kを用いて

v+ = - k v-

となります。

前述の常微分方程式を非線形方程式ソルバfsolveを利用して x=0 となる時刻を計算し、それぞれの跳ねるイベントの間の計算を行えば、この問題を解くことができます。

プログラム


結局Scilabスクリプトはball_sce.txtとなりました。

clear;

// *** 計算条件 ***
g = 9.81; // 重力加速度
k = 0.8; // 反発係数
// 時間
ts = 0; // 開始時刻
te = 10; // 終了時刻
// 初期条件
x0 = 10; // 初期位置
v0 = 15; // 初速度

// *** 常微分方程式の定義 ***
function dx = fall(t,x)
dx(1) = x(2); // dx/dt = v
dx(2) = -g; // dv/dt = -g
endfunction

// *** 解くべき非線形方程式 ***
function x = bound(t)
X = ode([x0; v0], ts, t, fall);
x = X(1);
endfunction

// *** メイン ***
// 初期化
tb = ts; // 衝突時刻
X = []; // プロット用の位置と速度
T = []; // プロット用の時間
// 終了時刻まで繰り返し
while tb < te
// 衝突時刻を計算
tb = fsolve(2 * te, bound);
// プロット用の時間ベクトルを作成
if tb > te then
// 終了時刻まで
time = linspace(ts, te);
else
// 衝突時刻まで
time = linspace(ts, tb);
end
T = [T, time];
// プロット用の位置と速度を計算
X = [X, ode([x0; v0], ts, time, fall)];
// 次の繰返しのための初期条件
x0 = 0; // 初期位置
v0 = -k * X(2,$); // 初速度
ts = tb; // 計算開始時刻
end

// *** グラフのプロット ***
// 位置のプロット
subplot(2,1,1);
plot(T, X(1,:),'g');
xgrid(color("gray"));
xlabel("Time");
ylabel("Position");
// 速度のプロット
subplot(2,1,2);
plot(T, X(2,:),'r');
xgrid(color("gray"));
xlabel("Time");
ylabel("Velocity");


関連エントリ




参考URL




付録


このエントリで使用したScilabのシミュレーション用ファイルを添付します。ファイル名末尾の".txt"を削除して、"_"を"."に変更すれば使えるはずです。(参考:ねがてぃぶろぐの付録)


参考文献/使用機器




フィードバック



にほんブログ村 その他趣味ブログ 電子工作へ

 ↑ 電子工作ブログランキング参加中です。1クリックお願いします。


コメント・トラックバックも歓迎です。 ↓      


 ↓ この記事が面白かった方は「拍手」をお願いします。

tag: Scilab 非線形方程式ソルバ 常微分方程式 

Scilabで二酸化炭素の状態方程式 その2

Scilabで二酸化炭素の状態方程式 その1では、Scilabを用いてファンデルワールスの状態方程式を解くプログラムを作成しました。

\left(P + \frac{a^2}{V} \right) (V-b)=RT

(P: 圧力, V: モル体積, R: 気体定数, T: 絶対温度, a, b: ファンデルワールス定数)

実はファンデルワールスの状態方程式は気体の体積だけでなく、液体や気体・液体共存のときのP,V,Tも計算することが出来ます。
この計算を行う際にMaxwellの規則を利用します(参考:ファン・デル・ワールスの状態方程式 (クラウジウス=クラペイロンの式、ジュール=トムソン効果)3.液体・気体共存領域)。Maxwellの規則ではグラフの面積が等しくなる条件を用いますが、こういった条件を探すのは、解析的には難しく、数値計算の出番となります。

004_20130811163805e0f.png

Fig.1: T = 250 (K)のときの二酸化炭素の圧力Pとモル体積Vの関係。グラフ中の赤の水平線の部分が液体・気体の共存領域、それよりも右側が気体の安定領域で左側が液体の安定領域。赤の水平線は、赤の水平線と赤の点線で囲まれた二つの領域の面積が等しくなる条件から引かれる。(Maxwellの規則)



二酸化炭素の相図


常温・常圧の二酸化炭素は気体ですが、固体の二酸化炭素といえばドライアイスです。ドライアイスは室温においておくと液体にならずに気体になりますが、5.1×105(Pa)つまり5気圧以上では水などと同様に液体になります。
以下に示すのは、ファン・デル・ワールスの状態方程式 (クラウジウス=クラペイロンの式、ジュール=トムソン効果)から引用した二酸化炭素の相図です。相図(Phase diagram, 状態図とも)は物質の状態(固体,液体,気体)と温度・圧力・化学組成の関係性を表した図です。



液体・気体共存領域


ファンデルワールスの状態方程式の1つの特徴として気体と液体の相転移を表すことができる点が挙げられます。
このときの液体、気体のそれぞれのモル体積は、Fig.1に示したとおりファンデルワールスの状態方程式と水平線の一番左の交点と一番右の交点として表されます。
またこの水平線は、水平線と状態方程式の作る二つの領域の面積が等しくなる条件から引くことが出来ます。
これをMaxwellの規則と呼び、数式で表すと以下のようになります。

\int_{V_l}^{V_g}P_{vdw}\mathrm{d}V - \int_{V_l}^{V_g}P_k \mathrm{d}V = 0

ただしPvdwがファンデルワールスの状態方程式で計算した圧力、Pkが水平線の圧力です。これらの交点のうち一番左の物が液体の体積Vlで一番右のものが気体の体積Vgです。

数値計算


色々な教科書に水平線Pkは面積が等しくなる条件から決定することが出来ると簡単に書かれていますが、Pkを決めないと交点Vg,Vlが決まらないため、Pkを決めるためには数値計算が必要です。

この計算にはScilabで金属の化学ポテンシャルScilabでおもりの吊り下げで利用した非線形方程式ソルバfsolveが使えます。

まずPkとPvdw(V)が与えられているとして3つの交点の値を求めます。
交点の値は、ファンデルワールスの状態方程式を変形して得られる以下の三次方程式の解です。

P_k V^3 - (b P_k + RT) V^2 + aV - ab = 0

Scilabでは多項式の解はrootsを用いて簡単に計算できます。解は複素数の要素を持つ縦ベクトルになります。Scilab言語には(C言語のような)型の宣言が無いのでミスを犯しやすいのですが、解の全ての要素が実部しか持たなかったとしても、変数の型としては複素数なので、realをつかって実数型へ変換する必要があります。

数値積分にはScilabで数値積分: 固体の比熱Scilabで関数フィッティング: 金属の電気抵抗で使ったintegrateを利用します。

最終的なプログラムはCO2-subcritical_sce.txtです。

clear;

// *** 入力パラメータ ***
// 物理定数
r = 8.31 // 気体定数 (J/K/mol)

// 二酸化炭素のファンデルワールス状態方程式
a = 3.65E-1; // Pa m^6 / mol^2
b = 4.28E-5; // m^3 / mol
// 温度 (K)
t = 250;

// *** ファンデルワールスの状態方程式 **
function p = pvdw(v)
p = r .* t ./ (v - b) - a ./ v ./ v
endfunction

// *** 解くべき方程式 ***
function e = func(pk)
Vx = roots([pk, -1 * (b * pk + r * t), a, - a * b]);
vg = max(real(Vx));
vl = min(real(Vx));
s1 = integrate('pvdw(v)','v',vl,vg);
s2 = (vg - vl) * pk;
e = s1 - s2;
endfunction

// *** 非線形方程式の数値解 ***
pk0 = %eps;
pk = fsolve(pk0,func);

Vx = roots([pk, -1 * (b * pk + r * t), a, - a * b]);
vg = max(real(Vx));
vl = min(real(Vx));

// *** 圧力の計算とプロット ***
// モル体積ベクトル
Vl = linspace(b,vl,1000) + %eps; // (m^3 / mol)
Vm = linspace(vl,vg,1000); // (m^3 / mol)
Vg = linspace(vg,1e-3,1000); // (m^3 / mol)
// 温度
plot(Vl,pvdw(Vl),'-r');
plot(Vm,pk,'-r');
plot(Vm,pvdw(Vm),'--r');
plot(Vg,pvdw(Vg),'-r');
// *** グラフの装飾 ***
xlabel("Molar volume (m^3/mol)");
ylabel("Pressure (Pa)");
plot([b,b],[-1E8,2E7],'--k');
plot([0,0.001],[0,0],'--k');
zoom_rect([0,-2E6,1E-3,2E7]);


関連エントリ




参考URL




付録


このエントリで使用したScilabのシミュレーション用ファイルを添付します。ファイル名末尾の".txt"を削除して、"_"を"."に変更すれば使えるはずです。(参考:ねがてぃぶろぐの付録)


参考文献/使用機器




フィードバック



にほんブログ村 その他趣味ブログ 電子工作へ

 ↑ 電子工作ブログランキング参加中です。1クリックお願いします。


コメント・トラックバックも歓迎です。 ↓      


 ↓ この記事が面白かった方は「拍手」をお願いします。

tag: Scilab 非線形方程式ソルバ 数値積分 状態方程式 熱力学 

FC2カウンター
カテゴリ
ユーザータグ

LTspiceAkaiKKRScilabmachikaneyamaKKRPSoCCPAOPアンプPIC強磁性モンテカルロ解析常微分方程式トランジスタodeインターフェース状態密度DOSecalj定電流PDS5022スイッチング回路半導体シェルスクリプト乱数レベルシフトHP6632A温度解析ブレッドボードI2CR6452A分散関係トランジスタ技術可変抵抗確率論数値積分反強磁性セミナー非線形方程式ソルバ絶縁バンドギャップ熱設計偏微分方程式バンド構造GW近似カオス三端子レギュレータLEDフォトカプラシュミットトリガISO-I2CA/DコンバータLM358USBカレントミラーTL431マフィンティン半径PC817C数値微分アナログスイッチ発振回路サーボ直流動作点解析74HC40532ちゃんねる標準ロジックチョッパアンプLDAアセンブラFFTbzqltyイジング模型ブラべ格子開発環境補間量子力学電子負荷BSchパラメトリック解析単振り子基本並進ベクトル熱伝導繰り返しGGAMaximaTLP621ewidthSMP相対論抵抗位相図ランダムウォークスピン軌道相互作用六方最密充填構造不規則合金FETコバルト失敗談QSGWcygwinスレーターポーリング曲線スイッチト・キャパシタラプラス方程式gfortranキュリー温度状態方程式条件分岐格子比熱TLP552LM555TLP521三角波NE555過渡解析FXA-7020ZRWriter509テスタ詰め回路MCUマントルダイヤモンドQNAPデータロガーガイガー管自動計測UPS井戸型ポテンシャルawk第一原理計算仮想結晶近似ブラウン運動差し込みグラフ平均場近似fsolve起電力熱力学OpenMPスーパーセル固有値問題最適化最小値VCAシュレディンガー方程式VESTAubuntu最大値面心立方構造PGAOPA2277L10構造非線型方程式ソルバ2SC1815fccフェルミ面等高線ジバニャン方程式ヒストグラム確率論マテリアルデザイン正規分布結晶磁気異方性interp1フィルタ初期値ウィグナーザイツ胞c/aルチル構造岩塩構造スワップ領域リジッドバンド模型edeltBaOウルツ鉱構造重積分SIC二相共存ZnOquantumESPRESSOCapSensegnuplotmultiplot全エネルギー固定スピンモーメントFSM合金ノコギリ波フォノンデバイ模型ハーフメタル半金属TeXifortTS-110不規則局所モーメントTS-112等価回路モデルパラメータ・モデルヒストグラムExcel円周率GimpトラックボールPC直流解析入出力文字列マンデルブロ集合キーボードフラクタル化学反応三次元Realforce縮退日本語最小二乗法関数フィッティング疎行列シンボル線種ナイキスト線図陰解法負帰還安定性熱拡散方程式EAGLECrank-Nicolson法連立一次方程式P-10クーロン散乱Ubuntu境界条件MBEHiLAPW軸ラベルトランスCK1026MAS830L凡例PIC16F785LMC662AACircuit両対数グラフ片対数グラフグラフの分割specx.f

最新コメント
リンク

にほんブログ村 その他趣味ブログ 電子工作へ
上記広告は1ヶ月以上更新のないブログに表示されています。新しい記事を書くことで広告を消せます。