Scilabで数値微分 その4

Scilabで数値微分 その1, その2で行った誤差の議論を、誤差の最大値と誤差の平均値について行いました。

こういう議論に意味があるかはわかりませんが。


Scilabで数値微分 その1, その2ではsin(x)のx=0.3πのときの微分値を数値計算するに際して、差分の刻み幅を変えた際に数値計算の誤差(丸め誤差、打切り誤差)がどのように影響するかについて調べました。
今回はxを1から2πの範囲で微分値を計算し、差分の刻み幅を変えた際に数値計算の誤差の平均値や最大値への影響を調べます。

001_20150405230943e9c.png
Fig.1: 数値微分と解析解の比較(丸は誤差の平均値、四角は誤差の最大値)

002_201504052309435a9.png
Fig.2: 数値微分の刻み幅を2倍にした時の変化の度合い(丸は誤差の平均値、四角は誤差の最大値)


Scilabのスクリプトはdiff3.sceです。Scilabで数値微分 その3で作成したdifferential.sciが同じディレクトリにある必要があります。

clear;

// *** 関数の定義を読み出し ***
exec('differential.sci',0);

// *** 計算の設定 ***
xmin = 0;
xmax = 2 * %pi;
x = linspace(xmin,xmax);
dy = cos(x); // 解析解
N = [0:1:50]'; // 刻み幅

// *** 数値微分 ***
for i = 1:length(N)
// 刻み幅
n = N(i);
dx = 1 / 2 ^ n;
// 前進差分
dyf1 = diff_f1(x, dx, sin);
dyf12 = diff_f1(x, 2 * dx, sin);
ERRmeanf1(i) = mean(abs(dy - dyf1));
ERRmaxf1(i) = max(abs(dy - dyf1));
DIFmeanf1(i) = mean(abs(dyf12 - dyf1));
DIFmaxf1(i) = max(abs(dyf12 - dyf1));
// 中心差分
dyf2 = diff_f2(x, dx, sin);
dyf22 = diff_f2(x, 2 * dx, sin);
ERRmeanf2(i) = mean(abs(dy - dyf2));
ERRmaxf2(i) = max(abs(dy - dyf2));
DIFmeanf2(i) = mean(abs(dyf22 - dyf2));
DIFmaxf2(i) = max(abs(dyf22 - dyf2));
// 前進差分に対するRomberg1段
dyf1r = diff_f1r(x, dx, sin);
dyf1r2 = diff_f1r(x, 2 * dx, sin);
ERRmeanf1r(i) = mean(abs(dy - dyf1r));
ERRmaxf1r(i) = max(abs(dy - dyf1r));
DIFmeanf1r(i) = mean(abs(dyf1r2 - dyf1r));
DIFmaxf1r(i) = max(abs(dyf1r2 - dyf1r));
// 中心差分に対するRomberg1段
dyf2r = diff_f2r(x, dx, sin);
dyf2r2 = diff_f2r(x, 2 * dx, sin);
ERRmeanf2r(i) = mean(abs(dy - dyf2r));
ERRmaxf2r(i) = max(abs(dy - dyf2r));
DIFmeanf2r(i) = mean(abs(dyf2r2 - dyf2r));
DIFmaxf2r(i) = max(abs(dyf2r2 - dyf2r));
end

// *** グラフのプロット ***
// *** 誤差のプロット ***
scf(0);
a = gca();
a.data_bounds = [min(N),1E-14; max(N),1];
a.log_flags = "nl";
// 誤差の平均値
plot(N, ERRmeanf1, '-or'); // 前進差分
plot(N, ERRmeanf2, '-om'); // 中心差分
plot(N, ERRmeanf1r, '-ob'); // 前進差分に対するRomberg1段
plot(N, ERRmeanf2r, '-og'); // 中心差分に対するRomberg1段
// 誤差の最大値
plot(N, ERRmaxf1, '-sr'); // 前進差分
plot(N, ERRmaxf2, '-sm'); // 中心差分
plot(N, ERRmaxf1r, '-sb'); // 前進差分に対するRomberg1段
plot(N, ERRmaxf2r, '-sg'); // 中心差分に対するRomberg1段
// *** 刻み幅を変えた際の値の変化 ***
scf(1);
a = gca();
a.data_bounds = [min(N),1E-14; max(N),1];
a.log_flags = "nl";
// 差の平均値
plot(N, DIFmeanf1, '-or'); // 前進差分
plot(N, DIFmeanf2, '-om'); // 中心差分
plot(N, DIFmeanf1r, '-ob'); // 前進差分に対するRomberg1段
plot(N, DIFmeanf2r, '-og'); // 中心差分に対するRomberg1段
// 差の最大値
plot(N, DIFmaxf1, '-sr'); // 前進差分
plot(N, DIFmaxf2, '-sm'); // 中心差分
plot(N, DIFmaxf1r, '-sb'); // 前進差分に対するRomberg1段
plot(N, DIFmaxf2r, '-sg'); // 中心差分に対するRomberg1段


関連エントリ




付録


このエントリで使用したScilabのシミュレーション用ファイルを添付します。ファイル名末尾の".txt"を削除して、"_"を"."に変更すれば使えるはずです。(参考:ねがてぃぶろぐの付録)


参考文献/使用機器




フィードバック



にほんブログ村 その他趣味ブログ 電子工作へ

 ↑ 電子工作ブログランキング参加中です。1クリックお願いします。


コメント・トラックバックも歓迎です。 ↓      


 ↓ この記事が面白かった方は「拍手」をお願いします。

tag: Scilab 数値微分 

Scilabで数値微分 その3

Scilabで数値微分 その1で紹介した数値微分の近似式をScilabのfunctionにまとめました。

// *** 前進差分 ***
function df = diff_f1(x, dx, func)
df = (func(x + dx) - func(x)) ./ dx
endfunction

// *** 中心差分 ***
function df = diff_f2(x, dx, func)
df = (func(x + dx) - func(x - dx)) ./ (2 * dx)
endfunction

// *** 前進差分に対するRomberg1段 ***
function df = diff_f1r(x, dx, func)
df = 2 * (diff_f1(x, dx, func) - 0.5 * diff_f1(x, 2 * dx, func))
endfunction

// *** 中心差分に対するRomberg1段 ***
function df = diff_f2r(x, dx, func)
df = (4 / 3) * (diff_f2(x, dx, func) - 0.25 * diff_f2(x, 2 * dx, func))
endfunction



上記の内容をdifferential.sciのように別ファイルにまとめておけば、以下のように呼び出して使えます。

clear;

// *** 関数の定義を読み出し ***
exec('differential.sci',0);

// *** 計算範囲と刻み幅 ***
n = 10;
xmin = 0;
xmax = 2 * %pi;
dx = 1 / 2 ^ n;
x = linspace(0,xmax);

// *** 正弦波とその微分 ***
y = sin(x);
//dy = diff_f1(x, dx, sin); // 前進差分
//dy = diff_f2(x, dx, sin); // 中心差分
//dy = diff_f1r(x, dx, sin); // 前進差分に対するRomberg1段
dy = diff_f2r(x, dx, sin); // 中心差分に対するRomberg1段

// *** グラフのプロット ***
// グラフの描画
plot(x, y, '-b');
plot(x, dy,'--r');
// グラフの装飾
legend(["sin(x)","d(sin(x))/dx"],3);
zoom_rect([xmin,-1,xmax,1]);


数値微分なので、微分値が具体的な数値として求まります。
xには微分したいxの値を、dxには微小な値を入力しますが、具体的にどの程度の数値が必要なのかはScilabで数値微分 その2を参考に決めます(hの値がこのエントリにおけるdxに相当します)。

そもそも関数の解析的な積分はできない場合が多い反面、微分はできてしまうことが多いので、数値的に微分値を求める需要はあまり多くないのかもしれませんが。

関連エントリ




付録


このエントリで使用したScilabのシミュレーション用ファイルを添付します。ファイル名末尾の".txt"を削除して、"_"を"."に変更すれば使えるはずです。(参考:ねがてぃぶろぐの付録)


参考文献/使用機器




フィードバック



にほんブログ村 その他趣味ブログ 電子工作へ

 ↑ 電子工作ブログランキング参加中です。1クリックお願いします。


コメント・トラックバックも歓迎です。 ↓      


 ↓ この記事が面白かった方は「拍手」をお願いします。

tag: Scilab 数値微分 

Scilabで数値微分 その2

Scilabで数値微分 その1に引き続き数値計算の常識に従ってf(x)=sin(x)の数値微分を行いました。

今回は刻み幅hを可変させたときのf(x,h)の値の変化から、誤差が最小となるhの最適値を探しました。


Scilabで数値微分 その1では数値計算の常識に従ってf(x)=sin(x)のx=0.3πにおける微分値を計算しf'(x)=cos(x)との比較を行いました。

その結果、微分を差分に置き換える際の刻み幅hには最適値があり、大きすぎても小さすぎても良くないということがわかりました。

Scilabで数値微分 その1はf(x)=sin(x)のような簡単な関数だったので、あらかじめ解析的に微分を行うことが出来ました。しかしながらScilabで金属の電子比熱の様にf(x)の計算自体に非線形方程式ソルバを使うような複雑な場合は、真の値と比較して最適なhを探すことは出来ません。むしろ、解析的に微分が出来るような場合は、そもそも数値的に微分をする必要が無いとも言えるので、解析的に微分できないときにどのように最適なhを探すのかというのは重要な問題です。

実践的な刻み幅の決定法


数値計算の常識には以下の様にあります。

実践的には,f1(x,h)とf1(x,2h)との"差"を観察して,
「hを半分にしたとき"差"が約半分になる傾向が保たれる範囲でもっとも小さなh」
をえらぶのがよい.


そこでこの計算をScilabで行います。

Scilabプログラム


作成したScilabのプログラムはdiff2_sce.txtとなりました。

clear;

// *** 刻み幅の設定 ***
n = [0:1:50];
h = 2 ^ (- n);

x = 0.3 * %pi;

// *** 微分の近似値 ***
// 前進差分
f1 = (sin(x + h) - sin(x)) ./ h;
f12 = (sin(x + 2 * h) - sin(x)) ./ (2 * h);
// 中心差分
f2 = (sin(x + h) - sin(x - h)) ./ (2 * h);
f22 = (sin(x + 2 * h) - sin(x - 2 * h)) ./ (4 * h);
// 前進差分に対するRomberg 1段公式
romberg1 = 2 * ((sin(x + h) - sin(x)) ./ h - 0.5 * (sin(x + 2 * h) - sin(x)) ./ (2 * h));
romberg12 = 2 * ((sin(x + 2 * h) - sin(x)) ./ (2 * h) - 0.5 * (sin(x + 4 * h) - sin(x)) ./ (4 * h));
// 中心差分に対するRomberg 1段
romberg2 = ((sin(x + h) - sin(x - h)) ./ (2 * h) - 0.25 * (sin(x + 2 * h) - sin(x - 2 * h)) ./ (4 * h)) / 0.75;
romberg22 = ((sin(x + 2 * h) - sin(x - 2 * h)) ./ (4 * h) - 0.25 * (sin(x + 4 * h) - sin(x - 4 * h)) ./ (8 * h)) / 0.75;

// *** グラフの軸設定 ***
a = gca();
a.data_bounds = [0,1E-14;50,1];
a.log_flags = "nl";

// *** グラフのプロット ***
plot(n,abs(f1 - f12),'-sr');
plot(n,abs(f2 - f22),'-sm');
plot(n,abs(romberg1 - romberg12),'-sb');
plot(n,abs(romberg2 - romberg22),'-sg');

// *** グラフの体裁 ***
xlabel("n");
ylabel("Err");
legend(['f1(x)','f2(x)','Romberg f1(x)','Romberg f2(x)'],4);


結果


Scilabで数値微分 その1で計算した数値微分と解析解の比較「f(x,h)-f'(x)」をFig.1に、今回計算した「f(x,h)-f(x,2h)」をFig.2に示します。これらは非常に良く似た形をしていますが全くの別物です。

001_20131110042107c73.png

Fig.1: 数値微分と解析解の比較

002_20131110080640da7.png
Fig.2: 数値微分の刻み幅を2倍にしたときの変化の度合い


数値計算の常識には以下の様にあります。

このような"差分"が「規則的に変化している」ことが,「打切り誤差が丸め誤差より優越していて,通常の打切り誤差の漸近理論が適用できる」ことの実際的な判別法として役立つ.


Fig.2をみるとnを大きくしていっても(つまりhを小さくしていっても)規則的に"差分"が小さくなっていっている部分が、丸め誤差の影響を受けず、打切り誤差が支配的となっている領域です。この範囲でもっとも大きなn(もっとも小さなh)を選んだとき、実際の誤差がほぼ最小になっていることがFig.1との比較から読み取れます。

関連エントリ




付録


このエントリで使用したScilabのシミュレーション用ファイルを添付します。ファイル名末尾の".txt"を削除して、"_"を"."に変更すれば使えるはずです。(参考:ねがてぃぶろぐの付録)


参考文献/使用機器




フィードバック



にほんブログ村 その他趣味ブログ 電子工作へ

 ↑ 電子工作ブログランキング参加中です。1クリックお願いします。


コメント・トラックバックも歓迎です。 ↓      


 ↓ この記事が面白かった方は「拍手」をお願いします。

tag: Scilab 数値微分 

Scilabで数値微分 その1

数値計算から関数の微分を求めようと考えたとき、微分の定義の通りに差分を計算すれば良いということはすぐに思いつきます。

f'(x) = \lim_{h \to 0} \frac{f(x+h)-f(x)}{h}

上記の式のhを次第に小さくしていけばf'(x)の近似値が得られます。
しかしながらhの数を小さくしすぎると数値計算の丸め誤差の影響で逆にf'(x)の値からずれていってしまうことが知られています。

これに関連する重要なポイントをまとめると以下の3つになります。

  • 倍精度浮動小数点数を使い丸め誤差を小さくする
  • 打切り誤差の小さいアルゴリズムを使う
  • 丸め誤差と打切り誤差のトータルで誤差が小さくなるhを探す


Scilabは特に指定をしなくても倍精度浮動小数点数演算をしてくれるので、今回は数値計算の常識に倣って数値微分の式とhの大きさを色々と変更したときに誤差の大きさがどのようになるのかを見てみます。


数値微分の近似式


数値微分を計算する公式として数値計算の常識に倣って前進差分f1(x)、中心差分f2(x)、及びそれらのRomberg 1段公式を用いました。

前進差分
f_1(x,h) = \frac{f(x+h)-f(x)}{h}

中心差分
f_2(x,h) = \frac{f(x+h)-f(x-h)}{2h}

前進差分に対するRomberg 1段
\frac{f_1(x,h)-\frac{1}{2}f_1(x,2h)}{1-\frac{1}{2}}

中心差分に対するRomberg 1段
\frac{f_2(x,h)-\frac{1}{4}f_2(x,2h)}{1-\frac{1}{4}}

Scilabプログラム


実際に計算する関数は普通のサイン関数f(x)=sin(x)とします。
当然ながら解析的に微分が可能でf'(x)=cos(x)です。

数値計算の常識と同様にx=0.3πのときの微分を計算します。

微分の刻み幅hは
h = 2^{-n}

とし、nが大きくなるほどhは小さくなります。

作成したScilabのプログラムはdiff_sce.txtです。

clear;

// *** 刻み幅の設定 ***
n = [0:1:50];
h = 2 ^ (- n);

x = 0.3 * %pi;

// *** 微分の近似値 ***
// 前進差分
f1 = (sin(x + h) - sin(x)) ./ h;
// 中心差分
f2 = (sin(x + h) - sin(x - h)) ./ (2 * h);
// 前進差分に対するRomberg 1段公式
romberg1 = 2 * ((sin(x + h) - sin(x)) ./ h - 0.5 * (sin(x + 2 * h) - sin(x)) ./ (2 * h));
// 中心差分に対するRomberg 1段
romberg2 = ((sin(x + h) - sin(x - h)) ./ (2 * h) - 0.25 * (sin(x + 2 * h) - sin(x - 2 * h)) ./ (4 * h)) / 0.75;

// *** グラフの軸設定 ***
a = gca();
a.data_bounds = [0,1E-16;50,1];
a.log_flags = "nl";

// *** グラフのプロット ***
plot(n,abs(f1 - cos(x)),'-sr');
plot(n,abs(f2 - cos(x)),'-sm');
plot(n,abs(romberg1 - cos(x)),'-sb');
plot(n,abs(romberg2 - cos(x)),'-sg');

// *** グラフの体裁 ***
xlabel("n");
ylabel("Err");
legend(['f1(x)','f2(x)','Romberg f1(x)','Romberg f2(x)'],4);


結果


以下に示すFig.1は上記の4つの式で計算したf(x)のx=0.3πでの微分の値とf'(x)=cos(x)の値の差の絶対値を取ったものです。
この2つの差が数値計算の誤差ということになります。

001_20131110042107c73.png

Fig.1: 数値微分と解析的な微分の間の関係。縦軸は誤差の絶対値、横軸はnで、nが大きくなるほどhは小さくなる(h = 2-n)。


まずn>25では、全てのグラフにおいて同じ挙動を示しています。これが丸め誤差によるものでどの式を使っても丸め誤差の問題は改善されないことが分かります。

次にnが小さい側、すなわち打切り誤差の影響を見てみます。
前進差分f1(x)(赤)と中心差分f2(x)(ピンク)を比べてみると、nが小さいとき中心差分f2(x)(ピンク)の方が誤差が小さくなることが分かります。

また前進差分f1(x)(赤)とそのRomberg 1段(青)を比較すると、Romberg 1段(青)で打切り誤差が改善していることが見て取れます。

中心差分f2(x)(ピンク)とf1(x)に対するRomberg 1段(青)では誤差はほとんど変わりませんが、中心差分f2(x)(ピンク)にさらにRomberg 1段(緑)をおこなうとこれら4つの式の中で最も誤差の少ない式に出来ることがわかります。

関連エントリ




付録


このエントリで使用したScilabのプログラムを添付します。ファイル名末尾の".txt"を削除して、"_"を"."に変更すれば使えるはずです。(参考:ねがてぃぶろぐの付録)


参考文献/使用機器




フィードバック



にほんブログ村 その他趣味ブログ 電子工作へ

 ↑ 電子工作ブログランキング参加中です。1クリックお願いします。


コメント・トラックバックも歓迎です。 ↓      


 ↓ この記事が面白かった方は「拍手」をお願いします。

tag: Scilab 数値微分 

Scilabで金属の電子比熱

Scilabで金属の化学ポテンシャルでは非線形方程式ソルバfsolveを使って金属の化学ポテンシャルを温度の関数として求めました。これを利用すると電子系の内部エネルギーが温度ごとに計算できます。

今回は、この電子系のエネルギーを温度で数値微分して電子比熱を計算しました。

001_20130616223024.png


電子比熱


電子比熱は、電子系のエネルギーue(T)を温度Tで微分することによって得られます。

c_e(T) = \frac{\mathrm{d}u_e(T)}{\mathrm{d}T}

電子系の内部エネルギーは

u_e(T) = \int_{-\infty}^{\infty}\epsilon f(\epsilon,T) D(\epsilon) \mathrm{d}\epsilon

f(\epsilon,T) = \frac{1}{\exp{\left(\frac{\epsilon - \mu(T)}{k_B - T}\right)}+1}

として表されるため前回数値データとして得られた化学ポテンシャルμ(T)を代入することによって、温度の関数としてue(T)の数値データを得ることが出来ます。

今回は、微分を数値的に行うことによってue(T)からce(T)を求めます。

数値微分


数値的な微分とは、実際には数値差分です。
微分の定義は

f^{'}(x) = \lim_{\Delta x \to 0} \frac{f(x+\Delta x) - f(x)}{\Delta x}

なのでΔxが充分小さければ

f^{'}(x) \simeq \frac{f(x+\Delta x)-f(x)}{\Delta x}

と引き算(差分)と割り算で計算できます。

プログラミング


電子比熱の微分を差分に置き換えると

c_e(T) = \frac{u_e (T+\Delta T)-u_e(T)}{\Delta T}

差分はベクトルueの中の隣り合うようその引き算からもとまりますが、これを一気にやってくれるScilab関数がdiffです。
今回のソースコードでは、化学ポテンシャルμ(T)を計算するループの中でついでに内部エネルギーue(T)を計算した後
// 数値計算による電子比熱
dUdT = diff(Uenum) / tstep;
Cenum = [0,dUdT];

として差分を求めています。
差分を求める際に、ベクトルのようその数がひとつ減ってしまうので、先頭にT=0のときの値ce=0を補っています。

作成したソースコードはElectronicSpecificHeat_sce.txtです。

結果と考察


電子比熱の温度依存性のグラフをFig.1に示します。
これまでの計算ではリュードベリ原子単位系を使ってきましたが、実験データと直接比較できるように縦軸がモル比熱となるようにしました。


001_20130616223024.png
Fig.1: 自由電子近似を用いたアルミニウムの電子比熱の温度依存性。青実線はゾンマーフェルト展開、赤破線は数値計算による結果。


前回書いたとおりゾンマーフェルト展開から

c_e(T) = \frac{\pi^2}{3} k_B^2 D(\epsilon_F)T

またScilabで差し込みグラフ:金属の比熱で書いたとおり金属の低温での電子比熱は、電子比熱係数γを用いて

c_e(T) = \gamma T

と書ける事が実験から知られています。

これらを比較すると

\gamma = \frac{\pi^2}{3} k_B^2 D(\epsilon_F)

となります。

実験から求められた電子比熱係数はγ=1.35(mJ/mol/K^2)です。これに対して「自由電子近似+ゾンマーフェルト展開」で求めたものはγ=0.91(mJ/mol/K-2)となり、自由電子近似はアルミニウムに対しておおよそ妥当といったところだと思います。(参考:Lin et al. 2008 Phys. Rev. B)

数値微分に関してなのですが、今回は温度の刻み幅を一定にしてしまったため、本当は低温側で刻み幅が温度そのものと比較して小さくならない様になってしまっています。このことは微分の結果をおかしくしてしまう筈なのですが、そもそもほとんど直線になるような式であったため、その効果が見えていないようです。もっと複雑な式を微分するときには注意しなければなりません。

数値計算とゾンマーフェルト展開の比較は、前回と同様です。
自由電子近似を用いたアルミニウムの電子状態では、融点以上までゾンマーフェルト展開は妥当であるといえそうです。

関連エントリ




参考URL




付録


このエントリで使用したLTspiceのシミュレーション用ファイルを添付します。ファイル名末尾の".txt"を削除して、"_"を"."に変更すれば使えるはずです。(参考:ねがてぃぶろぐの付録)


参考文献/使用機器




フィードバック



にほんブログ村 その他趣味ブログ 電子工作へ

 ↑ 電子工作ブログランキング参加中です。1クリックお願いします。


コメント・トラックバックも歓迎です。 ↓      


 ↓ この記事が面白かった方は「拍手」をお願いします。

tag: Scilab 比熱 電子比熱 数値微分 

FC2カウンター
カテゴリ
ユーザータグ

LTspiceAkaiKKRmachikaneyamaScilabKKRPSoCCPAOPアンプPIC強磁性常微分方程式モンテカルロ解析トランジスタode状態密度DOSインターフェースecaljスイッチング回路定電流PDS5022半導体シェルスクリプト乱数レベルシフトHP6632A温度解析可変抵抗I2Cブレッドボード分散関係トランジスタ技術R6452A数値積分反強磁性バンドギャップ確率論セミナー絶縁偏微分方程式非線形方程式ソルババンド構造熱設計カオスA/DコンバータISO-I2Cフォトカプラ三端子レギュレータシュミットトリガLEDGW近似LM358アナログスイッチ数値微分TL43174HC4053マフィンティン半径発振回路サーボ直流動作点解析カレントミラーPC817CUSB単振り子bzqlty開発環境BSch2ちゃんねる電子負荷イジング模型LDAチョッパアンプ量子力学補間アセンブラFFTブラべ格子標準ロジックパラメトリック解析基本並進ベクトルewidthキュリー温度QSGWGGA失敗談MaximaSMPTLP621スイッチト・キャパシタ熱伝導コバルト相対論スピン軌道相互作用六方最密充填構造繰り返しFETランダムウォークcygwingfortran不規則合金状態方程式ラプラス方程式抵抗スレーターポーリング曲線位相図格子比熱マントルデータロガー自動計測ダイヤモンドガイガー管QNAPUPS固有値問題条件分岐井戸型ポテンシャルシュレディンガー方程式詰め回路MCU第一原理計算起電力熱力学スーパーセルVCALM555仮想結晶近似awkTLP521NE555ubuntufsolveブラウン運動OpenMPVESTA最大値テスタ差し込みグラフFXA-7020ZRWriter509三角波TLP552平均場近似最適化最小値過渡解析LMC662トランスPIC16F785CapSenseMBEナイキスト線図CK1026フィルタP-10負帰還安定性EAGLEAACircuit2SC1815OPA2277PGAノコギリ波縮退非線型方程式ソルバL10構造fcc面心立方構造結晶磁気異方性TeX全エネルギー固定スピンモーメントFSMウィグナーザイツ胞interp1ヒストグラム確率論マテリアルデザインspecx.fジバニャン方程式等高線初期値フェルミ面正規分布c/agnuplotBaO岩塩構造ルチル構造ウルツ鉱構造ZnO重積分SIC二相共存スワップ領域リジッドバンド模型半金属合金multiplotハーフメタルデバイ模型edeltquantumESPRESSOフォノンifortUbuntuマンデルブロ集合キーボードRealforce関数フィッティングフラクタルクーロン散乱CIF化学反応三次元最小二乗法日本語直流解析PCトラックボールExcelTS-110パラメータ・モデル等価回路モデルTS-112疎行列文字列HiLAPW両対数グラフ片対数グラフ熱拡散方程式陰解法境界条件連立一次方程式Crank-Nicolson法グラフの分割軸ラベルヒストグラム不規則局所モーメント入出力円周率Gimp凡例線種シンボルMAS830L

最新コメント
リンク

にほんブログ村 その他趣味ブログ 電子工作へ