Scilabで差し込みグラフ:金属の比熱

Scilabで数値積分:固体の比熱では、積分を含む方程式としてあらわされるデバイの比熱式を計算しました。

今回は、アルミニウムの比熱に関して、デバイの比熱式に加えて金属の電子比熱の計算も行い、ほとんどの温度領域においてはデバイの比熱式で表される格子振動の寄与が支配的であり、しかしながら、数ケルビン程度の低温では電子比熱の影響が大きくなることを確認しました。


001_20130606070707.png
Fig.1: アルミニウムの格子比熱・電子比熱の温度依存性のシミュレーション。極めて低温では電子比熱(赤破線)が支配的になるものの、それ以外では格子比熱(青実線)に比べ電子比熱は無視できるほど小さい。



金属の比熱


Scilabで数値積分:固体の比熱では、積分を含む方程式としてあらわされるデバイの比熱式を計算しました。これは、固体の原子の熱振動に起因する熱容量で、格子比熱と呼びます。固体金属の比熱もまた、デバイの比熱式でほとんど問題なく計算できます。

しかしながら、金属の場合は、わずかながら伝導電子に起因する電子比熱も存在します。これは常温では、格子比熱と比較して無視できるほど小さいのですが、数ケルビン程度の極めて低い温度では格子比熱が急速に小さくなるため、電子比熱の寄与が相対的に大きくなります。

今回は、このアルミニウムに関して格子比熱と電子比熱の大きさをScilabで計算し、差し込みグラフ(インセットグラフ)を描画してみます。

プログラミング


格子比熱の計算には、Scilabで数値積分:固体の比熱で計算を行ったデバイモデルを用います。

C_l(T) = 9 R \left( \frac{T}{\Theta_D} \right)^3 \int^{\Theta_D / T}_{0}\frac{x^4 e^x}{(e^x - 1)^2}{\rm d}x

アルミニウムのデバイ温度は428Kとします。(参考:デバイ模型:wikipedia)

電子比熱は、低温では単純に温度に比例することが知られていて、電子比熱係数γを用いて以下のようにあらわします。

C_e(T) = \gamma T

アルミニウムの電子比熱係数は1.35mJ/mol/K^2です。(参考:第4講- 金属の基本物性の電子論-(PDF):志賀@高槻)

// アルミニウムの電子比熱係数(J/mol/K^2)
egamma = 1.35e-3;
// アルミニウムのデバイ温度
dt = 428;
// 気体定数 (J/K/mol)
r = 8.314

// 格子比熱 (Debye model)
function Cl = Cl(T)
Cl = 9 * r * ((T ./ dt) .^ 3) .* integrate('(x .^ 4) .* exp(x) ./ ((exp(x) - 1) .^ 2)','x',0,dt ./ T);
endfunction
// 電子比熱
function Ce = Ce(T)
Ce = egamma .* T;
endfunction

// 高温までのプロット
// 温度ベクトル
T = [1:1:500];
// 格子比熱のプロット
// 絶対零度の計算は出来ないので後から補う
plot([0,T],[0,Cl(T)],'-b');
// 電子比熱のプロット
plot([0,T],[0,Ce(T)],'--r');
legend(['Lattice specific heat';'Electronic specific heat'],2);
xlabel("Temperature (K)");
ylabel("Specific heat (J/K/mol)");

// 低温部分のプロット
xsetech([0.4,0.32,0.5,0.5]);
// 温度ベクトル
T = [1:0.1:10];
// 格子比熱のプロット
// 絶対零度の計算は出来ないので後から補う
plot([0,T],[0,Cl(T)],'-b');
// 電子比熱のプロット
plot([0,T],[0,Ce(T)],'--r');
xlabel("Temperature (K)");
ylabel("Specific heat (J/K/mol)");


格子比熱や電子比熱は、高温までの計算と低温のみの計算の2回の計算を行うため、あらかじめfunctionを用いて関数化してあります。(参考:Scilab入門―電気電子工学で学ぶ数値計算ツール)

差込グラフ(インセットグラフ)は、差し込むほうのグラフを後から小さいサイズで上書きすることで作成することが出来ます。
差し込むグラフの位置とサイズはxsetechで指定することが出来ます。(参考:コマンドxsetech([x座標始点,y座標始点,幅,高さ])を繰り返し使うことで一つのウィンドウに複数のグラフを記述することができます.及びxsetech - プロットのためのグラフィックスウィンドウの サブウィンドウを設定)

また、複数のパネルに分割する場合はsubplotを利用するほうが簡単かもしれません。

// 高温までのプロット
subplot(2,1,1);
// 温度ベクトル
T = [1:1:500];
// 格子比熱のプロット
// 絶対零度の計算は出来ないので後から補う
plot([0,T],[0,Cl(T)],'-b');
// 電子比熱のプロット
plot([0,T],[0,Ce(T)],'--r');
legend(['Lattice specific heat';'Electronic specific heat'],2);
xlabel("Temperature (K)");
ylabel("Specific heat (J/K/mol)");

// 低温部分のプロット
subplot(2,1,2);
// 温度ベクトル
T = [1:0.1:10];
// 格子比熱のプロット
// 絶対零度の計算は出来ないので後から補う
plot([0,T],[0,Cl(T)],'-b');
// 電子比熱のプロット
plot([0,T],[0,Ce(T)],'--r');
xlabel("Temperature (K)");
ylabel("Specific heat (J/K/mol)");


プロット部分を上記のものに差し替えた場合、グラフは以下のようになります。


002_20130606074346.png

Fig.2: subplotで分割した場合


ただし、下のパネルの横軸ラベルが切れてしまうので、きれいな図を描きたい場合は、やはりxsetechのほうがオススメです。

またScilabで関数フィッティング:金属の電気抵抗のように複数のグラフウインドウをひとつのプログラムから立ち上げたい場合は、subplotの代わりにscfでグラフ番号を指定します。

関連エントリ




参考URL




付録


このエントリで使用したScilabのシミュレーション用ファイルを添付します。ファイル名末尾の".txt"を削除して、"_"を"."に変更すれば使えるはずです。(参考:ねがてぃぶろぐの付録)


参考文献/使用機器




フィードバック



にほんブログ村 その他趣味ブログ 電子工作へ

 ↑ 電子工作ブログランキング参加中です。1クリックお願いします。


コメント・トラックバックも歓迎です。 ↓      


 ↓ この記事が面白かった方は「拍手」をお願いします。

tag: Scilab 差し込みグラフ インセットグラフ 比熱 電子比熱 格子比熱 デバイモデル 

Scilabで数値積分: 固体の比熱

固体の比熱の温度依存性は、物質の種類に関わらず大体似たような形のグラフになることが知られています。この関数は、計算が簡単なアインシュタインモデルと正確だが積分の計算をする必要のあるデバイモデルの2種類が知られています。Scilabを利用すると簡単に数値積分をすることが出来ます。

今回のエントリでは、銅を対象にアインシュタインモデル、デバイモデルの両方から比熱を計算します。

001_20130522024102.png
Fig.1: 銅の比熱の温度依存性。青破線がアインシュタインモデル、赤実線がデバイモデルによる計算。



固体の比熱


デュロン=プティの法則によると充分高温の固体の単位モルあたりの比熱は、物質の種類によらずほとんど一定で3R(R = 8.314 J/K/mol :気体定数)です。また絶対零度での比熱はゼロになることも知られています。更に、中間的な温度での温度依存性も適切な温度で規格化をすれば同じ関数の形で表すことが出来ることが知られています。

この関数には、アインシュタインモデルとデバイモデルの2種類が知られています。これら二つのモデルは、どちらも高温でデュロン=プティの法則を再現し、絶対零度でゼロになりますが、中間温度での計算結果が微妙に異なります。デバイモデルのほうがより実験値に近い結果を示すことが知られていますが、数式中に積分を含むため計算が多少困難です。

今回はScilabで数値積分をするサンプルとして、デバイモデルから銅の比熱の温度依存性を計算します。

物質の個性を表す「適切な規格化温度」は、デバイモデルではデバイ温度(ΘD)、アインシュタインモデルではアインシュタイン温度(ΘE)と呼ばれます。銅のデバイ温度は343.5Kで、デバイ温度とアインシュタイン温度は、以下の式で換算できます。(参考:デバイ模型)

\Theta_E = \Theta_D \sqrt[3]{\frac{\pi}{6}}

この関係を使うとアインシュタインモデルとデバイモデルを用いてそれぞれ計算した比熱の温度依存性を比較することが出来ます。

アインシュタインモデルの計算


まずは、積分の必要の無いアインシュタインモデルの計算プログラムを書きます。以下の式に従って、500Kまでの銅の比熱の温度依存性を計算しました。

C_E (T) = 3 R \left(\frac{\Theta_E}{T}\right)^2 \frac{e^{\Theta_E / T}}{(e^{\Theta_E / T}-1)^2}

//Debye temperature (K)
dt = 343.5;
// Einstein temperature (K)
et = dt * (%pi / 6) ^ (1 / 3);
// gas constant (J/K/mol)
r = 8.314

// Temperature
T = [1:1:500];

// Einstein model
Ce = 3 * r * ((et ./ T) .^ 2) .* exp(et ./ T) ./ ((exp(et ./ T) - 1) .^ 2);

plot(T,Ce,'--b');
xlabel("Temperature (K)");
ylabel("Specific heat (J/K/mol)");


デバイモデルの計算


次に、数値積分を用いたデバイモデルの計算プログラムです。アインシュタインモデルのときと同様に500Kまでの比熱の計算をしました。

C_D (T) = 9 R \left(\frac{T}{\Theta_D}\right)^3 \int_0^{\Theta_D / T}\frac{x^4 e^x}{(e^x -1)^2}{\rm d}x

Scilabでの数値積分にはintegrateを利用します。(参考:求積法による積分)

//Debye temperature (K)
dt = 343.5;
// Einstein temperature (K)
et = dt * (%pi / 6) ^ (1 / 3);
// gas constant (J/K/mol)
r = 8.314

// Temperature
T = [1:1:500];

// Debye model
Cd = 9 * r * ((T ./ dt) .^ 3) .* integrate('(x .^ 4) .* exp(x) ./ ((exp(x) - 1) .^ 2)','x',0,dt ./ T);
plot(T,Cd,'-r');
xlabel("Temperature (K)");
ylabel("Specific heat (J/K/mol)");


まとめ


最後に以上の計算をまとめてひとつのグラフ上にプロットします。ついでにグラフの凡例も付けました。(参考:グラフの凡例を描画する)

// Debye temperature (K)
dt = 343.5;
// Einstein temperature (K)
et = dt * (%pi / 6) ^ (1 / 3);
// gas constant (J/K/mol)
r = 8.314

// Temperature
T = [1:1:500];

// Einstein model
Ce = 3 * r * ((et ./ T) .^ 2) .* exp(et ./ T) ./ ((exp(et ./ T) - 1) .^ 2);
// Debye model
Cd = 9 * r * ((T ./ dt) .^ 3) .* integrate('(x .^ 4) .* exp(x) ./ ((exp(x) - 1) .^ 2)','x',0,dt ./ T);

plot(T,Ce,'--b');
plot(T,Cd,'-r');
legend(['Einstein model';'Debye model'],2);
xlabel("Temperature (K)");
ylabel("Specific heat (J/K/mol)");


デバイモデルとアインシュタインモデルを比較すると、高温でデュロン=プティの値になり、絶対零度でゼロになる点が一致します。しかし、中間的な温度ではデバイモデルのほうが高い比熱を示す事がグラフから読み取れます。

参考URL




付録


このエントリで使用したScilabのシミュレーション用ファイルを添付します。ファイル名末尾の".txt"を削除して、"_"を"."に変更すれば使えるはずです。(参考:ねがてぃぶろぐの付録)


参考文献/使用機器




フィードバック



にほんブログ村 その他趣味ブログ 電子工作へ

 ↑ 電子工作ブログランキング参加中です。1クリックお願いします。


コメント・トラックバックも歓迎です。 ↓      


 ↓ この記事が面白かった方は「拍手」をお願いします。

tag: Scilab 数値積分 格子比熱 

FC2カウンター
カテゴリ
ユーザータグ

LTspiceAkaiKKRmachikaneyamaScilabKKRPSoCCPAOPアンプPIC強磁性常微分方程式モンテカルロ解析トランジスタode状態密度DOSインターフェースecaljスイッチング回路定電流PDS5022半導体シェルスクリプト乱数レベルシフトHP6632A温度解析可変抵抗I2Cブレッドボード分散関係トランジスタ技術R6452A数値積分反強磁性バンドギャップ確率論セミナー絶縁偏微分方程式非線形方程式ソルババンド構造熱設計カオスA/DコンバータISO-I2Cフォトカプラ三端子レギュレータシュミットトリガLEDGW近似LM358アナログスイッチ数値微分TL43174HC4053マフィンティン半径発振回路サーボ直流動作点解析カレントミラーPC817CUSB単振り子bzqlty開発環境BSch2ちゃんねる電子負荷イジング模型LDAチョッパアンプ量子力学補間アセンブラFFTブラべ格子標準ロジックパラメトリック解析基本並進ベクトルewidthキュリー温度QSGWGGA失敗談MaximaSMPTLP621スイッチト・キャパシタ熱伝導コバルト相対論スピン軌道相互作用六方最密充填構造繰り返しFETランダムウォークcygwingfortran不規則合金状態方程式ラプラス方程式抵抗スレーターポーリング曲線位相図格子比熱マントルデータロガー自動計測ダイヤモンドガイガー管QNAPUPS固有値問題条件分岐井戸型ポテンシャルシュレディンガー方程式詰め回路MCU第一原理計算起電力熱力学スーパーセルVCALM555仮想結晶近似awkTLP521NE555ubuntufsolveブラウン運動OpenMPVESTA最大値テスタ差し込みグラフFXA-7020ZRWriter509三角波TLP552平均場近似最適化最小値過渡解析LMC662トランスPIC16F785CapSenseMBEナイキスト線図CK1026フィルタP-10負帰還安定性EAGLEAACircuit2SC1815OPA2277PGAノコギリ波縮退非線型方程式ソルバL10構造fcc面心立方構造結晶磁気異方性TeX全エネルギー固定スピンモーメントFSMウィグナーザイツ胞interp1ヒストグラム確率論マテリアルデザインspecx.fジバニャン方程式等高線初期値フェルミ面正規分布c/agnuplotBaO岩塩構造ルチル構造ウルツ鉱構造ZnO重積分SIC二相共存スワップ領域リジッドバンド模型半金属合金multiplotハーフメタルデバイ模型edeltquantumESPRESSOフォノンifortUbuntuマンデルブロ集合キーボードRealforce関数フィッティングフラクタルクーロン散乱CIF化学反応三次元最小二乗法日本語直流解析PCトラックボールExcelTS-110パラメータ・モデル等価回路モデルTS-112疎行列文字列HiLAPW両対数グラフ片対数グラフ熱拡散方程式陰解法境界条件連立一次方程式Crank-Nicolson法グラフの分割軸ラベルヒストグラム不規則局所モーメント入出力円周率Gimp凡例線種シンボルMAS830L

最新コメント
リンク

にほんブログ村 その他趣味ブログ 電子工作へ