Scilabで床で跳ねるボール

matlab 衝突のシミュレーションで質問された床ではねるボールのシミュレーションをScilabで行いました。

001_2015012510244301d.png
Fig.1: 跳ねるボールのシミュレーション


この問題は、常微分方程式ソルバodeと非線形方程式ソルバfsolveの二つを組み合わせることによってシミュレーションすることができます。


問題設定


高さx0から初速度v0でボールを投げる。ボールは重力加速度gで下方へ引かれ、床に落下する。落下したボールは、反発係数kで上方へ跳ねるとする。

この問題はmatlab 衝突のシミュレーション跳ねるボールのシミュレーションです。今回のエントリでは、この問題をScilabでシミュレーションします。

常微分方程式ソルバ


まず前半部分の放物運動は、常微分方程式ソルバodeを用いて簡単に計算できます。(参考: 常微分方程式タグ)

解くべき連立常微分方程式は以下のようになります。

\frac{\mathrm{d}x}{\mathrm{d}t} = v
\frac{\mathrm{d}v}{\mathrm{d}t} = -g

非線形方程式ソルバ


次に床で跳ねる計算を行います。
床ではねる直前の速度をv-,直後の速度をv+とすると反発係数kを用いて

v+ = - k v-

となります。

前述の常微分方程式を非線形方程式ソルバfsolveを利用して x=0 となる時刻を計算し、それぞれの跳ねるイベントの間の計算を行えば、この問題を解くことができます。

プログラム


結局Scilabスクリプトはball_sce.txtとなりました。

clear;

// *** 計算条件 ***
g = 9.81; // 重力加速度
k = 0.8; // 反発係数
// 時間
ts = 0; // 開始時刻
te = 10; // 終了時刻
// 初期条件
x0 = 10; // 初期位置
v0 = 15; // 初速度

// *** 常微分方程式の定義 ***
function dx = fall(t,x)
dx(1) = x(2); // dx/dt = v
dx(2) = -g; // dv/dt = -g
endfunction

// *** 解くべき非線形方程式 ***
function x = bound(t)
X = ode([x0; v0], ts, t, fall);
x = X(1);
endfunction

// *** メイン ***
// 初期化
tb = ts; // 衝突時刻
X = []; // プロット用の位置と速度
T = []; // プロット用の時間
// 終了時刻まで繰り返し
while tb < te
// 衝突時刻を計算
tb = fsolve(2 * te, bound);
// プロット用の時間ベクトルを作成
if tb > te then
// 終了時刻まで
time = linspace(ts, te);
else
// 衝突時刻まで
time = linspace(ts, tb);
end
T = [T, time];
// プロット用の位置と速度を計算
X = [X, ode([x0; v0], ts, time, fall)];
// 次の繰返しのための初期条件
x0 = 0; // 初期位置
v0 = -k * X(2,$); // 初速度
ts = tb; // 計算開始時刻
end

// *** グラフのプロット ***
// 位置のプロット
subplot(2,1,1);
plot(T, X(1,:),'g');
xgrid(color("gray"));
xlabel("Time");
ylabel("Position");
// 速度のプロット
subplot(2,1,2);
plot(T, X(2,:),'r');
xgrid(color("gray"));
xlabel("Time");
ylabel("Velocity");


関連エントリ




参考URL




付録


このエントリで使用したScilabのシミュレーション用ファイルを添付します。ファイル名末尾の".txt"を削除して、"_"を"."に変更すれば使えるはずです。(参考:ねがてぃぶろぐの付録)


参考文献/使用機器




フィードバック



にほんブログ村 その他趣味ブログ 電子工作へ

 ↑ 電子工作ブログランキング参加中です。1クリックお願いします。


コメント・トラックバックも歓迎です。 ↓      


 ↓ この記事が面白かった方は「拍手」をお願いします。

tag: Scilab 非線形方程式ソルバ 常微分方程式 

Scilabでガウス型波束の散乱

Scilabを用いて初期波動関数がガウス型をしている波束が、ポテンシャルの谷によって散乱される様子をシミュレーションしました。

001.gif

Fig.1: ガウス型波束がポテンシャルの谷間によって散乱される様子を表したアニメーション。赤が波動関数の絶対値、緑が波動関数の実部を表す。青はポテンシャルの形状。



偏微分方程式


ねがてぃぶろぐでは微分方程式による物理現象のモデル化(PDF)で紹介されている常微分方程式をScilabで計算してきました。
次のテーマである波束の運動の問題は、時間微分だけの常微分方程式ではなく、時間と空間の両方の微分を含む偏微分方程式です。

ScilabやOctaveには偏微分方程式を解くための特別な関数は用意されていません。そこで、偏微分方程式を解くためには微分を差分に置き換えた計算が必要になります。Scilabで一次元井戸型ポテンシャルScilabで規則ポテンシャルと縮退では位置の微分であるエネルギー演算子を含むハミルトニアンを行列で表すことによって、固有値問題を解くための命令であるspecを利用することにより計算しました。

今回はScilabで一次元井戸型ポテンシャルと同様にハミルトニアンを行列であらわし、常微分方程式ソルバodeと組み合わせることにより、時間に依存するシュレディンガー方程式を解いてガウス型波束が散乱される様子をシミュレーションします。


ガウス型波束の運動


シッフの量子力学の本(上巻 下巻)によるとx軸の正の方向に運動量を持つ波束の波動関数は以下のように表されます。

\psi(x) = \frac{1}{\sqrt[4]{2 \pi (\Delta x)^2}} \exp\left(- \frac{(x-\langle x \rangle)^2}{4(\Delta x)^2}+\frac{i\langle p \rangle}{\hbar}x \right)

今回は、このガウス型波束を初期値に持つ波動関数がポテンシャルの谷に散乱される様子をScilabを用いてシミュレーションします。


時間に依存するシュレディンガー方程式


時間に依存するシュレディンガー方程式は、以下の様に表されます。

i \hbar \frac{\partial \psi (x,t)}{\partial t} = \left(- \frac{\hbar}{2m}\frac{\partial^2}{\partial x^2} + V(x) \right)\psi(x,t)

時間に依存しないシュレディンガー方程式の場合と同様に

\hbar = 1, m = \frac{1}{2}

とおくと、ハミルトニアンHは以下のようにかけます。

H = - \frac{\partial^2}{\partial x^2} + V(x)

この段階で時間に依存するシュレディンガー方程式は以下のように書くことが出来ます。

i\frac{\partial \psi}{\partial t} = H \psi

ここまでくればScilabの常微分方程式ソルバodeで解けることが分かります。
dψ/dt = ...の形にすると

\frac{\partial \psi}{\partial t} = -i H \psi

となり、これが今回の解くべき方程式となります。

微分方程式による物理現象のモデル化(PDF)によるとOctaveの常微分方程式ソルバであるlsodeは複素数に対応していないとのことですが、Scilabのodeは複素数に対応しているので、今回はodeを利用してシュレディンガー方程式を解きます。


疎行列


Scilabで一次元井戸型ポテンシャルで書いたとおり、ハミルトニアンを行列として書き下すと、以下のようにほとんどの成分がゼロとなります。

\begin{eqnarray*} H &=& - \frac{\mathrm{d}^2}{\mathrm{d}x^2} + V \\ &=& \left( \begin{array}{ccccccc} \frac{2}{h^2} + v_1 & -\frac{1}{h^2} & 0 & \hdots & & \hdots & 0 \\ -\frac{1}{h^2} & \frac{2}{h^2} + v_2 & -\frac{1}{h^2} & 0 & \hdots & & \vdots \\ 0 & -\frac{1}{h^2} & \frac{2}{h^2} + v_3 & -\frac{1}{h^2} & 0 & \hdots & \\ \vdots & \ddots & \ddots & \ddots & \ddots & \ddots & \vdots \\ & \hdots & 0 & -\frac{1}{h^2} & \frac{2}{h^2} + v_{n-2} & -\frac{1}{h^2} & 0 \\ \vdots &  & \hdots & 0 & -\frac{1}{h^2} & \frac{2}{h^2} + v_{n-1} & -\frac{1}{h^2} \\ 0 & \hdots &  & \hdots & 0 & -\frac{1}{h^2} & \frac{2}{h^2} + v_n \end{array} \right) \end{eqnarray*}

このようにゼロでない要素が全体の中でごくわずかしかない行列を疎行列と呼びます。Scilabでは疎行列を扱う特別なデータ型があり、普通に定義した行列に対して

sp = sparse(X);


とすることによって疎行列へ変換することが出来ます。(参考:sparse)

今回の計算のハミルトニアンのようにゼロとなる要素が多い場合は、疎行列型へ変換することにより計算速度が劇的に速くなります。


数値計算


微分方程式による物理現象のモデル化(PDF)のように100stepごとに700ステップまで表示するScilabのプログラムがschiff-gv_sce.txtです。

clear;

vw = 0.064; // ポテンシャルの幅
vh = - (70.7 * %pi) ^ 2; // ポテンシャルの深さ
dim = 500; // 空間の分割数
h = 2.0 / dim; // 空間の刻み幅

// *** 位置ベクトル ***
X = linspace(-1,1,dim + 1);

// *** ハミルトニアンの定義 ***
// エネルギー演算子
vd = 2 / h ^ 2;
vdt = - 1 / h ^ 2;
SD = diag(vdt * ones(1,dim),1);
D = diag(vd * ones(1,dim + 1));
H = SD + D + SD.';
// ポテンシャル
V = zeros(H);
for i = 1:dim + 1 do
if abs(X(i)) < vw / 2 then
V(i,i) = vh;
end
end
// 全ハミルトニアン
H = sparse(H + V); // 疎行列へ変換するほうが実行速度が速い

// *** 常微分方程式の定義 ***
function dphi = schiff(t,phi)
dphi = - %i * H * phi;
endfunction

// *** 波束の初期設定 ***
xe = - 0.3; // 初期波束の位置の期待値(波束の中心位置)
dx = 0.035; // 初期波束の空間的広がり
pe = 50 * %pi; // 初期波束の運動量の期待値
phi0 = zeros(dim + 1,1);
for k = 1:dim + 1 do
// 初期波束
phi0(k) = exp(-(X(k) - xe) ^ 2 / (4 * dx ^ 2) + %i * pe * X(k)) ..
/ (2 * %pi * (dx) ^ 2) ^ 0.25;
end

// *** 時間刻みの設定 ***
dt = h ^ 2 / 4;
nstep = 700;
itvl = 100;
tf = dt * itvl;
T = [0:dt:tf];

// *** プロット ***
// ポテンシャルのプロット
subplot(3,3,1);
plot(X,diag(V));
// 目盛りを非表示にする
g = gca();
g.axes_visible = 'off';
zoom_rect([-0.5,-5,0.5,5]);
// 初期値のプロット
subplot(3,3,2);
plot(X,diag(V)); // ポテンシャルのプロット
plot(X,real(phi0),'-g'); // 波動関数の実部のプロット
plot(X,abs(phi0),'-r'); // 波動関数の絶対値のプロット
// ステップ数を表示
xstring(0.1,3,"step = 0");
// 目盛りを非表示にする
g = gca();
g.axes_visible = 'off';
zoom_rect([-0.5,-5,0.5,5]);

for k = 1:nstep/itvl do
// 微分方程式の数値解
phi = ode(phi0,0,T,schiff);
// ポテンシャルと波動関数のプロット
subplot(3,3,k + 2);
plot(X,diag(V)); // ポテンシャルのプロット
plot(X,real(phi(:,itvl)),'-g'); // 波動関数の実部のプロット
plot(X,abs(phi(:,itvl)),'-r'); // 波動関数の絶対値のプロット
// ステップ数を表示
stepnum = string(k * itvl);
xstring(0.1,3,strcat(["step = ",stepnum]));
// 目盛りを非表示にする
g = gca();
g.axes_visible = 'off';
zoom_rect([-0.5,-5,0.5,5]);
// 最後の波動関数を次の初期値に設定
phi0 = phi(:,itvl);
end


Fig.1のGIFアニメーションはschiff-gv-gif_sce.txtで作成したGIF画像をGimpやImagemagickで結合したものです。
Scilabの計算結果をGIFアニメーションにする方法はのちのち別のエントリにまとめようと思っています。

GIF動画に関連する情報は以下のリストにあります。


関連エントリ




参考URL




付録


このエントリで使用したScilabのシミュレーション用ファイルを添付します。ファイル名末尾の".txt"を削除して、"_"を"."に変更すれば使えるはずです。(参考:ねがてぃぶろぐの付録)


参考文献/使用機器




フィードバック



にほんブログ村 その他趣味ブログ 電子工作へ

 ↑ 電子工作ブログランキング参加中です。1クリックお願いします。


コメント・トラックバックも歓迎です。 ↓      


 ↓ この記事が面白かった方は「拍手」をお願いします。

tag: Scilab ode 常微分方程式 偏微分方程式 疎行列 量子力学 

Scilabで化学反応

私の練習のためにScilabで微分方程式による物理現象のモデル化(PDF)の問題を順番に解いてきました。最早、基本的な常微分方程式ならその物理的な背景を理解していなくてもルーチンワークでプログラムを書くだけで計算できてしまいます。

今回は、可逆反応と非可逆反応の反応が進む様子をシミュレーションします。

001_20130802112714a35.jpg

Fig.1: 化学反応は反応物質の数に依存して反応速度が異なる。また、可逆反応と非可逆反応では反応速度を表す微分方程式の形が異なる。画像は(c)GLOBALHAWK90



非可逆反応


非可逆な化学反応とは、反応する化学物質
非可逆反応の微分方程式とその解析解をプロットするScilabプログラムを作成します。

常微分方程式:
\frac{\mathrm{d}x}{\mathrm{d}t} = k(a-x)(b-x)

解析解:
x(t) = \begin{cases}ab\frac{\exp(gt) -\exp(-gt)}{a\exp(gt)-b\exp(-gt)} & (a > b) \\a - \frac{1}kt-\frac{1}{a}} & (a = b)\end{cases}

プログラムはunreversible_sce.txtです。

002_201308021127143ec.png

Fig.2: 非可逆反応の計算結果。


clear;

// ************************************
//
// 共通部分
//
// ************************************
// *** 入力パラメータ ***
a = 1;
k1 = input("k1 = ");
k2 = input("k2 = ");
// 時間ベクトル
T = linspace(0,10);

// ************************************
//
// 数値解
//
// ************************************
// 解くべき微分方程式
function dx = unreversible(t,x)
dx = k1 * (a - x) ^ 2 - k2 * x;
endfunction
// 初期値
x0 = 0;
// 微分方程式の数値解
X = ode(x0,0,T,unreversible);

// ************************************
//
// 解析解
//
// ************************************
b1 = (2 * a + k2 / k1 + sqrt(4 * a * k2 / k1 + (k2 / k1) ^ 2)) / 2;
b2 = (2 * a + k2 / k1 - sqrt(4 * a * k2 / k1 + (k2 / k1) ^ 2)) / 2;
d = sqrt(4 * a * k2 / k1 + (k2 / k1) ^ 2);
Xa = b2 * (exp(k1 * d * T) - 1) ./ (exp(k1 * d * T) - b2 / b1);

// ************************************
//
// プロット
//
// ************************************
plot(T,X,'or');
plot(T,Xa,'-g');
xtitle(strcat(["Chemical Reaction: ","a = ",string(a),", k1 = ",string(k1),", k2 = ",string(k2)]));
xlabel("$t [s]$");
ylabel("$N_x$");
legend(["Numerical","Analytical"],4);


可逆反応


可逆反応の微分方程式と解析解をプロットするScilabプログラムを作成します。

常微分方程式:
\frac{\mathrm{d}x}{\mathrm{d}t} = k_1 (a-x)^2 - k_2 x

解析解:
x(t) = b_2 \frac{\exp(k_1 \Delta b t)-1}{\exp(k_1 \Delta b t) - \frac{b_2}{b_1}}

ただし
b_1 = \frac{2a+\frac{k_2}{k_1} + \sqrt{4a\frac{k_2}{k_1}+\left(\frac{k_2}{k_1} \right)^2}}{2}

b_2 = \frac{2a+\frac{k_2}{k_1} - \sqrt{4a\frac{k_2}{k_1}+\left(\frac{k_2}{k_1} \right)^2}}{2}

\Delta b = b1 - b2 = \sqrt{4a\frac{k_2}{k_1}+\left(\frac{k_2}{k_1} \right)^2}


プログラムはbalanced_sce.txtです。

003_20130802112714957.png

Fig.3: 可逆反応の計算結果。


clear;

// ************************************
//
// 共通部分
//
// ************************************
// *** 入力パラメータ ***
a = 1;
b = input("b = ");
k = input("k = ");
// 時間ベクトル
T = linspace(0,10);

// ************************************
//
// 数値解
//
// ************************************
// 解くべき微分方程式
function dx = balanced(t,x)
dx = k * (a - x) * (b - x);
endfunction
// 初期値
x0 = 0;
// 微分方程式の数値解
X = ode(x0,0,T,balanced);

// ************************************
//
// 解析解
//
// ************************************
g = (a - b) / 2 * k;
if a == b then
Xa = a - 1 ./ (k .* T + 1 / a);
else
Xa = a * b * (exp(g * T) - exp(- g * T)) ./ (a * exp(g * T) - b * exp(- g * T));
end

// ************************************
//
// プロット
//
// ************************************
plot(T,X,'or');
plot(T,Xa,'-g');
xtitle(strcat(["Chemical Reaction: ","a = ",string(a),", b = ",string(b),", k = ",string(k)]));
xlabel("$t [s]$");
ylabel("$N_c$");
legend(["Numerical","Analytical"],4);


常微分方程式の数値解法


以下の通り、これまで微分方程式による物理現象のモデル化(PDF)に倣って、Scilabで常微分方程式の数値解法を扱ってきました。



2013年の更新はこれにて終了です。特にひねりは無いですが、来年は量子力学の問題から行こうと思います。
ただし、量子力学以降は単純な常微分方程式ではありません。常微分方程式は(ある意味何も考えずに)常微分方程式ソルバodeを使うだけで計算できてしまいますが、偏微分方程式は全自動で解いてくれるソルバが存在しないので少し考える必要があります。

元PDFには、(遍微分方程式ではない)普通の常微分方程式の問題として電子回路関係が残っていますが、LTspiceを使えば極めて簡単に計算できる回路をわざわざプログラム書きたくないという思いがあり、やる気がおきないです。

それでは、良いお年を。(と、予約投稿なので、書いている今はまだ7月なのですが。)

参考URL




付録


このエントリで使用したScilabのシミュレーション用ファイルを添付します。ファイル名末尾の".txt"を削除して、"_"を"."に変更すれば使えるはずです。(参考:ねがてぃぶろぐの付録)


参考文献/使用機器




フィードバック



にほんブログ村 その他趣味ブログ 電子工作へ

 ↑ 電子工作ブログランキング参加中です。1クリックお願いします。


コメント・トラックバックも歓迎です。 ↓      


 ↓ この記事が面白かった方は「拍手」をお願いします。

tag: Scilab 常微分方程式 ode 化学反応 

Scilabで荷電粒子の三次元運動

微分方程式による物理現象のモデル化(PDF)の直交電磁界中の荷電粒子のプログラムをScilabで再現します。
元PDFでも指摘されている通り、計算そのものよりも三次元的にプロットするほうが本題だと思います。

001_20130729175916.png

Fig.1: 荷電粒子の三次元運動。三次元プロットしたものとx-y平面にプロットしたもの。x-y平面にプロットしても実際の運動の様子はいまいち良く分からない。


また、元PDFではz方向の磁界とy方向の電界をパラメータとするプログラムを書いていますが、それ以外の方向にも書けるようにしておきます。


解くべき微分方程式は以下のように示されます。

\frac{\mathrm{d}\vec{v}}{\mathrm{d}t} = \frac{q}{m} \vec{E} + \frac{q}{m} \vec{v}\times\vec{B}

Scilabのode関数で解くためには dX/dt = ...の形にします。要素が増えると分かり辛くなるので、ベクトルの中での順番が分かりやすいように要素を書き下します。

3200cfe9f5356627aee923664d453908_90_black.png

次に微分方程式もベクトルの要素を書き出します。

\frac{\mathrm{d}}{\mathrm{d}t}\begin{pmatrix}v_x \\v_y \\v_z\end{pmatrix}&=\frac{q}{m}\begin{pmatrix}E_x \\E_y \\E_z\end{pmatrix}+\frac{q}{m}\begin{pmatrix}v_x \\v_y \\v_z\end{pmatrix}\times\begin{pmatrix}B_x \\B_y \\B_z\end{pmatrix}\\&=\frac{q}{m}\begin{pmatrix}E_x \\E_y \\E_z\end{pmatrix}+\frac{q}{m}\begin{pmatrix}v_y B_z - v_z B_y \\v_z B_z - v_x B_z \\v_x B_y - v_y B_x\end{pmatrix}

これを踏まえたScilabのプログラムがemdrift_sce.txtです。
Scilabでカオスアトラクタではplot3d3を使いましたが、これは三次元曲面を描く命令で、三次元空間に曲線を引くのはparam3dで行うのが良いようです。

clear;

// *** 入力パラメータ ***
m = 1.0; // 粒子の質量
q = 1.0; // 粒子の電荷
// 一様磁界
bx = 0;
by = 0;
bz = 3.0;
// 一様電解
ex = 0;
ey = 1.5;
ez = 0;

// *** 解くべき常微分方程式の定義 ***
function dx = em(t,x)
// dx/dt = vx
dx(1) = x(2);
// dy/dt = vy
dx(3) = x(4);
// dz/dt = vz
dx(5) = x(6);
// dvx/dt = (q/m) * Ex + (q/m) * (vy*Bz-vz*By)
dx(2) = q * ex / m + q * (x(4) * bz - x(6) * by) / m;
// dvy/dt = (q/m) * Ey + (q/m) * (vz*Bx-vx*Bz)
dx(4) = q * ey / m + q * (x(6) * bx - x(2) * bz) / m;
// dvz/dt = (q/m) * Ez + (q/m) * (vx*By-vz*Bx)
dx(6) = q * ez / m + q * (x(2) * by - x(4) * bx) / m;
endfunction

// 時間ベクトル
T = linspace(0,20,201);

// 初期条件
x0 = 0;
vx0 = - 1;
y0 = 0;
vy0 = 0;
z0 = 0;
vz0 = 0.5;
X0 = [x0; vx0; y0; vy0; z0; vz0];

// 常微分方程式ソルバ
X = ode(X0,0,T,em);

// グラフのプロット
param3d(X(1,:),X(3,:),X(5,:),,flag=[5,4],ebox=[-5,5,-5,5,0,10]);
param3d(X(1,:),X(3,:),zeros(X(5,:)),flag=[5,4],ebox=[-5,5,-5,5,0,10]);
xlabel("x");
ylabel("y");
zlabel("z");



関連エントリ




参考URL




付録


このエントリで使用したScilabのシミュレーション用ファイルを添付します。ファイル名末尾の".txt"を削除して、"_"を"."に変更すれば使えるはずです。(参考:ねがてぃぶろぐの付録)


参考文献/使用機器




フィードバック



にほんブログ村 その他趣味ブログ 電子工作へ

 ↑ 電子工作ブログランキング参加中です。1クリックお願いします。


コメント・トラックバックも歓迎です。 ↓      


 ↓ この記事が面白かった方は「拍手」をお願いします。

tag: Scilab 常微分方程式 ode 三次元 

Scilabでラザフォード散乱

微分方程式による物理現象のモデル化(PDF)に従ってラザフォード散乱のプログラムをScilabで書き直します。

001_20130729024531.png

Fig.1: ラザフォード散乱のシミュレーション結果の中心部分を拡大したもの。



点電荷によるα粒子の散乱


前期量子力学の重要な結論の一つに、原子はほとんど「すかすか」で質量と正の電荷は原子の中心の極めて狭い領域に集中しているというラザフォードの原子模型があります。このことを明らかにした実験がラザフォード散乱です。原子の構造に関しては九州大学のインターネット・セミナーミクロの世界」 - その1 - (原子の世界の謎) 第2部: 原子の構造が分かりやすいです。以下のトムソンの原子模型とラザフォードの原子模型の図も上記サイトから引用しました。このインターネットセミナーは書籍にもなっているようです(わかりやすい量子力学入門―原子の世界の謎を解く)。

Atom.png


金の原子核が金原子の大きさとくらべて充分小さく大きさが無視できると仮定すると、金原子はZAuの正の電荷を持つ点電荷であると考えることが出来ます。この金原子に5.3MeVのエネルギーを持つα粒子に作用するクーロン力は、金の原子核を局座標の原点に置くと、以下のようにあらわされます。

f = \frac{Z_{\alpha}Z_{\mathrm{Au}}e^2}{4 \pi \epsilon_0}\frac{1}{r^2}

たいそうな形をしていますが、r以外は全て定数です。つまり、クーロン力は金の原子核の距離だけで決まり、その大きさは距離の二乗に反比例します。

002_20130729024531.png

Fig.2: クーロン力


クーロン力のx成分とy成分はそれぞれ以下のようにあらわせます。

f_x = f \cos\theta = f\frac{x}{r}

f_y = f \sin\theta = f\frac{y}{r}

これらを運動方程式へ代入し、両辺をα粒子の質量mαで割ると

\frac{\mathrm{d}^2x}{\mathrm{d}t^2} = \frac{Z_{\alpha}Z_{\mathrm{Au}}e^2}{4 \pi \epsilon_0 m_{\alpha}}\frac{x}{r^3}

\frac{\mathrm{d}^2y}{\mathrm{d}t^2} = \frac{Z_{\alpha}Z_{\mathrm{Au}}e^2}{4 \pi \epsilon_0 m_{\alpha}}\frac{y}{r^3}

x,y,r以外は定数なので適切な単位系を設定すると

\frac{Z_{\alpha}Z_{\mathrm{Au}}e^2}{4 \pi \epsilon_0 m_{\alpha}} = 0.0614

となります。なお、微分方程式による物理現象のモデル化(PDF)には数値が書かれていませんが、α粒子の質量は陽子2つと中性子2つでmα=3756[MeV/c2]です。

プログラム


以上を踏まえたプログラムを以下に示します。
これによって描かれた図がFig1およびFig.3です。

003_20130729024530.png

Fig.3: ラザフォード散乱


clear;
// 表示領域のサイズ
//xymax = 2000; // 表示領域を2000*2000に設定
xymax = 400; // 表示領域を400*400に設定
// グラフの縦横比を等しくする
h = scf(); // ウィンドウを作成
ha = h.children(1); // Axes(座標軸)オブジェクトへのハンドルを取得
ha.isoview = "on"; // 座標軸の縦横比を等しくする
ha.data_bounds = [- xymax,- xymax; xymax, xymax]; // 座標軸表示範囲の設定

// *** 解くべき常微分方程式 ***
function dx = ruther(t,x)
r = sqrt(x(1) ^ 2 + x(3) ^ 2);
dx(1) = x(2);
dx(2) = 0.0614 * x(1) / r ^ 3;
dx(3) = x(4);
dx(4) = 0.0614 * x(3) / r ^ 3;
endfunction

// *** 時間ベクトル ***
T = linspace(0,100000,1000);

// *** α粒子の初速度 ***
v0 = 0.053;
vx0 = v0;
vy0 = 0;

// *** α線源の位置 ***
// x座標
x0 = - 2000;

// y座標を変えながらα粒子の運動を計算
for y0 = -95:10:95
X0 = [x0; vx0; y0; vy0];
X = ode(X0,0,T,ruther);
plot(X(1,:),X(3,:),'-r');
end

// 描画範囲の設定
zoom_rect([- xymax,- xymax, xymax, xymax]);


クーロン力のベクトル表示


α粒子が受けるクーロン力は単純に位置のみに依存するので、その力の向きと方向を矢印であらわして見ます。
矢印を表示するScilabのコマンドはchampで、champのためのベクトルを用意するのに便利なのがndgridです。

ベクトル表示を加えたプログラムがrutherford_sce.txtです。

004_20130729024530.png

Fig.4: ラザフォード散乱の結果にクーロン力のベクトルを追加したもの。


矢印の長さが、その点にあるα粒子が受けるクーロン力の大きさを表しています。数式を見るとクーロン力は距離の2乗に反比例することが分かりますが、グラフにしてみても強いクーロン力を受けるのは金原子核のごく近傍だけです。

さて微分方程式による物理現象のモデル化(PDF)の問題28は、つまるところトムソンの原子模型を採用すると散乱はどうなるのかということです。(例題でなく問題という割には答えも書いてありますが)。
これはトムソン模型の原子内部と外部でクーロン力の関数が以下のように場合分けされると考えれば簡単に考察できます。

f( \vec{r} ) = \begin{cases}<br />\frac{Z_{\alpha}Z_{\mathrm{Au}}e^2}{4 \pi \epsilon_0 m_{\alpha} R^3} \vec{r} & (r \leq R) \\<br />\frac{Z_{\alpha}Z_{\mathrm{Au}}e^2}{4 \pi \epsilon_0 m_{\alpha} r^3} \vec{r} & (r > R)<br />\end{cases}

r > Rでは、これまでに考えてきたラザフォード模型と同じ結果を示しますが、r≦Rではr=Rのときと同じ力しか受けません。したがってトムソン模型では飛んできたα粒子を大きな角度へ押し返すような散乱は起こりません。

なお、元PDFの数式は、またしても質量mαで割り算するのを忘れているようです。

参考URL




付録


このエントリで使用したScilabのシミュレーション用ファイルを添付します。ファイル名末尾の".txt"を削除して、"_"を"."に変更すれば使えるはずです。(参考:ねがてぃぶろぐの付録)


参考文献/使用機器




フィードバック



にほんブログ村 その他趣味ブログ 電子工作へ

 ↑ 電子工作ブログランキング参加中です。1クリックお願いします。


コメント・トラックバックも歓迎です。 ↓      


 ↓ この記事が面白かった方は「拍手」をお願いします。

tag: Scilab 常微分方程式 ode 量子力学 クーロン散乱 

FC2カウンター
カテゴリ
ユーザータグ

LTspiceAkaiKKRmachikaneyamaScilabKKRPSoCCPAOPアンプPIC強磁性常微分方程式モンテカルロ解析トランジスタode状態密度DOSインターフェースecaljスイッチング回路定電流PDS5022半導体シェルスクリプト乱数レベルシフトHP6632A温度解析可変抵抗I2Cブレッドボード分散関係トランジスタ技術R6452A数値積分反強磁性バンドギャップ確率論セミナー絶縁偏微分方程式非線形方程式ソルババンド構造熱設計カオスA/DコンバータISO-I2Cフォトカプラ三端子レギュレータシュミットトリガLEDGW近似LM358アナログスイッチ数値微分TL43174HC4053マフィンティン半径発振回路サーボ直流動作点解析カレントミラーPC817CUSB単振り子bzqlty開発環境BSch2ちゃんねる電子負荷イジング模型LDAチョッパアンプ量子力学補間アセンブラFFTブラべ格子標準ロジックパラメトリック解析基本並進ベクトルewidthキュリー温度QSGWGGA失敗談MaximaSMPTLP621スイッチト・キャパシタ熱伝導コバルト相対論スピン軌道相互作用六方最密充填構造繰り返しFETランダムウォークcygwingfortran不規則合金状態方程式ラプラス方程式抵抗スレーターポーリング曲線位相図格子比熱マントルデータロガー自動計測ダイヤモンドガイガー管QNAPUPS固有値問題条件分岐井戸型ポテンシャルシュレディンガー方程式詰め回路MCU第一原理計算起電力熱力学スーパーセルVCALM555仮想結晶近似awkTLP521NE555ubuntufsolveブラウン運動OpenMPVESTA最大値テスタ差し込みグラフFXA-7020ZRWriter509三角波TLP552平均場近似最適化最小値過渡解析LMC662トランスPIC16F785CapSenseMBEナイキスト線図CK1026フィルタP-10負帰還安定性EAGLEAACircuit2SC1815OPA2277PGAノコギリ波縮退非線型方程式ソルバL10構造fcc面心立方構造結晶磁気異方性TeX全エネルギー固定スピンモーメントFSMウィグナーザイツ胞interp1ヒストグラム確率論マテリアルデザインspecx.fジバニャン方程式等高線初期値フェルミ面正規分布c/agnuplotBaO岩塩構造ルチル構造ウルツ鉱構造ZnO重積分SIC二相共存スワップ領域リジッドバンド模型半金属合金multiplotハーフメタルデバイ模型edeltquantumESPRESSOフォノンifortUbuntuマンデルブロ集合キーボードRealforce関数フィッティングフラクタルクーロン散乱CIF化学反応三次元最小二乗法日本語直流解析PCトラックボールExcelTS-110パラメータ・モデル等価回路モデルTS-112疎行列文字列HiLAPW両対数グラフ片対数グラフ熱拡散方程式陰解法境界条件連立一次方程式Crank-Nicolson法グラフの分割軸ラベルヒストグラム不規則局所モーメント入出力円周率Gimp凡例線種シンボルMAS830L

最新コメント
リンク

にほんブログ村 その他趣味ブログ 電子工作へ