ねがてぃぶろぐ　正規分布

Scilabでブラウン運動その3

Scilabでブラウン運動その2では、単位時間あたりに任意の方向に距離1だけ移動するランダムウォークのスクリプトを書きました。これはScilabでブラウン運動その1では移動できる角度が制限されていたことに対する拡張です。

今回は、さらに発展させて、単位時間あたりに移動する距離もランダムに決定するように拡張を行います。

Fig.1: 一次元のランダムウォーク。各ステップでの移動距離を1に固定したもの(青)と移動距離の平均二乗変位平方根が1となるような正規分布から計算したもの(赤)。赤線は、移動距離が1よりも短いこともあれば長いこともある。

一次元のランダムウォーク

二次元から始めてもよいのですが、移動距離を固定したものとの比較が簡単なため、一次元のスクリプトも示します。
各ステップにおける移動量を乱数で与える場合、どのような乱数を使うかの選択肢がいくつかあると思いますが、今回は正規分布(ガウス関数)としました。Scilabにおいてはgrandを利用することによって正規分布に従う乱数を生成する事ができます。

clear;

// *** 計算の設定 ***
u = 1;					// 1ステップの間の平均二乗変位平方根
av = 0;
tnum = 20;				// 時間ステップ数
t = (0:1:tnum)';			// 時間のベクトル

// *** 位置の計算 ***
// 移動距離が正規分布に従う場合
xigauss = grand(tnum,1,'nor',av,u);
Sgauss = [0; cumsum(xigauss)];
// 移動距離が一定の場合
xifix = 2 * u * (rand(tnum,1) >= 0.5) - u;
Sfix =  [0; cumsum(xifix)];

// *** グラフのプロット ***
plot(t,Sgauss,'-or');
plot(t,Sfix,'-ob');
xlabel("x position");
ylabel("y position");

二次元のランダムウォーク

二次元への拡張を行います。ソースコードを比較するなら今回の一次元のものと比較するよりもScilabでブラウン運動その2の二次元のものと比較する方がわかりやすいです。ほとんど r=1 を r=abs(grand(1,tnum,'nor',av,u)) にしただけなので。

Fig.2: 二次元のランダムウォーク

clear;

// *** 計算の設定 ***
u = 1;					// 1ステップの間の平均二乗変位平方根
av = 0;
tnum = 10000;				// 時間ステップ数
t = (0:1:tnum)';			// 時間のベクトル

// *** 位置の計算 ***
// 移動する距離
r = abs(grand(1,tnum,'nor',av,u));
// 移動する方向
theta = 2 * %pi * rand(1,tnum);
// 移動量
xi = r .* cos(theta);
yi = r .* sin(theta);
// 最終的な座標
S = [zeros(2,1), [cumsum(xi,'c'); cumsum(yi,'c')]];

// *** グラフのプロット ***
plot(S(1,:),S(2,:),'-b');
xlabel("x position");
ylabel("y position");

三次元のランダムウォーク

三次元への拡張もこれまでと全く同様です。

Fig.3: 三次元のランダムウォーク

clear;

// *** 計算の設定 ***
u = 1;					// 1ステップの間の平均二乗変位平方根
av = 0;
tnum = 10000;				// 時間ステップ数
t = (0:1:tnum)';			// 時間のベクトル

// *** 位置の計算 ***
// 移動する距離
r = abs(grand(1,tnum,'nor',av,u));
// 移動する方向
theta = 2 * %pi * rand(1,tnum);
phi   = 2 * %pi * rand(1,tnum);
// 移動量
xi = r .* sin(theta) .* cos(phi);
yi = r .* sin(theta) .* sin(phi);
zi = r .* cos(phi);
// 最終的な座標
S = [zeros(3,1), [cumsum(xi,'c'); cumsum(yi,'c'); cumsum(zi,'c')]];

// *** グラフのプロット ***
param3d(S(1,:),S(2,:),S(3,:));
xlabel("x position");
ylabel("y position");
zlabel("z position");