Scilabで二酸化炭素の状態方程式 その2

Scilabで二酸化炭素の状態方程式 その1では、Scilabを用いてファンデルワールスの状態方程式を解くプログラムを作成しました。

\left(P + \frac{a^2}{V} \right) (V-b)=RT

(P: 圧力, V: モル体積, R: 気体定数, T: 絶対温度, a, b: ファンデルワールス定数)

実はファンデルワールスの状態方程式は気体の体積だけでなく、液体や気体・液体共存のときのP,V,Tも計算することが出来ます。
この計算を行う際にMaxwellの規則を利用します(参考:ファン・デル・ワールスの状態方程式 (クラウジウス=クラペイロンの式、ジュール=トムソン効果)3.液体・気体共存領域)。Maxwellの規則ではグラフの面積が等しくなる条件を用いますが、こういった条件を探すのは、解析的には難しく、数値計算の出番となります。

004_20130811163805e0f.png

Fig.1: T = 250 (K)のときの二酸化炭素の圧力Pとモル体積Vの関係。グラフ中の赤の水平線の部分が液体・気体の共存領域、それよりも右側が気体の安定領域で左側が液体の安定領域。赤の水平線は、赤の水平線と赤の点線で囲まれた二つの領域の面積が等しくなる条件から引かれる。(Maxwellの規則)



二酸化炭素の相図


常温・常圧の二酸化炭素は気体ですが、固体の二酸化炭素といえばドライアイスです。ドライアイスは室温においておくと液体にならずに気体になりますが、5.1×105(Pa)つまり5気圧以上では水などと同様に液体になります。
以下に示すのは、ファン・デル・ワールスの状態方程式 (クラウジウス=クラペイロンの式、ジュール=トムソン効果)から引用した二酸化炭素の相図です。相図(Phase diagram, 状態図とも)は物質の状態(固体,液体,気体)と温度・圧力・化学組成の関係性を表した図です。



液体・気体共存領域


ファンデルワールスの状態方程式の1つの特徴として気体と液体の相転移を表すことができる点が挙げられます。
このときの液体、気体のそれぞれのモル体積は、Fig.1に示したとおりファンデルワールスの状態方程式と水平線の一番左の交点と一番右の交点として表されます。
またこの水平線は、水平線と状態方程式の作る二つの領域の面積が等しくなる条件から引くことが出来ます。
これをMaxwellの規則と呼び、数式で表すと以下のようになります。

\int_{V_l}^{V_g}P_{vdw}\mathrm{d}V - \int_{V_l}^{V_g}P_k \mathrm{d}V = 0

ただしPvdwがファンデルワールスの状態方程式で計算した圧力、Pkが水平線の圧力です。これらの交点のうち一番左の物が液体の体積Vlで一番右のものが気体の体積Vgです。

数値計算


色々な教科書に水平線Pkは面積が等しくなる条件から決定することが出来ると簡単に書かれていますが、Pkを決めないと交点Vg,Vlが決まらないため、Pkを決めるためには数値計算が必要です。

この計算にはScilabで金属の化学ポテンシャルScilabでおもりの吊り下げで利用した非線形方程式ソルバfsolveが使えます。

まずPkとPvdw(V)が与えられているとして3つの交点の値を求めます。
交点の値は、ファンデルワールスの状態方程式を変形して得られる以下の三次方程式の解です。

P_k V^3 - (b P_k + RT) V^2 + aV - ab = 0

Scilabでは多項式の解はrootsを用いて簡単に計算できます。解は複素数の要素を持つ縦ベクトルになります。Scilab言語には(C言語のような)型の宣言が無いのでミスを犯しやすいのですが、解の全ての要素が実部しか持たなかったとしても、変数の型としては複素数なので、realをつかって実数型へ変換する必要があります。

数値積分にはScilabで数値積分: 固体の比熱Scilabで関数フィッティング: 金属の電気抵抗で使ったintegrateを利用します。

最終的なプログラムはCO2-subcritical_sce.txtです。

clear;

// *** 入力パラメータ ***
// 物理定数
r = 8.31 // 気体定数 (J/K/mol)

// 二酸化炭素のファンデルワールス状態方程式
a = 3.65E-1; // Pa m^6 / mol^2
b = 4.28E-5; // m^3 / mol
// 温度 (K)
t = 250;

// *** ファンデルワールスの状態方程式 **
function p = pvdw(v)
p = r .* t ./ (v - b) - a ./ v ./ v
endfunction

// *** 解くべき方程式 ***
function e = func(pk)
Vx = roots([pk, -1 * (b * pk + r * t), a, - a * b]);
vg = max(real(Vx));
vl = min(real(Vx));
s1 = integrate('pvdw(v)','v',vl,vg);
s2 = (vg - vl) * pk;
e = s1 - s2;
endfunction

// *** 非線形方程式の数値解 ***
pk0 = %eps;
pk = fsolve(pk0,func);

Vx = roots([pk, -1 * (b * pk + r * t), a, - a * b]);
vg = max(real(Vx));
vl = min(real(Vx));

// *** 圧力の計算とプロット ***
// モル体積ベクトル
Vl = linspace(b,vl,1000) + %eps; // (m^3 / mol)
Vm = linspace(vl,vg,1000); // (m^3 / mol)
Vg = linspace(vg,1e-3,1000); // (m^3 / mol)
// 温度
plot(Vl,pvdw(Vl),'-r');
plot(Vm,pk,'-r');
plot(Vm,pvdw(Vm),'--r');
plot(Vg,pvdw(Vg),'-r');
// *** グラフの装飾 ***
xlabel("Molar volume (m^3/mol)");
ylabel("Pressure (Pa)");
plot([b,b],[-1E8,2E7],'--k');
plot([0,0.001],[0,0],'--k');
zoom_rect([0,-2E6,1E-3,2E7]);


関連エントリ




参考URL




付録


このエントリで使用したScilabのシミュレーション用ファイルを添付します。ファイル名末尾の".txt"を削除して、"_"を"."に変更すれば使えるはずです。(参考:ねがてぃぶろぐの付録)


参考文献/使用機器




フィードバック



にほんブログ村 その他趣味ブログ 電子工作へ

 ↑ 電子工作ブログランキング参加中です。1クリックお願いします。


コメント・トラックバックも歓迎です。 ↓      


 ↓ この記事が面白かった方は「拍手」をお願いします。

tag: Scilab 非線形方程式ソルバ 数値積分 状態方程式 熱力学 

Scilabで二酸化炭素の状態方程式 その1

気体の温度・圧力・体積の関係を表す式といえば、理想気体の状態方程式を思い浮かべる人は多いと思います。理想気体の状態方程式は、気体分子自体の体積や気体分子間の相互作用を無視して作られた状態方程式です。しかしながら、実在気体ではこれらの効果が無視できないことがあります。

そこで今回のエントリでは、実在気体の挙動をよりよく再現できるファンデルワールスの状態方程式を計算するプログラムをScilabで作成しました。

\left(P + \frac{a^2}{V} \right) (V-b)=RT

(P: 圧力, V: モル体積, R: 気体定数, T: 絶対温度, a, b: ファンデルワールス定数)

001_20130811163806c85.jpg

Fig.1: 気体の二酸化炭素のイメージ。もっとも、ドライアイスを水に入れたときに発生している白煙は、実際には二酸化炭素ではないのですが・・・。画像は(c)Kim H Yusukeより



理想気体の状態方程式


物質化学の分野では、状態方程式というと、物質の圧力P,温度T,体積Vの間に成り立つ関係式の事を指します。
最も簡単なものとして、理想気体の状態方程式が挙げられます。

PV = RT

(P: 圧力, V: モル体積, R: 気体定数, T: 絶対温度)

この式から分かるとおり、物質はP,V,Tのうち2つを指定すると残りの1つが決まってしまいます。
このようにP,V,Tのうち2つを決めて残り1つを計算することを状態方程式を解くといいます。

ファンデルワールスの状態方程式


理想気体の状態方程式は、以下の2点を仮定しています。

  • 気体分子同士の間に力(分子間力)が働かない
  • 気体分子の大きさは無視できる

しかしながら、実際には分子と分子の間には、ファンデルワールス力による引力が働きます。また、気体分子自身の大きさは、気体全体のモル体積が大きいときは無視できますが、強く圧縮されて(または冷却されて)分子間の距離が近くなると無視できなくなります。

そこでよく用いられるのがファンデルワールスの状態方程式です。

\left(P + \frac{a^2}{V} \right) (V-b)=RT

a,bはファンデルワールス定数と呼ばれるもので、物質によって異なる定数です。

aはファンデルワールス力による分子間の引力を表すパラメータです。圧力のイメージは、ピストン内に閉じ込められた気体が容器の壁を押す力であるといったものですが、気体の分子同士が引き合うとその分、壁を押す力が減ります。

bは別名、排除体積とも呼ばれ、気体分子そのものの体積を反映しています。極めて高圧・低温になってもモル体積はbよりも小さくなりません。

二酸化炭素の状態方程式


ファン・デル・ワールスの状態方程式 (クラウジウス=クラペイロンの式、ジュール=トムソン効果)によると二酸化炭素のファンデルワールス定数は a = 3.65×10-1(Pa m6/mol2), b = 4.28×10-5(m3/mol)です。このパラメータを使ってモル体積Vと絶対温度Tから状態方程式を解いてPを求めるプログラムをScilabで書きます。

作成したプログラムはvdwEOS-CO2_sce.txtです。

002_201308111638065fd.png

Fig.2: 二酸化炭素の状態方程式の2次元プロット。250-350Kの温度範囲にわたってモル体積と温度から圧力を計算した。


同じプログラム中に、3次元プロットをする部分も含めました。
3次元プロットをするための空間グリッド作成にはndgridが便利です。

003_2013081116380518d.png

Fig.3: 二酸化炭素の状態方程式の3次元プロット。200-500Kの温度範囲にわたってモル体積と温度から圧力を計算した。軸が切れてしまっているがZ軸は圧力を表す。


clear;

// *** 入力パラメータ ***
// 物理定数
r = 8.31 // 気体定数 (J/K/mol)

// 二酸化炭素のファンデルワールス状態方程式
a = 3.65E-1; // Pa m^6 / mol^2
b = 4.28E-5; // m^3 / mol
// 理想気体の状態方程式
//a = 0; // Pa m^6 / mol^2
//b = 0; // m^3 / mol

// *** ファンデルワールスの状態方程式 **
deff("p = f(v,t)","p = r .* t ./ (v - b) - a ./ v ./ v");

// 体積・温度ベクトルと計算グリッド
v = [5E-5:1E-5:1E-3]; // 体積ベクトル (m^3 / mol)
t = [200:10:500]; // 温度ベクトル (K)
[V,T] = ndgrid(v,t); // 体積温度空間グリッド

// *** 圧力の計算と2次元グラフのプロット ***
scf(0);
plot(v,f(v,250),'-r');
plot(v,f(v,275),'-g');
plot(v,f(v,300),'-b');
plot(v,f(v,325),'-m');
plot(v,f(v,350),'-c');
// グラフの装飾
xlabel("Molar volume (m^3/mol)");
ylabel("Pressure (Pa)");
plot([b,b],[-1E8,2E7],'--k'); //
plot([0,0.001],[0,0],'--k');
zoom_rect([0,-2E6,1E-3,2E7]);
legend(["T = 250 (K)","T = 275 (K)","T = 300 (K)","T = 325 (K)","T = 350 (K)"],1);

// *** 圧力の計算と3次元グラフのプロット ***
scf(1);
P = f(V,T);
mesh(V,T,P);
// グラフの装飾
a = gca();
a.data_bounds = [0,200,0;1E-3,500,2E7];
xlabel("Volume (m^3/mol)");
ylabel("Temperature (K)");
zlabel("Pressure (Pa)");


関連エントリ




参考URL




付録


このエントリで使用したScilabのシミュレーション用ファイルを添付します。ファイル名末尾の".txt"を削除して、"_"を"."に変更すれば使えるはずです。(参考:ねがてぃぶろぐの付録)


参考文献/使用機器




フィードバック



にほんブログ村 その他趣味ブログ 電子工作へ

 ↑ 電子工作ブログランキング参加中です。1クリックお願いします。


コメント・トラックバックも歓迎です。 ↓      


 ↓ この記事が面白かった方は「拍手」をお願いします。

tag: Scilab 状態方程式 熱力学 

FC2カウンター
カテゴリ
ユーザータグ

LTspiceAkaiKKRmachikaneyamaScilabKKRPSoCOPアンプPICCPA強磁性常微分方程式モンテカルロ解析odeトランジスタ状態密度インターフェーススイッチング回路ecaljPDS5022DOS定電流半導体シェルスクリプト乱数レベルシフトHP6632Aブレッドボード分散関係温度解析R6452Aトランジスタ技術I2C可変抵抗反強磁性セミナー数値積分確率論偏微分方程式バンド構造非線形方程式ソルババンドギャップ絶縁熱設計シュミットトリガLEDA/Dコンバータ三端子レギュレータLM358ISO-I2CGW近似カオスフォトカプラマフィンティン半径TL431数値微分PC817Cアナログスイッチ直流動作点解析発振回路USBサーボカレントミラー74HC4053パラメトリック解析LDAbzqltyチョッパアンプ量子力学FFT2ちゃんねるアセンブラBSch開発環境電子負荷ブラべ格子イジング模型補間基本並進ベクトル標準ロジック単振り子キュリー温度繰り返しMaxima状態方程式失敗談相対論スピン軌道相互作用FETランダムウォーク熱伝導六方最密充填構造コバルトewidthTLP621GGAQSGW不規則合金位相図抵抗SMPcygwinラプラス方程式スレーターポーリング曲線gfortranスイッチト・キャパシタ詰め回路TLP552三角波格子比熱TLP521条件分岐LM555MCUNE555QNAPマントルテスタ過渡解析FXA-7020ZRダイヤモンドデータロガーガイガー管自動計測Writer509UPSシュレディンガー方程式ブラウン運動awk差し込みグラフ熱力学平均場近似仮想結晶近似VCAfsolve井戸型ポテンシャルVESTA起電力スーパーセルOpenMP第一原理計算ubuntu固有値問題L10構造OPA2277interp12SC1815fccウィグナーザイツ胞面心立方構造フィルタジバニャン方程式ヒストグラム確率論マテリアルデザインspecx.f等高線正規分布PGAフェルミ面非線型方程式ソルバ初期値固定スピンモーメントスワップ領域ルチル構造リジッドバンド模型edeltquantumESPRESSO岩塩構造BaOSIC二相共存ZnOウルツ鉱構造フォノンデバイ模型c/aノコギリ波全エネルギーFSMTeXgnuplotmultiplotハーフメタルCapSense半金属合金結晶磁気異方性Ubuntu文字列入出力TS-110TS-112疎行列Excel直流解析ヒストグラム円周率不規則局所モーメントトラックボールPC等価回路モデルパラメータ・モデルキーボードRealforce三次元マンデルブロ集合フラクタル化学反応重積分縮退日本語最小二乗法関数フィッティングGimpMAS830LHiLAPW熱拡散方程式両対数グラフナイキスト線図負帰還安定性陰解法Crank-Nicolson法P-10クーロン散乱境界条件連立一次方程式片対数グラフEAGLEPIC16F785LMC662トランスシンボルCK1026線種凡例MBEAACircuitグラフの分割軸ラベルifort

最新コメント
リンク

にほんブログ村 その他趣味ブログ 電子工作へ