Scilabでガウス型波束の散乱

Scilabを用いて初期波動関数がガウス型をしている波束が、ポテンシャルの谷によって散乱される様子をシミュレーションしました。

001.gif

Fig.1: ガウス型波束がポテンシャルの谷間によって散乱される様子を表したアニメーション。赤が波動関数の絶対値、緑が波動関数の実部を表す。青はポテンシャルの形状。



偏微分方程式


ねがてぃぶろぐでは微分方程式による物理現象のモデル化(PDF)で紹介されている常微分方程式をScilabで計算してきました。
次のテーマである波束の運動の問題は、時間微分だけの常微分方程式ではなく、時間と空間の両方の微分を含む偏微分方程式です。

ScilabやOctaveには偏微分方程式を解くための特別な関数は用意されていません。そこで、偏微分方程式を解くためには微分を差分に置き換えた計算が必要になります。Scilabで一次元井戸型ポテンシャルScilabで規則ポテンシャルと縮退では位置の微分であるエネルギー演算子を含むハミルトニアンを行列で表すことによって、固有値問題を解くための命令であるspecを利用することにより計算しました。

今回はScilabで一次元井戸型ポテンシャルと同様にハミルトニアンを行列であらわし、常微分方程式ソルバodeと組み合わせることにより、時間に依存するシュレディンガー方程式を解いてガウス型波束が散乱される様子をシミュレーションします。


ガウス型波束の運動


シッフの量子力学の本(上巻 下巻)によるとx軸の正の方向に運動量を持つ波束の波動関数は以下のように表されます。

\psi(x) = \frac{1}{\sqrt[4]{2 \pi (\Delta x)^2}} \exp\left(- \frac{(x-\langle x \rangle)^2}{4(\Delta x)^2}+\frac{i\langle p \rangle}{\hbar}x \right)

今回は、このガウス型波束を初期値に持つ波動関数がポテンシャルの谷に散乱される様子をScilabを用いてシミュレーションします。


時間に依存するシュレディンガー方程式


時間に依存するシュレディンガー方程式は、以下の様に表されます。

i \hbar \frac{\partial \psi (x,t)}{\partial t} = \left(- \frac{\hbar}{2m}\frac{\partial^2}{\partial x^2} + V(x) \right)\psi(x,t)

時間に依存しないシュレディンガー方程式の場合と同様に

\hbar = 1, m = \frac{1}{2}

とおくと、ハミルトニアンHは以下のようにかけます。

H = - \frac{\partial^2}{\partial x^2} + V(x)

この段階で時間に依存するシュレディンガー方程式は以下のように書くことが出来ます。

i\frac{\partial \psi}{\partial t} = H \psi

ここまでくればScilabの常微分方程式ソルバodeで解けることが分かります。
dψ/dt = ...の形にすると

\frac{\partial \psi}{\partial t} = -i H \psi

となり、これが今回の解くべき方程式となります。

微分方程式による物理現象のモデル化(PDF)によるとOctaveの常微分方程式ソルバであるlsodeは複素数に対応していないとのことですが、Scilabのodeは複素数に対応しているので、今回はodeを利用してシュレディンガー方程式を解きます。


疎行列


Scilabで一次元井戸型ポテンシャルで書いたとおり、ハミルトニアンを行列として書き下すと、以下のようにほとんどの成分がゼロとなります。

\begin{eqnarray*} H &=& - \frac{\mathrm{d}^2}{\mathrm{d}x^2} + V \\ &=& \left( \begin{array}{ccccccc} \frac{2}{h^2} + v_1 & -\frac{1}{h^2} & 0 & \hdots & & \hdots & 0 \\ -\frac{1}{h^2} & \frac{2}{h^2} + v_2 & -\frac{1}{h^2} & 0 & \hdots & & \vdots \\ 0 & -\frac{1}{h^2} & \frac{2}{h^2} + v_3 & -\frac{1}{h^2} & 0 & \hdots & \\ \vdots & \ddots & \ddots & \ddots & \ddots & \ddots & \vdots \\ & \hdots & 0 & -\frac{1}{h^2} & \frac{2}{h^2} + v_{n-2} & -\frac{1}{h^2} & 0 \\ \vdots &  & \hdots & 0 & -\frac{1}{h^2} & \frac{2}{h^2} + v_{n-1} & -\frac{1}{h^2} \\ 0 & \hdots &  & \hdots & 0 & -\frac{1}{h^2} & \frac{2}{h^2} + v_n \end{array} \right) \end{eqnarray*}

このようにゼロでない要素が全体の中でごくわずかしかない行列を疎行列と呼びます。Scilabでは疎行列を扱う特別なデータ型があり、普通に定義した行列に対して

sp = sparse(X);


とすることによって疎行列へ変換することが出来ます。(参考:sparse)

今回の計算のハミルトニアンのようにゼロとなる要素が多い場合は、疎行列型へ変換することにより計算速度が劇的に速くなります。


数値計算


微分方程式による物理現象のモデル化(PDF)のように100stepごとに700ステップまで表示するScilabのプログラムがschiff-gv_sce.txtです。

clear;

vw = 0.064; // ポテンシャルの幅
vh = - (70.7 * %pi) ^ 2; // ポテンシャルの深さ
dim = 500; // 空間の分割数
h = 2.0 / dim; // 空間の刻み幅

// *** 位置ベクトル ***
X = linspace(-1,1,dim + 1);

// *** ハミルトニアンの定義 ***
// エネルギー演算子
vd = 2 / h ^ 2;
vdt = - 1 / h ^ 2;
SD = diag(vdt * ones(1,dim),1);
D = diag(vd * ones(1,dim + 1));
H = SD + D + SD.';
// ポテンシャル
V = zeros(H);
for i = 1:dim + 1 do
if abs(X(i)) < vw / 2 then
V(i,i) = vh;
end
end
// 全ハミルトニアン
H = sparse(H + V); // 疎行列へ変換するほうが実行速度が速い

// *** 常微分方程式の定義 ***
function dphi = schiff(t,phi)
dphi = - %i * H * phi;
endfunction

// *** 波束の初期設定 ***
xe = - 0.3; // 初期波束の位置の期待値(波束の中心位置)
dx = 0.035; // 初期波束の空間的広がり
pe = 50 * %pi; // 初期波束の運動量の期待値
phi0 = zeros(dim + 1,1);
for k = 1:dim + 1 do
// 初期波束
phi0(k) = exp(-(X(k) - xe) ^ 2 / (4 * dx ^ 2) + %i * pe * X(k)) ..
/ (2 * %pi * (dx) ^ 2) ^ 0.25;
end

// *** 時間刻みの設定 ***
dt = h ^ 2 / 4;
nstep = 700;
itvl = 100;
tf = dt * itvl;
T = [0:dt:tf];

// *** プロット ***
// ポテンシャルのプロット
subplot(3,3,1);
plot(X,diag(V));
// 目盛りを非表示にする
g = gca();
g.axes_visible = 'off';
zoom_rect([-0.5,-5,0.5,5]);
// 初期値のプロット
subplot(3,3,2);
plot(X,diag(V)); // ポテンシャルのプロット
plot(X,real(phi0),'-g'); // 波動関数の実部のプロット
plot(X,abs(phi0),'-r'); // 波動関数の絶対値のプロット
// ステップ数を表示
xstring(0.1,3,"step = 0");
// 目盛りを非表示にする
g = gca();
g.axes_visible = 'off';
zoom_rect([-0.5,-5,0.5,5]);

for k = 1:nstep/itvl do
// 微分方程式の数値解
phi = ode(phi0,0,T,schiff);
// ポテンシャルと波動関数のプロット
subplot(3,3,k + 2);
plot(X,diag(V)); // ポテンシャルのプロット
plot(X,real(phi(:,itvl)),'-g'); // 波動関数の実部のプロット
plot(X,abs(phi(:,itvl)),'-r'); // 波動関数の絶対値のプロット
// ステップ数を表示
stepnum = string(k * itvl);
xstring(0.1,3,strcat(["step = ",stepnum]));
// 目盛りを非表示にする
g = gca();
g.axes_visible = 'off';
zoom_rect([-0.5,-5,0.5,5]);
// 最後の波動関数を次の初期値に設定
phi0 = phi(:,itvl);
end


Fig.1のGIFアニメーションはschiff-gv-gif_sce.txtで作成したGIF画像をGimpやImagemagickで結合したものです。
Scilabの計算結果をGIFアニメーションにする方法はのちのち別のエントリにまとめようと思っています。

GIF動画に関連する情報は以下のリストにあります。


関連エントリ




参考URL




付録


このエントリで使用したScilabのシミュレーション用ファイルを添付します。ファイル名末尾の".txt"を削除して、"_"を"."に変更すれば使えるはずです。(参考:ねがてぃぶろぐの付録)


参考文献/使用機器




フィードバック



にほんブログ村 その他趣味ブログ 電子工作へ

 ↑ 電子工作ブログランキング参加中です。1クリックお願いします。


コメント・トラックバックも歓迎です。 ↓      


 ↓ この記事が面白かった方は「拍手」をお願いします。

tag: Scilab ode 常微分方程式 偏微分方程式 疎行列 量子力学 

Scilabで規則ポテンシャルと縮退

Scilabで一次元井戸型ポテンシャルでは、時間に依存しないシュレディンガー方程式を、固有値問題と考えて固有方程式を解くためのScilab関数であるspecを用いました。

H \phi = E \phi

(H: ハミルトニアン, φ: 波動関数, E: 固有エネルギー)

今回は、これを応用して規則的なポテンシャルの中では、ポテンシャルの高さが大きくなるにつれてエネルギー固有値が縮退することを確認しました。

001_2013081221404272f.png

Fig.1: 規則的ポテンシャルと波動関数



Scilabで一次元井戸型ポテンシャルでは、無限の高さを持つ一次元井戸型ポテンシャルの中に有限の高さを持つポテンシャル壁をひとつだけ置いたときの時間に依存しないシュレディンガー方程式を解き、波動関数を求めました。

今回は、微分方程式による物理現象のモデル化(PDF)に従って井戸の中に複数のポテンシャル壁が規則的に並んだ場合の計算を行います。

複数のポテンシャル壁がある平坦な井戸


プログラムの基本はScilabで一次元井戸型ポテンシャルと同様です。

Fig.1は規則的なポテンシャルと波動関数をプロットしたものです。
ポテンシャルの谷の部分の波動関数の値が高く、存在確率が高いことを表しています。

次にポテンシャルの高さを変えながら固有状態と固有エネルギーの関係をプロットしたものをFig.2に示します。

002_20130812214042142.png

Fig.2: 固有状態kに対するエネルギー固有値Ekの対応関係


関連エントリ




参考URL




付録


このエントリで使用したScilabのシミュレーション用ファイルを添付します。ファイル名末尾の".txt"を削除して、"_"を"."に変更すれば使えるはずです。(参考:ねがてぃぶろぐの付録)


参考文献/使用機器




フィードバック



にほんブログ村 その他趣味ブログ 電子工作へ

 ↑ 電子工作ブログランキング参加中です。1クリックお願いします。


コメント・トラックバックも歓迎です。 ↓      


 ↓ この記事が面白かった方は「拍手」をお願いします。

tag: Scilab シュレディンガー方程式 量子力学 固有値問題 井戸型ポテンシャル 縮退 

Scilabで一次元井戸型ポテンシャル

微分方程式による物理現象のモデル化(PDF)では、Octaveを用いていろいろな物理現象の数値計算を行っています。
今回は、その中のひとつである量子力学の問題をScilabでプログラミングします。

002_2013080422573295f.png

Fig.1: 無限高さの井戸型ポテンシャルの中に有限高さのポテンシャル壁がある場合



時間に依存しないシュレディンガー方程式


一次元のシュレディンガー方程式は、以下の様にあらわされます。

i \hbar \frac{\partial \psi(x,t)}{\partial t} = \left(- \frac{\hbar^2}{2m}\frac{\partial^2}{\partial x^2} + V(x) \right)\psi(x,t)

ここで

H = - \frac{\hbar^2}{2m}\frac{\partial^2}{\partial x^2} + V(x)

をハミルトニアンと呼びます。ハミルトニアンが時間に依存しないときは、波動関数ψ(x,t)は

\psi(x,t) = \phi(x)\exp\left(-\frac{i E t}{\hbar} \right)

のように変数分離できます。

このとき、以下のように時間に依存しないシュレディンガー方程式がえられます。(最早、変数がxだけになったので∂2/∂x2はd2/dx2と書きます。)

\left(-\frac{\hbar^2}{2m}\frac{\mathrm{d}^2}{\mathrm{d}x^2} + V(x) \right) \phi(x) = E \phi(x)

まず、数値計算をする上で定数の係数は面倒なだけなので、原子単位系のように

\frac{\hbar^2}{2m} = 1

と置きます。時間に依存しないシュレディンガー方程式をもう一度書き直すと

\left(-\frac{\mathrm{d}^2}{\mathrm{d} x^2} + V(x) \right)\phi(x) = E \phi(x)

となり、ハミルトニアンは

H = -\frac{\mathrm{d}^2}{\mathrm{d} x^2}+V(x)

となります。

今回はこの方程式をScilabによって数値的に解きます。

固有値問題


行列A、ベクトルxに対して

Ax = \lambda x

を満たすλ(スカラー)を行列Aの固有値、xを固有ベクトルといいます。

時間に依存しないシュレディンガー方程式もこの形をしており

H \phi = E \phi

A = H: ハミルトニアン
x = φ: 固有ベクトル = 波動関数
λ = E: 固有値 = 固有エネルギー

という関連になっています。

行列Aに対する固有値と固有ベクトルの組み合わせは複数あります。
Scilabではspecで簡単に計算することが出来ます。(参考:固有値問題)

固有ベクトルV, 対角成分に固有値λを並べた行列Dは
[V, D] = spec(A);

で計算できます。

D = <br />\left(<br />\begin{array}{cccc}<br />\lambda_1 & 0 & \hdots & 0 \\<br />0 & \lambda_2 & & \vdots \\<br />\vdots & & \ddots & 0 \\<br />0 & \hdots & 0 & \lambda_n<br />\end{array}<br />\right)  V = <br />\left\{<br />\left(<br />\begin{array}{c}<br />x_{1,1} \\<br />x_{2,1} \\<br />\vdots \\<br />x_{n,1}<br />\end{array}<br />\right)<br />\cdots<br />\left(<br />\begin{array}{c}<br />x_{1,n} \\<br />x_{2,n} \\<br />\vdots \\<br />x_{n,n}<br />\end{array}<br />\right)<br />\right\}

したがって、時間に依存しないシュレディンガー方程式を解くために必要なことは、行列A、すなわちハミルトニアンHをどのような行列としてあらわすかという問題であると言えます。

ハミルトニアンを行列として表現する


基本的な考え方はシュレーディンガー方程式を行列風に描くの通りです。

まずハミルトニアンの前半部分である∂2/∂x2から行きます。
微分の定義から、充分小さいhを考えれば、微分は差分に置き換えることが出来ます。

\frac{\mathrm{d}}{\mathrm{d}x}\phi(x) = \frac{\phi(x+h)-\phi(x)}{h}

\frac{\mathrm{d}}{\mathrm{d}x}\left( \frac{\mathrm{d}}{\mathrm{d}x}\phi(x) \right) = \frac{\frac{\phi(x+h)-\phi(x)}{h}-\frac{\phi(x)-\phi(x-h)}{h}}{h}

2階の微分はこれらを組み合わせて

\begin{eqnarray*}<br />\frac{\mathrm{d}}{\mathrm{d}x}\left( \frac{\mathrm{d}}{\mathrm{d}x}\phi(x) \right) & = & \frac{\frac{\phi(x+h)-\phi(x)}{h}-\frac{\phi(x)-\phi(x-h)}{h}}{h} \\<br />& = & \frac{\phi(x+h)-2\phi(x)+\phi(x-h)}{h^2}<br />\end{eqnarray*}

シュレーディンガー方程式を行列風に描くに倣って行列風に書き下すと

- \frac{\mathrm{d}^2}{\mathrm{d}x^2} = <br />\left(<br />\begin{array}{ccccccc}<br />\frac{2}{h^2} & -\frac{1}{h^2} & 0 & \hdots & & \hdots & 0 \\<br />-\frac{1}{h^2} & \frac{2}{h^2} & -\frac{1}{h^2} & 0 & \hdots & & \vdots \\<br />0 & -\frac{1}{h^2} & \frac{2}{h^2} & -\frac{1}{h^2} & 0 & \hdots & \\<br />\vdots & \ddots & \ddots & \ddots & \ddots & \ddots & \vdots \\<br />& \hdots & 0 & -\frac{1}{h^2} & \frac{2}{h^2} & -\frac{1}{h^2} & 0 \\<br />\vdots &  & \hdots & 0 & -\frac{1}{h^2} & \frac{2}{h^2} & -\frac{1}{h^2} \\<br />0 & \hdots &  & \hdots & 0 & -\frac{1}{h^2} & \frac{2}{h^2}<br />\end{array}<br />\right)


ポテンシャルは、対角成分にポテンシャルの値を入力するだけです。
xiにおけるポテンシャルをvi=V(xi)とおくと、最終的なハミルトニアンは以下のようになります。

\begin{eqnarray*}<br />H &=& - \frac{\mathrm{d}^2}{\mathrm{d}x^2} + V \\<br />&=& \left(<br />\begin{array}{ccccccc}<br />\frac{2}{h^2} + v_1 & -\frac{1}{h^2} & 0 & \hdots & & \hdots & 0 \\<br />-\frac{1}{h^2} & \frac{2}{h^2} + v_2 & -\frac{1}{h^2} & 0 & \hdots & & \vdots \\<br />0 & -\frac{1}{h^2} & \frac{2}{h^2} + v_3 & -\frac{1}{h^2} & 0 & \hdots & \\<br />\vdots & \ddots & \ddots & \ddots & \ddots & \ddots & \vdots \\<br />& \hdots & 0 & -\frac{1}{h^2} & \frac{2}{h^2} + v_{n-2} & -\frac{1}{h^2} & 0 \\<br />\vdots &  & \hdots & 0 & -\frac{1}{h^2} & \frac{2}{h^2} + v_{n-1} & -\frac{1}{h^2} \\<br />0 & \hdots &  & \hdots & 0 & -\frac{1}{h^2} & \frac{2}{h^2} + v_n<br />\end{array}<br />\right)<br />\end{eqnarray*}<br />


井戸型ポテンシャルの中央にポテンシャル壁がある場合


微分方程式による物理現象のモデル化(PDF)に従って、井戸型ポテンシャルの中央に有限の高さのポテンシャル壁がある場合の計算を行います。

中心からw0の幅に高さv0のポテンシャルがある場合のプログラムを書きます。

プログラムはeigen_sce.txtです。

まずはv0=0の場合、いわゆる普通の無限高さの井戸型ポテンシャルのなかの波動関数の計算です。

001_201308042257325d7.png

Fig.2: 無限高さの井戸型ポテンシャルの中の波動関数


更にv0=100のときの波動関数を計算したものが冒頭のものになります。

関連エントリ




参考URL




付録


このエントリで使用したScilabのシミュレーション用ファイルを添付します。ファイル名末尾の".txt"を削除して、"_"を"."に変更すれば使えるはずです。(参考:ねがてぃぶろぐの付録)


参考文献/使用機器




フィードバック



にほんブログ村 その他趣味ブログ 電子工作へ

 ↑ 電子工作ブログランキング参加中です。1クリックお願いします。


コメント・トラックバックも歓迎です。 ↓      


 ↓ この記事が面白かった方は「拍手」をお願いします。

tag: Scilab 固有値問題 シュレディンガー方程式 井戸型ポテンシャル 量子力学 

Scilabでラザフォード散乱

微分方程式による物理現象のモデル化(PDF)に従ってラザフォード散乱のプログラムをScilabで書き直します。

001_20130729024531.png

Fig.1: ラザフォード散乱のシミュレーション結果の中心部分を拡大したもの。



点電荷によるα粒子の散乱


前期量子力学の重要な結論の一つに、原子はほとんど「すかすか」で質量と正の電荷は原子の中心の極めて狭い領域に集中しているというラザフォードの原子模型があります。このことを明らかにした実験がラザフォード散乱です。原子の構造に関しては九州大学のインターネット・セミナーミクロの世界」 - その1 - (原子の世界の謎) 第2部: 原子の構造が分かりやすいです。以下のトムソンの原子模型とラザフォードの原子模型の図も上記サイトから引用しました。このインターネットセミナーは書籍にもなっているようです(わかりやすい量子力学入門―原子の世界の謎を解く)。

Atom.png


金の原子核が金原子の大きさとくらべて充分小さく大きさが無視できると仮定すると、金原子はZAuの正の電荷を持つ点電荷であると考えることが出来ます。この金原子に5.3MeVのエネルギーを持つα粒子に作用するクーロン力は、金の原子核を局座標の原点に置くと、以下のようにあらわされます。

f = \frac{Z_{\alpha}Z_{\mathrm{Au}}e^2}{4 \pi \epsilon_0}\frac{1}{r^2}

たいそうな形をしていますが、r以外は全て定数です。つまり、クーロン力は金の原子核の距離だけで決まり、その大きさは距離の二乗に反比例します。

002_20130729024531.png

Fig.2: クーロン力


クーロン力のx成分とy成分はそれぞれ以下のようにあらわせます。

f_x = f \cos\theta = f\frac{x}{r}

f_y = f \sin\theta = f\frac{y}{r}

これらを運動方程式へ代入し、両辺をα粒子の質量mαで割ると

\frac{\mathrm{d}^2x}{\mathrm{d}t^2} = \frac{Z_{\alpha}Z_{\mathrm{Au}}e^2}{4 \pi \epsilon_0 m_{\alpha}}\frac{x}{r^3}

\frac{\mathrm{d}^2y}{\mathrm{d}t^2} = \frac{Z_{\alpha}Z_{\mathrm{Au}}e^2}{4 \pi \epsilon_0 m_{\alpha}}\frac{y}{r^3}

x,y,r以外は定数なので適切な単位系を設定すると

\frac{Z_{\alpha}Z_{\mathrm{Au}}e^2}{4 \pi \epsilon_0 m_{\alpha}} = 0.0614

となります。なお、微分方程式による物理現象のモデル化(PDF)には数値が書かれていませんが、α粒子の質量は陽子2つと中性子2つでmα=3756[MeV/c2]です。

プログラム


以上を踏まえたプログラムを以下に示します。
これによって描かれた図がFig1およびFig.3です。

003_20130729024530.png

Fig.3: ラザフォード散乱


clear;
// 表示領域のサイズ
//xymax = 2000; // 表示領域を2000*2000に設定
xymax = 400; // 表示領域を400*400に設定
// グラフの縦横比を等しくする
h = scf(); // ウィンドウを作成
ha = h.children(1); // Axes(座標軸)オブジェクトへのハンドルを取得
ha.isoview = "on"; // 座標軸の縦横比を等しくする
ha.data_bounds = [- xymax,- xymax; xymax, xymax]; // 座標軸表示範囲の設定

// *** 解くべき常微分方程式 ***
function dx = ruther(t,x)
r = sqrt(x(1) ^ 2 + x(3) ^ 2);
dx(1) = x(2);
dx(2) = 0.0614 * x(1) / r ^ 3;
dx(3) = x(4);
dx(4) = 0.0614 * x(3) / r ^ 3;
endfunction

// *** 時間ベクトル ***
T = linspace(0,100000,1000);

// *** α粒子の初速度 ***
v0 = 0.053;
vx0 = v0;
vy0 = 0;

// *** α線源の位置 ***
// x座標
x0 = - 2000;

// y座標を変えながらα粒子の運動を計算
for y0 = -95:10:95
X0 = [x0; vx0; y0; vy0];
X = ode(X0,0,T,ruther);
plot(X(1,:),X(3,:),'-r');
end

// 描画範囲の設定
zoom_rect([- xymax,- xymax, xymax, xymax]);


クーロン力のベクトル表示


α粒子が受けるクーロン力は単純に位置のみに依存するので、その力の向きと方向を矢印であらわして見ます。
矢印を表示するScilabのコマンドはchampで、champのためのベクトルを用意するのに便利なのがndgridです。

ベクトル表示を加えたプログラムがrutherford_sce.txtです。

004_20130729024530.png

Fig.4: ラザフォード散乱の結果にクーロン力のベクトルを追加したもの。


矢印の長さが、その点にあるα粒子が受けるクーロン力の大きさを表しています。数式を見るとクーロン力は距離の2乗に反比例することが分かりますが、グラフにしてみても強いクーロン力を受けるのは金原子核のごく近傍だけです。

さて微分方程式による物理現象のモデル化(PDF)の問題28は、つまるところトムソンの原子模型を採用すると散乱はどうなるのかということです。(例題でなく問題という割には答えも書いてありますが)。
これはトムソン模型の原子内部と外部でクーロン力の関数が以下のように場合分けされると考えれば簡単に考察できます。

f( \vec{r} ) = \begin{cases}<br />\frac{Z_{\alpha}Z_{\mathrm{Au}}e^2}{4 \pi \epsilon_0 m_{\alpha} R^3} \vec{r} & (r \leq R) \\<br />\frac{Z_{\alpha}Z_{\mathrm{Au}}e^2}{4 \pi \epsilon_0 m_{\alpha} r^3} \vec{r} & (r > R)<br />\end{cases}

r > Rでは、これまでに考えてきたラザフォード模型と同じ結果を示しますが、r≦Rではr=Rのときと同じ力しか受けません。したがってトムソン模型では飛んできたα粒子を大きな角度へ押し返すような散乱は起こりません。

なお、元PDFの数式は、またしても質量mαで割り算するのを忘れているようです。

参考URL




付録


このエントリで使用したScilabのシミュレーション用ファイルを添付します。ファイル名末尾の".txt"を削除して、"_"を"."に変更すれば使えるはずです。(参考:ねがてぃぶろぐの付録)


参考文献/使用機器




フィードバック



にほんブログ村 その他趣味ブログ 電子工作へ

 ↑ 電子工作ブログランキング参加中です。1クリックお願いします。


コメント・トラックバックも歓迎です。 ↓      


 ↓ この記事が面白かった方は「拍手」をお願いします。

tag: Scilab 常微分方程式 ode 量子力学 クーロン散乱 

FC2カウンター
カテゴリ
ユーザータグ

LTspiceAkaiKKRmachikaneyamaScilabKKRPSoCOPアンプCPA強磁性PICモンテカルロ解析常微分方程式odeトランジスタecalj状態密度DOSインターフェース定電流スイッチング回路PDS5022半導体シェルスクリプト乱数レベルシフトHP6632A温度解析分散関係I2Cトランジスタ技術R6452A可変抵抗ブレッドボードセミナーバンドギャップ数値積分確率論反強磁性偏微分方程式バンド構造絶縁熱設計非線形方程式ソルバフォトカプラシュミットトリガLEDLM358カオスISO-I2C三端子レギュレータGW近似A/Dコンバータカレントミラーアナログスイッチ数値微分マフィンティン半径TL431発振回路サーボPC817CUSB直流動作点解析74HC4053補間FFTBSch開発環境パラメトリック解析2ちゃんねるチョッパアンプ量子力学bzqlty電子負荷イジング模型LDA標準ロジックアセンブラ基本並進ベクトルブラべ格子単振り子熱伝導位相図TLP621キュリー温度繰り返し状態方程式MaximaVESTAスイッチト・キャパシタ相対論FETランダムウォークスピン軌道相互作用SMP六方最密充填構造抵抗不規則合金ewidthスレーターポーリング曲線GGAラプラス方程式cygwingfortranQSGW失敗談コバルト条件分岐TLP521テスタLM555Writer509TLP552格子比熱マントルデータロガー自動計測詰め回路ガイガー管ダイヤモンドQNAPMCUFXA-7020ZR過渡解析三角波UPSNE555固有値問題熱力学ブラウン運動フェルミ面awk起電力第一原理計算OpenMPfsolveubuntu最大値xcrysden最小値最適化仮想結晶近似VCA差し込みグラフスーパーセル井戸型ポテンシャル平均場近似シュレディンガー方程式FSMフラクタルOPA2277固定スピンモーメント2SC1815全エネルギー合金multiplotgnuplotc/aTeX結晶磁気異方性interp1ウィグナーザイツ胞初期値マンデルブロ集合疎行列面心立方構造fcc不純物問題非線型方程式ソルバフィルタL10構造PGA半金属二相共存SICZnOウルツ鉱構造BaO重積分クーロン散乱磁気モーメント電荷密度三次元CIF岩塩構造CapSenseノコギリ波デバイ模型ハーフメタル正規分布フォノンquantumESPRESSOルチル構造スワップ領域リジッドバンド模型edelt縮退キーボード軸ラベルグラフの分割凡例トラックボールPC不規則局所モーメント片対数グラフトランス両対数グラフCK1026MAS830L直流解析Excel円周率パラメータ・モデルヒストグラム日本語最小二乗法等価回路モデルGimp線種シンボルTS-110TS-112PIC16F785LMC662化学反応文字列specx.f入出力ifortマテリアルデザインヒストグラム確率論Realforce等高線ジバニャン方程式P-10Ubuntuナイキスト線図Crank-Nicolson法陰解法熱拡散方程式HiLAPWAACircuit連立一次方程式負帰還安定性境界条件EAGLEMBE関数フィッティング

最新コメント
リンク

にほんブログ村 その他趣味ブログ 電子工作へ