Scilabの論理演算で条件分岐

Scilabで条件分岐:テント写像ではif then elseを利用して条件分岐のプログラムを書きました。
しかしながらScilabで繰り返し計算: ロジスティック写像で指摘したとおりScilabではループ計算をさせるととたんに計算速度が遅くなります。

前回のプログラムではif then elseを使うためにforループを二重になってしまっています。
そこで今回は、論理演算を用いてループが減るようにしました。

texclip20130718112739.png

nmax = 200;
nout = 100;

Mu = [1:0.001:2];
X = 0.5 * ones(nmax,length(Mu));

for n = 1: nmax - 1 do
X(n+1,:) = Mu .* X(n,:) .* (X(n,:) < 0.5) + ..
Mu .* (1.0 - X(n,:)) .* (X(n,:) >= 0.5);
end

plot(Mu,X(nout:nmax,:),'.r','markersize',1)
xlabel("$\mu$");
ylabel("$x_n$");



論理演算


Scilabでは結果をT(true, 真)とF(false, 偽)で返す論理演算があります。
例えば、以下のようなものです。
M = [0:0.1:1]
M > 0.5
この結果は F F F F F F T T T T T といった様に要素にTとFを持つ行列になります。

これを F=0,T=1 の数値としてそのまま計算に使うことが出来ます。例えば
M = [0:0.1:1]
1 * (M > 0.5)
の結果は 0 0 0 0 0 0 1 1 1 1 1 です。

関連エントリ




参考URL




付録


このエントリで使用したScilabのシミュレーション用ファイルを添付します。ファイル名末尾の".txt"を削除して、"_"を"."に変更すれば使えるはずです。(参考:ねがてぃぶろぐの付録)




参考文献/使用機器




フィードバック



にほんブログ村 その他趣味ブログ 電子工作へ

 ↑ 電子工作ブログランキング参加中です。1クリックお願いします。


コメント・トラックバックも歓迎です。 ↓      


 ↓ この記事が面白かった方は「拍手」をお願いします。

tag: Scilab 条件分岐 繰り返し カオス 

Scilabで条件分岐:テント写像

Scilabで繰り返し計算: ロジスティック写像ではforを使ったループを利用してカオス理論に現れるロジスティック写像の図を描くプログラムを作成しました。

今回は、更に条件分岐をプラスしてテント写像のプログラムを作成します。

001_20130718113839.png

Fig.1: テント写像の分岐図



Wikipediaのテント写像の項にある通り、テント写像は以下の式で表されます。

texclip20130718112739.png


条件分岐はScilabではifを使って実現することが出来ます。(参考:if then else)
Scilabで繰り返し計算: ロジスティック写像の繰り返し計算を入れ子にしたものに少し手を加えるだけでテント写像のプログラムになります。

nmax = 200;
nout = 100;

Mu = [1:0.001:2];
X = 0.5 * ones(nmax,length(Mu));

for m = 1:length(Mu) do
for n = 1: nmax - 1 do
if X(n,m) < 0.5 then
X(n+1,m) = Mu(m) * X(n,m);
else
X(n+1,m) = Mu(m) * (1 - X(n,m));
end
end
end

plot(Mu,X(nout:nmax,:),'.r','markersize',1)
xlabel("$\mu$");
ylabel("$x_n$");


なお、Scilabのグラフのラベルには$記号で囲うことによってTeX形式で文字を書くことが出来ます。(参考:Scilabのグラフの凡例)

関連エントリ




参考URL




付録


このエントリで使用したScilabのシミュレーション用ファイルを添付します。ファイル名末尾の".txt"を削除して、"_"を"."に変更すれば使えるはずです。(参考:ねがてぃぶろぐの付録)


参考文献/使用機器




フィードバック



にほんブログ村 その他趣味ブログ 電子工作へ

 ↑ 電子工作ブログランキング参加中です。1クリックお願いします。


コメント・トラックバックも歓迎です。 ↓      


 ↓ この記事が面白かった方は「拍手」をお願いします。

tag: Scilab 条件分岐 繰り返し カオス 

Scilabで繰り返し計算: ロジスティック写像

Scilabを使えば、非常に簡単に数値計算のプログラムを書くことができます。例えば、たった8行のプログラムでFig.1のような計算が出来てしまいます。

今回は、プログラミングの基本のひとつであるループ処理の例としてロジスティック写像の計算を行いました。Scilabはインタープリタなので、ループ処理は苦手です。そのため出来る限りループを無くすようにする実例にもなっています。

001_20130520003209.png
Fig.1: ロジスティック写像。横軸が繁殖率a、縦軸が100世代目から200世代目までの個体数X(n)。



ロジスティック写像


生物の個体数Xが世代nに従ってどのように変化するかという研究からロジスティック方程式というものが知られています。

X(n+1) = a \times X(n) \times (1-X(n))

この式の見た目はとても簡単であるにもかかわらず、個体数の初期値X(1)や繁殖率aに対して、充分時間がたったときの個体数(例えば100世代目の個体数X(100)など)が非常に敏感に反応するため、カオス理論と関連して議論される面白い方程式となっています。(参考:ロジスティック写像:長崎県立大学伊藤研究室)

002_20130520024958.png
Fig.2: 繁殖率aに関して 3 < a < 4 の部分を拡大したもの


また、数値計算の例題としてもシンプルな繰り返しのコードで思いもよらないほど複雑な、かっこいい結果が得られるので良く見かけます。Fig.1,2はロジスティック方程式を繁殖率aを0<a<4の間で計算したもので、縦軸に個体数X(n)を100 < n < 200の範囲でプロットしてあります。個体数の初期値はX(1)=0.2としました。
本エントリではScilabを用いたループ計算の例としてこのロジスティック写像のプログラムを紹介します。特にScilabのようなインタプリタではループ処理と非ループ処理で計算速度に大きな差が出るため、この点についても書きます。

繰り返し計算


まずは、簡単のために繁殖率をa=3.5に固定して、世代数nを順次変化させるプログラムを書きます。
Scilabで繰り返し処理をするにはforを使います。(参考:繰り返し:Scilab簡易リファレンス-PukiWiki)

nmax = 50;

a = 3.5;
x = 0.2 * ones(nmax,1);

for n = 1: nmax - 1 do
x(n+1) = a * x(n) * (1.0 - x(n));
end

plot(x,'o-r');
xlabel("n");
ylabel("X(n)");

plot([0,0],[0,1]);


最後の行の(0,0)と(0,1)のプロットは描画領域を調整するためのダミーです。


003_20130521000718.png
Fig.3: a=3.5 X(1)=0.2のときの個体数X(n)の世代発展


Fig.3を見ると30世代ぐらいまでは過渡領域で、それ以降は4つの値を行き来していることが分かります。
Fig.1-2は充分時間がったったときの個体数で、a=3.5において4つの値を行き来する事は四本の線に分かれている事から読み取れます。

繰り返し計算の入れ子


それでは次にFig.1-2を描くプログラムについて考えます。
先ほどは世代数nを変更するために繰り返し命令forを使いました。このことを応用してforを入れ子にすれば、さらに繁殖率aを変更した繰り返し計算のプログラムがかけます。

nmax = 200;
nout = 100;

A = [0:0.001:4];
X = 0.2 * ones(nmax,length(A));

for m = 1:length(A) do
for n = 1: nmax - 1 do
X(n+1,m) = A(m) * X(n,m) * (1.0 - X(n,m));
end
end

plot(A,X(nout:nmax,:),'.r','markersize',1);

このプログラムは悪くないのですが、ベストではないです。

繰り返し計算は出来れば避ける


ループ計算は遅いので,できるだけ使わないでは、同じ内容の計算であってもForループの有無により数10倍計算速度が変わる例が示されています。

ループを使わずに済ませることができるかどうかはケース・バイ・ケースなのですが、今回は入れ子にせずとも1段階のループで処理することが出来ます。
今回のロジスティック写像のプログラムは、私の環境では数10倍どころか、ループ部分の計算時間が約14秒から約0.03秒まで短縮できました。(もっとも、そのあとのグラフの描画に数秒程度かかってしまうのですが。)

nmax = 200;
nout = 100;

A = [0:0.001:4];
X = 0.2 * ones(nmax,length(A));

for n = 1: nmax - 1 do
X(n+1,:) = A .* X(n,:) .* (1.0 - X(n,:));
end

plot(A,X(nout:nmax,:),'.r','markersize',1);


ただし、Scilabは細かいことを気にせずにプログラムが書けることが最大の利点なので、計算速度向上のために腐心して時間を無駄遣いするぐらいなら、多少効率が落ちようともさっさとコードを書いてしまうほうがいいという面もあります。

関連エントリ




参考URL




付録


このエントリで使用したScilab用のソースコードを添付します。ファイル名末尾の".txt"を削除して、"_"を"."に変更すれば使えるはずです。(参考:ねがてぃぶろぐの付録)


参考文献/使用機器




フィードバック



にほんブログ村 その他趣味ブログ 電子工作へ

 ↑ 電子工作ブログランキング参加中です。1クリックお願いします。


コメント・トラックバックも歓迎です。 ↓      


 ↓ この記事が面白かった方は「拍手」をお願いします。

tag: Scilab 繰り返し カオス 

FC2カウンター
カテゴリ
ユーザータグ

LTspiceAkaiKKRmachikaneyamaScilabKKRPSoC強磁性PICCPAOPアンプecalj常微分方程式モンテカルロ解析状態密度odeトランジスタインターフェースDOS定電流スイッチング回路PDS5022半導体シェルスクリプト分散関係レベルシフト乱数HP6632Aトランジスタ技術ブレッドボード可変抵抗温度解析I2CR6452A反強磁性バンドギャップ確率論数値積分セミナー偏微分方程式絶縁バンド構造熱設計非線形方程式ソルバシュミットトリガISO-I2CLEDマフィンティン半径GW近似三端子レギュレータLM358A/DコンバータカオスフォトカプラUSBPC817C直流動作点解析サーボ74HC4053アナログスイッチTL431発振回路カレントミラー数値微分単振り子量子力学開発環境補間2ちゃんねるチョッパアンプbzqltyFFT電子負荷アセンブラBSchLDA標準ロジックパラメトリック解析ブラべ格子基本並進ベクトルイジング模型VESTAVCAMaximaSMPewidthGGA仮想結晶近似FET位相図キュリー温度QSGWTLP621ランダムウォーク不規則合金gfortranコバルト相対論失敗談抵抗状態方程式スレーターポーリング曲線ラプラス方程式スピン軌道相互作用スイッチト・キャパシタ六方最密充填構造熱伝導繰り返しcygwinTLP552条件分岐TLP521NE555LM555マントル詰め回路MCUテスタFXA-7020ZR三角波過渡解析ガイガー管自動計測Writer509UPSQNAPダイヤモンドデータロガー格子比熱熱力学平均場近似OpenMPブラウン運動スーパーセルUbuntuフェルミ面差し込みグラフubuntuハーフメタルfsolve最適化第一原理計算固有値問題シュレディンガー方程式最小値awk起電力井戸型ポテンシャルCIFxcrysden最大値結晶磁気異方性PGATeX非線型方程式ソルバ2SC1815等高線OPA2277面心立方構造初期値FSM正規分布interp1ウィグナーザイツ胞フィルタfccL10構造合金BaOウルツ鉱構造CapSense岩塩構造ルチル構造ZnO二相共存磁気モーメント不純物問題電荷密度重積分SICスワップ領域リジッドバンド模型multiplotジバニャン方程式gnuplotc/a全エネルギー半金属デバイ模型edeltquantumESPRESSOノコギリ波フォノン固定スピンモーメントspecx.f等価回路モデル円周率パラメータ・モデルヒストグラム不規則局所モーメントTS-112TS-110直流解析PCExcelシンボルGimp日本語最小二乗法フラクタルマンデルブロ集合縮退クーロン散乱三次元ゼーベック係数キーボード入出力関数フィッティング文字列疎行列Realforceトラックボール線種EAGLE連立一次方程式MBECrank-Nicolson法AACircuit負帰還安定性ナイキスト線図マテリアルデザインP-10化学反応ifort境界条件陰解法熱拡散方程式MAS830LCK1026グラフの分割軸ラベル凡例片対数グラフトランスHiLAPW両対数グラフLMC662PIC16F785ヒストグラム確率論

最新コメント
リンク

にほんブログ村 その他趣味ブログ 電子工作へ