スポンサーサイト

上記の広告は1ヶ月以上更新のないブログに表示されています。
新しい記事を書く事で広告が消せます。

Scilabでガウス型波束の散乱

Scilabを用いて初期波動関数がガウス型をしている波束が、ポテンシャルの谷によって散乱される様子をシミュレーションしました。

001.gif

Fig.1: ガウス型波束がポテンシャルの谷間によって散乱される様子を表したアニメーション。赤が波動関数の絶対値、緑が波動関数の実部を表す。青はポテンシャルの形状。



偏微分方程式


ねがてぃぶろぐでは微分方程式による物理現象のモデル化(PDF)で紹介されている常微分方程式をScilabで計算してきました。
次のテーマである波束の運動の問題は、時間微分だけの常微分方程式ではなく、時間と空間の両方の微分を含む偏微分方程式です。

ScilabやOctaveには偏微分方程式を解くための特別な関数は用意されていません。そこで、偏微分方程式を解くためには微分を差分に置き換えた計算が必要になります。Scilabで一次元井戸型ポテンシャルScilabで規則ポテンシャルと縮退では位置の微分であるエネルギー演算子を含むハミルトニアンを行列で表すことによって、固有値問題を解くための命令であるspecを利用することにより計算しました。

今回はScilabで一次元井戸型ポテンシャルと同様にハミルトニアンを行列であらわし、常微分方程式ソルバodeと組み合わせることにより、時間に依存するシュレディンガー方程式を解いてガウス型波束が散乱される様子をシミュレーションします。


ガウス型波束の運動


シッフの量子力学の本(上巻 下巻)によるとx軸の正の方向に運動量を持つ波束の波動関数は以下のように表されます。

\psi(x) = \frac{1}{\sqrt[4]{2 \pi (\Delta x)^2}} \exp\left(- \frac{(x-\langle x \rangle)^2}{4(\Delta x)^2}+\frac{i\langle p \rangle}{\hbar}x \right)

今回は、このガウス型波束を初期値に持つ波動関数がポテンシャルの谷に散乱される様子をScilabを用いてシミュレーションします。


時間に依存するシュレディンガー方程式


時間に依存するシュレディンガー方程式は、以下の様に表されます。

i \hbar \frac{\partial \psi (x,t)}{\partial t} = \left(- \frac{\hbar}{2m}\frac{\partial^2}{\partial x^2} + V(x) \right)\psi(x,t)

時間に依存しないシュレディンガー方程式の場合と同様に

\hbar = 1, m = \frac{1}{2}

とおくと、ハミルトニアンHは以下のようにかけます。

H = - \frac{\partial^2}{\partial x^2} + V(x)

この段階で時間に依存するシュレディンガー方程式は以下のように書くことが出来ます。

i\frac{\partial \psi}{\partial t} = H \psi

ここまでくればScilabの常微分方程式ソルバodeで解けることが分かります。
dψ/dt = ...の形にすると

\frac{\partial \psi}{\partial t} = -i H \psi

となり、これが今回の解くべき方程式となります。

微分方程式による物理現象のモデル化(PDF)によるとOctaveの常微分方程式ソルバであるlsodeは複素数に対応していないとのことですが、Scilabのodeは複素数に対応しているので、今回はodeを利用してシュレディンガー方程式を解きます。


疎行列


Scilabで一次元井戸型ポテンシャルで書いたとおり、ハミルトニアンを行列として書き下すと、以下のようにほとんどの成分がゼロとなります。

\begin{eqnarray*} H &=& - \frac{\mathrm{d}^2}{\mathrm{d}x^2} + V \\ &=& \left( \begin{array}{ccccccc} \frac{2}{h^2} + v_1 & -\frac{1}{h^2} & 0 & \hdots & & \hdots & 0 \\ -\frac{1}{h^2} & \frac{2}{h^2} + v_2 & -\frac{1}{h^2} & 0 & \hdots & & \vdots \\ 0 & -\frac{1}{h^2} & \frac{2}{h^2} + v_3 & -\frac{1}{h^2} & 0 & \hdots & \\ \vdots & \ddots & \ddots & \ddots & \ddots & \ddots & \vdots \\ & \hdots & 0 & -\frac{1}{h^2} & \frac{2}{h^2} + v_{n-2} & -\frac{1}{h^2} & 0 \\ \vdots &  & \hdots & 0 & -\frac{1}{h^2} & \frac{2}{h^2} + v_{n-1} & -\frac{1}{h^2} \\ 0 & \hdots &  & \hdots & 0 & -\frac{1}{h^2} & \frac{2}{h^2} + v_n \end{array} \right) \end{eqnarray*}

このようにゼロでない要素が全体の中でごくわずかしかない行列を疎行列と呼びます。Scilabでは疎行列を扱う特別なデータ型があり、普通に定義した行列に対して

sp = sparse(X);


とすることによって疎行列へ変換することが出来ます。(参考:sparse)

今回の計算のハミルトニアンのようにゼロとなる要素が多い場合は、疎行列型へ変換することにより計算速度が劇的に速くなります。


数値計算


微分方程式による物理現象のモデル化(PDF)のように100stepごとに700ステップまで表示するScilabのプログラムがschiff-gv_sce.txtです。

clear;

vw = 0.064; // ポテンシャルの幅
vh = - (70.7 * %pi) ^ 2; // ポテンシャルの深さ
dim = 500; // 空間の分割数
h = 2.0 / dim; // 空間の刻み幅

// *** 位置ベクトル ***
X = linspace(-1,1,dim + 1);

// *** ハミルトニアンの定義 ***
// エネルギー演算子
vd = 2 / h ^ 2;
vdt = - 1 / h ^ 2;
SD = diag(vdt * ones(1,dim),1);
D = diag(vd * ones(1,dim + 1));
H = SD + D + SD.';
// ポテンシャル
V = zeros(H);
for i = 1:dim + 1 do
if abs(X(i)) < vw / 2 then
V(i,i) = vh;
end
end
// 全ハミルトニアン
H = sparse(H + V); // 疎行列へ変換するほうが実行速度が速い

// *** 常微分方程式の定義 ***
function dphi = schiff(t,phi)
dphi = - %i * H * phi;
endfunction

// *** 波束の初期設定 ***
xe = - 0.3; // 初期波束の位置の期待値(波束の中心位置)
dx = 0.035; // 初期波束の空間的広がり
pe = 50 * %pi; // 初期波束の運動量の期待値
phi0 = zeros(dim + 1,1);
for k = 1:dim + 1 do
// 初期波束
phi0(k) = exp(-(X(k) - xe) ^ 2 / (4 * dx ^ 2) + %i * pe * X(k)) ..
/ (2 * %pi * (dx) ^ 2) ^ 0.25;
end

// *** 時間刻みの設定 ***
dt = h ^ 2 / 4;
nstep = 700;
itvl = 100;
tf = dt * itvl;
T = [0:dt:tf];

// *** プロット ***
// ポテンシャルのプロット
subplot(3,3,1);
plot(X,diag(V));
// 目盛りを非表示にする
g = gca();
g.axes_visible = 'off';
zoom_rect([-0.5,-5,0.5,5]);
// 初期値のプロット
subplot(3,3,2);
plot(X,diag(V)); // ポテンシャルのプロット
plot(X,real(phi0),'-g'); // 波動関数の実部のプロット
plot(X,abs(phi0),'-r'); // 波動関数の絶対値のプロット
// ステップ数を表示
xstring(0.1,3,"step = 0");
// 目盛りを非表示にする
g = gca();
g.axes_visible = 'off';
zoom_rect([-0.5,-5,0.5,5]);

for k = 1:nstep/itvl do
// 微分方程式の数値解
phi = ode(phi0,0,T,schiff);
// ポテンシャルと波動関数のプロット
subplot(3,3,k + 2);
plot(X,diag(V)); // ポテンシャルのプロット
plot(X,real(phi(:,itvl)),'-g'); // 波動関数の実部のプロット
plot(X,abs(phi(:,itvl)),'-r'); // 波動関数の絶対値のプロット
// ステップ数を表示
stepnum = string(k * itvl);
xstring(0.1,3,strcat(["step = ",stepnum]));
// 目盛りを非表示にする
g = gca();
g.axes_visible = 'off';
zoom_rect([-0.5,-5,0.5,5]);
// 最後の波動関数を次の初期値に設定
phi0 = phi(:,itvl);
end


Fig.1のGIFアニメーションはschiff-gv-gif_sce.txtで作成したGIF画像をGimpやImagemagickで結合したものです。
Scilabの計算結果をGIFアニメーションにする方法はのちのち別のエントリにまとめようと思っています。

GIF動画に関連する情報は以下のリストにあります。


関連エントリ




参考URL




付録


このエントリで使用したScilabのシミュレーション用ファイルを添付します。ファイル名末尾の".txt"を削除して、"_"を"."に変更すれば使えるはずです。(参考:ねがてぃぶろぐの付録)


参考文献/使用機器




フィードバック



にほんブログ村 その他趣味ブログ 電子工作へ

 ↑ 電子工作ブログランキング参加中です。1クリックお願いします。


コメント・トラックバックも歓迎です。 ↓      


 ↓ この記事が面白かった方は「拍手」をお願いします。
スポンサーサイト

tag: Scilab ode 常微分方程式 偏微分方程式 疎行列 量子力学 

FC2カウンター
カテゴリ
ユーザータグ

LTspiceAkaiKKRmachikaneyamaScilabKKRPSoC強磁性CPAPICOPアンプecalj状態密度常微分方程式モンテカルロ解析odeトランジスタインターフェースDOS定電流PDS5022スイッチング回路半導体分散関係シェルスクリプトレベルシフト乱数HP6632A可変抵抗I2Cトランジスタ技術温度解析R6452Aブレッドボード数値積分確率論バンド構造バンドギャップセミナー反強磁性絶縁熱設計偏微分方程式非線形方程式ソルバA/Dコンバータフォトカプラカオス三端子レギュレータISO-I2CPWscfLM358GW近似シュミットトリガLEDマフィンティン半径数値微分サーボ発振回路TL431直流動作点解析USBカレントミラー補間PC817Cアナログスイッチ74HC4053VESTAbzqlty電子負荷イジング模型アセンブラQuantumESPRESSOLDAチョッパアンプBSch開発環境単振り子量子力学2ちゃんねるFFT基本並進ベクトル標準ロジックブラべ格子パラメトリック解析位相図キュリー温度ラプラス方程式繰り返し抵抗熱伝導スイッチト・キャパシタ状態方程式MaximaSMP失敗談gfortran六方最密充填構造コバルトTLP621不規則合金スピン軌道相互作用ランダムウォーク最適化ewidth相対論FETQSGWスレーターポーリング曲線VCA仮想結晶近似GGAcygwinQuantum_ESPRESSO条件分岐詰め回路NE555LM555固有値問題最小値ガイガー管QNAPUPSダイヤモンドマントルデータロガーゼーベック係数TLP552シュレディンガー方程式ZnO最大値CIF格子比熱xcrysdenMCUハーフメタル井戸型ポテンシャル三角波ブラウン運動フェルミ面awk差し込みグラフスーパーセルFXA-7020ZR過渡解析起電力fsolveOpenMPUbuntuWriter509テスタ熱力学第一原理計算TLP521ubuntu平均場近似自動計測CK1026MAS830LトランスPIC16F785フィルタAACircuitCapSense負帰還安定性ノコギリ波ナイキスト線図EAGLE2SC1815P-10PGAOPA2277MBELMC662入出力FSMTeX結晶磁気異方性非線型方程式ソルバ固定スピンモーメント全エネルギーmultiplotgnuplotc/aL10構造fcc等高線ジバニャン方程式ヒストグラム確率論正規分布初期値面心立方構造ウィグナーザイツ胞interp1合金半金属電荷密度重積分SIC二相共存磁気モーメント不純物問題cif2cellPWgui擬ポテンシャルウルツ鉱構造BaOquantumESPRESSOフォノンデバイ模型edeltリジッドバンド模型岩塩構造ルチル構造スワップ領域マテリアルデザインspecx.fフラクタルマンデルブロ集合キーボードRealforceクーロン散乱三次元疎行列縮退化学反応関数フィッティング最小二乗法Excel直流解析PCTS-110TS-112日本語パラメータ・モデル等価回路モデル文字列状態図熱拡散方程式HiLAPW両対数グラフ陰解法Crank-Nicolson法ifort境界条件連立一次方程式片対数グラフグラフの分割円周率ヒストグラム不規則局所モーメントGimpシンボル軸ラベル凡例線種トラックボール

最新コメント
リンク

にほんブログ村 その他趣味ブログ 電子工作へ
上記広告は1ヶ月以上更新のないブログに表示されています。新しい記事を書くことで広告を消せます。