Scilabで一次元のラプラス方程式 その3

Scilabで一次元のラプラス方程式 その1その2では一次元のラプラス方程式を 0 ≦ x ≦ 1 の範囲で以下の様なディリクレの境界条件で解きました。

一次元ラプラス方程式:
\frac{\partial^2 u}{\partial x^2} = 0

ディリクレ境界条件:
u = 1 (x = 0)
u = 0 (x = 1)

今回は、同様の方程式を x = 0 に関して以下の様なノイマンの境界条件で解きました。

ノイマン境界条件:
∂u/∂x = -1 (x = 0)


ラプラス方程式と境界条件


Scilabで一次元のラプラス方程式 その1その2では一次元のラプラス方程式をScilabを用いて数値的に解きました。

\frac{\partial^2 u}{\partial x^2} = 0

偏微分方程式を解くためには、この式のほかに幾つかの境界条件が必要です。
偏微分方程式の数値解法入門によると偏微分方程式の境界条件に関して以下の様に書かれています。

境界上においてuの値(関数値)が指定されている境界条件を第1種の境界条件あるいディリクレ(Dirichlet)の境界条件という.
一方,境界上でその境界の外向き法線方向nの微分係数∂u/∂nが指定されている場合がある.これを第2種の境界条件あるいはノイマン(Neumann)の境界条件という.

Scilabで一次元のラプラス方程式 その1その2、及びScilabで熱拡散方程式 その1その2その3は全てディリクレの境界条件でした。そこで今回は、一次元のラプラス方程式を境界の片側をノイマンの境界条件で、反対側をディリクレの境界条件として数値的に解くことにします。

連立方程式の立て方はScilabで一次元のラプラス方程式 その1の流儀で行きます。

問題設定


解くべき方程式は、一次元のラプラス方程式です。

\frac{\partial^2 u}{\partial x^2} = 0

ただし 0 ≦ x ≦ 1
境界条件は

x = 0 にて
\frac{\partial u}{\partial x} = -1

x = 1 にて
u = 0

とします。


001_20140220011035c9c.png
Fig.1: 計算の設定(と計算結果)


まず前回までと同様にディリクレ境界条件と偏微分方程式から以下の連立方程式が立ちます。

u1 - 2u2 + u3 = 0
u2 - 2u3 + u4 = 0
u3 - 2u4 + u5 = 0
u5 = 0

当然ながらこれだけでは変数の数に対して方程式の数が足りないので、ノイマンの境界条件についても考えます。1階の偏微分をを前進差分近似で表すと以下の様になります。

\frac{\partial u}{\partial x} = \frac{u_{i+1} - u_{i}}{\Delta x}

より良い精度で計算をするためには(-Δx,u0)の点も用意して中心差分近似を使うべきなのでしょうが、今回は前進差分近似で済ませることにします。

これがx = 0 で ∂u/∂x = -1 なので

\frac{u_2 - u_1}{\Delta x} = -1

したがって

u1 - u2 = Δx

結局、連立方程式は以下の様になります。

u1 - u2 = Δx
u1 - 2u2 + u3 = 0
u2 - 2u3 + u4 = 0
u3 - 2u4 + u5 = 0
u5 = 0

これをScilabで連立一次方程式の方法で解くプログラムがLaplace1d3_sce.txtです。

clear;

// xの刻み幅
dx = 1 / 4;
// グラフ用のx座標
x = [0:dx:1];

// *** 連立方程式の定義 ***
A = [1 -1 0 0 0;
1 -2 1 0 0;
0 1 -2 1 0;
0 0 1 -2 1;
0 0 0 0 1];
b = [dx;
0;
0;
0;
0];

// *** ラプラス方程式の解 ***
u = A \ b;

// *** グラフのプロット ***
// グラフのプロット
plot(x,u,'-ob');
// グラフの装飾
xlabel("x");
ylabel("u");
zoom_rect([0,0,1.2,1.2]);


境界条件の意味


ラプラス方程式は、熱拡散方程式や波動方程式の時間微分の項をゼロと置いたものでした。従って一次元のラプラス方程式自体の物理的なイメージは、例えば、充分に長い時間を置いた針金の中の温度分布などとして理解できます。

Scilabで熱拡散方程式 その1その2その3で分かるとおり、ディリクレの境界条件は、境界での温度を指定することに対応します。
一方で、ノイマンの境界条件は、境界での温度勾配を指定することに対応します。熱伝導に対するフーリエの法則は以下の様に表すことができます。

q = k \frac{\partial T}{\partial x}

(q: 熱フラックス, k: 熱伝導度, T: 温度, x: 位置)

フーリエの法則の式から明らかなように、境界での温度勾配を指定するということは、境界での熱流量を指定することと同じです。特に ∂T/∂x = 0 の場合は、熱流量がゼロということなので、境界が断熱的であることを意味しています。

関連エントリ




付録


このエントリで使用したScilabのシミュレーション用ファイルを添付します。ファイル名末尾の".txt"を削除して、"_"を"."に変更すれば使えるはずです。(参考:ねがてぃぶろぐの付録)


参考文献/使用機器




フィードバック



にほんブログ村 その他趣味ブログ 電子工作へ

 ↑ 電子工作ブログランキング参加中です。1クリックお願いします。


コメント・トラックバックも歓迎です。 ↓      


 ↓ この記事が面白かった方は「拍手」をお願いします。

tag: Scilab 偏微分方程式 ラプラス方程式 境界条件 

Scilabで一次元のラプラス方程式 その2

Scilabで一次元のラプラス方程式 その1ではラプラス方程式を差分化し連立一次方程式にした後、Scilabで連立一次方程式の方法で計算しました。

今回もほぼ全く同じ事を行うのですが、境界条件の部分を連立方程式にあらかじめ代入してしまうことで行列の大きさを少しだけ小さくしました。


001_20140217071734b51.png
Fig.1: ラプラス方程式の数値解



問題設定


Scilabで一次元のラプラス方程式 その1と同様に、一次元のラプラス方程式を数値的に解きます。

\frac{\partial^2 u}{\partial x^2} = 0

ただし 0 ≦ x ≦ 1 で境界条件は以下の通りです。

u = 1 (x = 0)
u = 0 (x = 1)

ここまでは前回と完全に同じです。

別解


前回とほぼ同じ内容ですが、行列のサイズを小さくするために表記を少し工夫します。

問題設定自体は同じですが、空間の分割数をひとつ増やします。それに伴って添え字を1からでは無く0からに変更しています。すなわち境界条件は u0=1, u4=0 です。

境界条件の部分を除いた連立方程式は以下の様になります。

u0 - 2u1 + u2 = 0
u1 - 2u2 + u3 = 0
u2 - 2u3 + u4 = 0

これに境界条件 u0=1, u4=0 を代入すると

-2u1 + u2 = -1
u1 - 2u2 + u3 = 0
u2 - 2u3 = 0

となります。

A = \begin{pmatrix} -2 & 1 & 0 \\ 1 & -2 & 1 \\ 0 & 1 & -2 \\ \end{pmatrix}

\mathbf{u} = \left( \begin{array}{c} u_1 \\ u_2 \\ u_3 \end{array} \right)

\mathbf{b} = \left( \begin{array}{c} -1 \\ 0 \\ 0 \end{array} \right)

とおけば、連立方程式を行列の形式で表すことができ

Au = b

やはりScilabで連立一次方程式の方法で計算することが出来ます。

今回の計算では、空間分解能が高くなったにもかかわらず、行列の大きさが小さくなっていることが分かると思います。まあ、あらかじめ境界条件の部分を代入して連立する方程式の数を2つ減らしただけですが。

Scilabで熱拡散方程式 その3 (陰解法)では、Octaveの精義の流儀に従っていますが、これは今回の方法と同じです。

一方、偏微分方程式の差分解法入門(PDF)前回の様に境界条件まで行列の中に含める方法を採っています。

関連エントリ




参考URL




付録


このエントリで使用したScilabのシミュレーション用ファイルを添付します。ファイル名末尾の".txt"を削除して、"_"を"."に変更すれば使えるはずです。(参考:ねがてぃぶろぐの付録)


参考文献/使用機器




フィードバック



にほんブログ村 その他趣味ブログ 電子工作へ

 ↑ 電子工作ブログランキング参加中です。1クリックお願いします。


コメント・トラックバックも歓迎です。 ↓      


 ↓ この記事が面白かった方は「拍手」をお願いします。

tag: Scilab 偏微分方程式 ラプラス方程式 

Scilabで一次元のラプラス方程式 その1

Scilabで熱拡散方程式 その1その2その3では一次元の熱拡散方程式をScilabで数値的に解きました。今回はこれらプログラムをよりよく理解するために、より簡単な一次元のラプラス方程式を解いてみます。

\frac{\partial^2 u}{\partial x^2} = 0

実を言うと一次元のラプラス方程式は、Scilabで連立一次方程式で計算した連立一次方程式になってしまうので簡単に計算することが出来ます。


ラプラス方程式


ラプラス方程式は、熱拡散方程式や波動方程式に対して、時間の偏微分の項をゼロとしたものです。

2u=0

一次元の場合は

\frac{\partial^2 u}{\partial x^2} = 0

です。

時間による偏微分がゼロということなので、この式は定常状態の物理現象を表しています。

ラプラス方程式の解法


一次元のラプラス方程式を、0 ≦ x ≦ 1 の範囲で、下記の境界条件で解くことを考えます。

u = 1 (x = 0)
u = 0 (x = 1)

この解は、数値計算をするまでもなく直感的に (x,u)=(0,1) と (1,0) を通る直線となることが想像できます。

つまり

u = 1 - x

です。

このことを実際に差分化を行った数値計算から確認します。
簡単のため、空間の分割数は極端に少なくすることにします。(Fig.1)


001_201402170611560b6.png
Fig.1: ラプラス方程式の差分化


2u/∂x2 を差分化すると

\frac{\partial^2 u}{\partial x^2} = \frac{1}{(\Delta x)^2} (u_{i+1} - 2u_{i} + u_{i-1})

ラプラス方程式は ∂2u/∂x2 = 0 なので差分化したラプラス方程式は

ui+1 - 2ui + ui+1 = 0

となります。(参考:偏微分方程式の数値解法入門)

先ほどの境界条件とあわせると

u1 = 1
u1 - 2u2 + u3 = 0
u2 - 2u3 + u4 = 0
u4 = 0

となり、これは実のところScilabで連立一次方程式で解いた連立一次方程式以外の何物でもありません。

よって行列Aとベクトルu, bを以下の様におくと

A = \begin{pmatrix} 1 & 0 & 0 & 0 \\ 1 & -2 & 1 & 0 \\ 0 & 1 & -2 & 1 \\ 0 & 0 & 0 & 1 \\ \end{pmatrix}

\mathbf{u} = \left(   \begin{array}{c}     u_1 \\     u_2 \\     u_3 \\     u_4   \end{array} \right)

\mathbf{b} = \left(   \begin{array}{c}     1 \\     0 \\    0 \\     0   \end{array} \right)

連立方程式は、以下の様に行列の式で表現することが出来ます。

Au=b

Scilabで連立一次方程式と同様に計算すればラプラス方程式が解けたことになります。

clear;

// *** 連立方程式の定義 ***
A = [1 0 0 0;
1 -2 1 0;
0 1 -2 1;
0 0 0 1];
b = [1;
0;
0;
0];

// *** ラプラス方程式の解 ***
u = A \ b;

// *** グラフのプロット ***
// グラフ用のx座標
x = linspace(0,1,4);
// グラフのプロット
plot(x,u,'-ob');
// グラフの装飾
xlabel("x");
ylabel("u");
zoom_rect([0,0,1.2,1.2]);


関連エントリ




参考URL




付録


このエントリで使用したScilabのシミュレーション用ファイルを添付します。ファイル名末尾の".txt"を削除して、"_"を"."に変更すれば使えるはずです。(参考:ねがてぃぶろぐの付録)


参考文献/使用機器




フィードバック



にほんブログ村 その他趣味ブログ 電子工作へ

 ↑ 電子工作ブログランキング参加中です。1クリックお願いします。


コメント・トラックバックも歓迎です。 ↓      


 ↓ この記事が面白かった方は「拍手」をお願いします。

tag: Scilab 偏微分方程式 ラプラス方程式 

Scilabで熱拡散方程式 その3 (陰解法)

Scilabで熱拡散方程式 その1 (陽解法)Scilabで熱拡散方程式 その2 (無次元化)では陽解法で偏微分方程式を解く方法を書くと同時に、時間と空間の刻み幅を自由に選べないという問題点を指摘しました。今回はその問題点を解決した陰解法(Crank-Nicolson法)を紹介します。


001_20140215031531793.png
Fig.1: 一次元熱伝導問題の解



偏微分方程式の陰解法


Scilabで熱拡散方程式 その1 (陽解法)では、Octaveの精義を参考にして、一次元の熱伝導を題材に偏微分方程式を陽解法で解くということを行いました。しかしながらScilabで熱拡散方程式 その2 (無次元化)で紹介したとおり、陽解法では λ ≦ 1/2 という安定性の条件から空間の分解能と時間の分解能を独立に決めることが出来ないという欠点があることが確認されました。

Octaveの精義では、この問題を陰解法のひとつであるCrank-Nicolson法を用いて解決する方法を紹介しています。そこで今回は、その1の計算をCrank-Nicolson法で計算します。

計算


計算結果が冒頭に示したFig.1です。
そのスクリプトはCN_sce.txtです。

clear;

// *** 時間と空間の分割 ***
n = 129; // 空間の分割数
dx = 1 / (n - 1); // 空間の刻み幅

r = 4

dt = r * dx ^ 2; // 時間の刻み幅
m = 1001; // 時間の分割数
dm = 100; // プロットする m の間隔

// *** 初期条件と境界条件 ***
// 初期条件
u = zeros(n,m);
// 境界条件
u(1,1) = 0;
u(n,1) = 1;

// *** 行列C ***
C = sparse(toeplitz([-2, 1, zeros(1,n - 2)]));
A = sparse(2 * eye(n,n) - r * C);
B = sparse(2 * eye(n,n) + r * C);
b = zeros(n,1);
b($) = 2 * r;

// *** 偏微分方程式の計算 ***
for j = 1:(m - 1)
// 境界以外の計算
u(:, j + 1) = A \ (B * u(:,j) + b);
// 境界条件
u(1, j + 1) = 0;
u(n, j + 1) = 1;
end

// *** グラフのプロット ***
plot([0:dx:1],u(:,1:dm:m));


陰解法の利点


Scilabで熱拡散方程式 その1 (陽解法)Scilabで熱拡散方程式 その2 (無次元化)では、陽解法の問題点として時間と空間の刻み幅を独立に決定することが出来ないという点を挙げました。

Crank-Nicolson法はこの問題点を改善したものです。


002_201402150315301ea.png
Fig.2: 1次元熱伝導方程式の陽解法(FTCS法)による数値解で、Octaveの精義のコードをScilabへ移植したもの。全てh2=1/322に固定しr = 1/6 (左上), 1/2 (右上), 65/128 (左下)と変化させた結果。r = 64/128 > 1/2 の場合には解が不安定になっていることが読み取れる。

003_20140215031530c4c.png
Fig.3: 1次元熱伝導方程式の陰解法(Crank-Nicolson法)による数値解で、Octaveの精義のコードをScilabへ移植したもの。全てh2=1/1282に固定しr=1 (左上),2 (右上), 4(左下)と変化させた結果。全てのrに対して安定な解が得られていることが分かる。



関連エントリ




参考URL




付録


このエントリで使用したScilabのシミュレーション用ファイルを添付します。ファイル名末尾の".txt"を削除して、"_"を"."に変更すれば使えるはずです。(参考:ねがてぃぶろぐの付録)


参考文献/使用機器






フィードバック



にほんブログ村 その他趣味ブログ 電子工作へ

 ↑ 電子工作ブログランキング参加中です。1クリックお願いします。


コメント・トラックバックも歓迎です。 ↓      


 ↓ この記事が面白かった方は「拍手」をお願いします。

tag: Scilab 偏微分方程式 熱伝導 陰解法 Crank-Nicolson法 

Scilabで熱拡散方程式 その2 (無次元化)

Scilabで熱拡散方程式 その1 (陽解法)ではOctaveの精義を参考にして以下に示す一次元の熱拡散方程式を無次元化してScilabで計算しました。

\frac{\partial T'}{\partial t'} = D^2 \frac{\partial^2 T'}{\partial {x'}^2}

ただし 0 ≦ x' ≦ λ, t' ≧ 0

(T': 温度, t': 時間, D2: 熱拡散率, x': 位置)

今回はもう少し具体的に、現実に即した問題を無次元化し、更にもう一度具体的な次元を持った値に直すという手順をやってみます。


問題設定


Scilabで熱拡散方程式 その1 (陽解法)では一次元の熱伝導の問題を解くために熱拡散方程式を無次元化して陽解法でで計算を行いました。
無次元化を行ったということは、計算結果は実際の長さや時間とは違う目盛りで書かれているということなので、無次元化とは逆の処理をして実際のものに直す必要があります。

今回は以下のような具体的な条件でScilabで熱拡散方程式 その1 (陽解法)と全く同じ計算を行います。

長さ1.5mの銅でできた棒の左端を0℃の氷に、右端を100℃のお湯に接しさせたとき、1時間後の温度分布はどのようになるか。ただし、最初の温度分布は全て0℃であったとする。

銅の熱拡散率D2 = 116 × 10-6 m2/sは以下の計算式とパラメータから計算しました。

D^{2} = \frac{k}{\rho C_p}

(D2: 熱拡散率, ρ: 密度, CP: 定圧比熱)

パラメータ
熱伝導度 k398 W/m/K
密度 ρ8.92×103 kg/m3
定圧モル比熱 CP,m24.44 J/mol/K
原子量 M6.3546×10-2 kg/mol
table.1: 熱拡散率D2=116×10-6 m2/s を計算するためのパラメータ。定圧比熱は密度と単位をそろえるためにCP=CP,m/Mとする。各パラメータの出展はWikipedia。


分子のおもちゃ箱 熱拡散長には色々な金属の熱拡散率が表にまとめられています。

熱拡散方程式


Scilabで熱拡散方程式 その1 (陽解法)と全く同じ内容をもう一度書いておきます。今回解くべき偏微分方程式は以下のものになります。

\frac{\partial T'}{\partial t'} = D^2 \frac{\partial^2 T'}{\partial {x'}^2}

ただし 0 ≦ x' ≦ λ, t' ≧ 0

(T': 温度, t': 時間, D2:熱拡散率, x': 位置)

なお文字の上についている'(アポストロフィー)は(後で行う)無次元化をしていないことを意味します(微分を意味するものではありません)。

方程式の無次元化


以下の様に方程式の無次元化することを考えます。

x' = λx
t' = τt
T'(x',t') = T0u(x,t)

ただし

\frac{D^2 \tau}{\lambda^2}=1

の関係に注意が必要です。

いま銅の棒の長さは1.5mなので λ=1.5 m です。
これに熱拡散率 D2 = 116 × 10-6 m2/s をあわせてτが必然的に決まります。

\tau = \frac{\lambda^2}{D^2}

計算結果は τ = 19394.442 s となりました。

最後に温度の無次元化ですが、これは単純に T0 = 100 ℃ と置けばよいでしょう。このように置けば 0 ≦ T' ≦ 100 に対して 0 ≦ u ≦ 1 となります。

結局、無次元化した熱拡散方程式は下記の様になります。

\frac{\partial u(x,t)}{\partial t} = \frac{\partial^2 u(x,t)}{\partial x^2}

0 ≦ x ≦ 1, t ≧ 0

方程式の差分化


無次元化された熱拡散方程式を差分化するに際して、時間と空間の刻み幅をまとめて

r = \frac{\Delta t}{(\Delta x)^2}

と置いたわけですが、これが r < 1/2 では計算が失敗し r = 1/6 のときだけ誤差が小さくなるという特徴があると前回書きました。

ここからは r = 1/6 を選ぶとして話を進めます。rにこれ以外の数字を選ぶにしても、必ず1/2 未満にならないようにチェックをする必要があります。

いま一次元空間 0 ≦ x ≦ 1 の範囲でn点ほど計算するとするならば、Δxの大きさは Δx = 1/(n-1) となります。
rとΔxが決まるとΔtも必然的に決まり Δt = r×(Δx)2 です。

時間はτを使って無次元化されているため、無次元化された時間の刻み幅Δtもτを使って実際の時間の刻み幅に戻すことが出来ます。

\tau \Delta t = \tau r (\Delta x)^2 = \frac{\tau r}{(n-1)^2}

仮に空間の計算点数を n=50 とすると、τΔt= 1.3462753 s となります。
今回の計算では1時間後(60×60=3600秒後)の温度分布を計算するので m ≒ 3600 / (τΔt) ≒ 2674 回の繰り返し計算をします。

計算結果


以下に示すのが 約1時間後(3599.9401秒後)の銅の棒の温度分布です。


001_20140123132748b05.png
Fig.1: 全体が0℃であった銅の棒の左端を0℃に固定、右端を100℃に固定した状態で約1時間(3599.9401秒)保持したときの内部の温度分布。


計算の手順はこのエントリに書いたとおりです。

clear;

// *** 銅の物性値 ***
k = 398; // 熱伝導度 398 W/m/K
rho = 8.92E3; // 密度 8.92×10^3 kg/m^3

cpm = 24.44; // 定積モル比熱 24.44 J/mol/K
m = 63.546; // 原子量 g/mol
mkg = m * 1E-3; // 原子量 kg/mol
cp = cpm / mkg; // 定積質量比熱 J/kg/K

d2 = k / (rho * cp) // 熱拡散率 m^2/s

// *** 無次元化前の時間と空間 ***
lambda = 1.5; // 棒の長さ λ (m)
tdmax = 60 * 60; // t'max (s) まで計算

// *** 無次元化 ***
tau = lambda ^ 2 / d2; // 時間の無次元化係数
tmax = tdmax / tau; // 無次元化時間で tmax まで計算
temp0 = 100; // u=1 に対してT'=100℃

// *** 時間と空間の分割 ***
n = 50; // 空間の分割数
dx = 1 / (n - 1); // 空間の刻み幅

r = 1 / 6;

dt = r * dx ^ 2; // 時間の刻み幅
m = round(tmax / dt); // 時間の分割数

// *** 初期条件と境界条件 ***
// 初期条件
U = zeros(n,m);
// 境界条件
U(1,1) = 0;
U(n,1) = 1;

// *** 行列P ***
s = 1 - 2 * r;
P = toeplitz([s, r, zeros(1, n - 2)]);

// *** 偏微分方程式の計算 ***
for j = 1:(m - 1)
// 境界以外の計算
U(:, j + 1) = P * U(:,j);
// 境界条件
U(1, j + 1) = 0;
U(n, j + 1) = 1;
end

// *** グラフのプロット ***
X = linspace(0,lambda,n);
plot(X,temp0 * U(:,m),'o-b');
zoom_rect([0,0,lambda,temp0]);

xlabel("Position (m)");
ylabel("Temperature (degree C)");


関連エントリ




参考URL




付録


このエントリで使用したScilabのシミュレーション用ファイルを添付します。ファイル名末尾の".txt"を削除して、"_"を"."に変更すれば使えるはずです。(参考:ねがてぃぶろぐの付録)


参考文献/使用機器







フィードバック



にほんブログ村 その他趣味ブログ 電子工作へ

 ↑ 電子工作ブログランキング参加中です。1クリックお願いします。


コメント・トラックバックも歓迎です。 ↓      


 ↓ この記事が面白かった方は「拍手」をお願いします。

tag: Scilab 偏微分方程式 熱拡散方程式 熱伝導 

FC2カウンター
カテゴリ
ユーザータグ

LTspiceAkaiKKRmachikaneyamaScilabKKRPSoC強磁性OPアンプPICCPA常微分方程式モンテカルロ解析ecaljodeトランジスタ状態密度インターフェースDOS定電流スイッチング回路PDS5022半導体シェルスクリプトレベルシフト乱数HP6632AR6452AI2C可変抵抗分散関係トランジスタ技術ブレッドボード温度解析反強磁性確率論バンドギャップセミナー数値積分熱設計非線形方程式ソルババンド構造絶縁偏微分方程式ISO-I2CLM358フォトカプラ三端子レギュレータカオスLEDシュミットトリガGW近似A/Dコンバータ発振回路PC817C直流動作点解析USBマフィンティン半径数値微分アナログスイッチTL43174HC4053カレントミラーサーボ量子力学単振り子チョッパアンプ補間2ちゃんねる開発環境bzqltyFFT電子負荷LDAイジング模型BSch基本並進ベクトルブラべ格子パラメトリック解析標準ロジックアセンブラ繰り返し六方最密充填構造SMPコバルトewidthFET仮想結晶近似QSGW不規則合金VCAMaximaGGA熱伝導cygwinスレーターポーリング曲線キュリー温度スイッチト・キャパシタ失敗談ランダムウォークgfortran抵抗相対論位相図スピン軌道相互作用VESTA状態方程式TLP621ラプラス方程式TLP552条件分岐NE555LM555TLP521マントル詰め回路MCUテスタFXA-7020ZR三角波過渡解析ガイガー管自動計測QNAPUPSWriter509ダイヤモンドデータロガー格子比熱熱力学awkブラウン運動起電力スーパーセル差し込みグラフ第一原理計算フェルミ面fsolveCIFxcrysden最大値最小値ubuntu最適化平均場近似OpenMPシュレディンガー方程式固有値問題井戸型ポテンシャル2SC1815TeX結晶磁気異方性OPA2277非線型方程式ソルバフラクタルFSM固定スピンモーメントc/agnuplotPGA全エネルギーfccマンデルブロ集合縮退正規分布キーボード初期値interp1multiplotフィルタ面心立方構造ウィグナーザイツ胞L10構造半金属二相共存ZnOウルツ鉱構造BaOSIC重積分磁気モーメント電荷密度化学反応クーロン散乱岩塩構造CapSenseノコギリ波デバイ模型ハーフメタルRealforceフォノンquantumESPRESSOルチル構造スワップ領域リジッドバンド模型edelt合金等高線凡例軸ラベル線種シンボルトラックボールグラフの分割MAS830LPIC16F785トランス入出力CK1026PC直流解析パラメータ・モデル等価回路モデル不規則局所モーメント関数フィッティング日本語ヒストグラムTS-112ExcelGimp円周率TS-110LMC662片対数グラフ三次元specx.fifortUbuntu文字列疎行列不純物問題ジバニャン方程式ヒストグラム確率論マテリアルデザインP-10境界条件連立一次方程式AACircuit熱拡散方程式HiLAPW両対数グラフ陰解法MBEナイキスト線図負帰還安定性Crank-Nicolson法EAGLE最小二乗法

最新コメント
リンク

にほんブログ村 その他趣味ブログ 電子工作へ